1064: [Noi2008]假面舞会 - BZOJ

Description

一年一度的假面舞会又开始了，栋栋也兴致勃勃的参加了今年的舞会。今年的面具都是主办方特别定制的。每个参加舞会的人都可以在入场时选择一 个自己喜欢的面具。每个面具都有一个编号，主办方会把此编号告诉拿该面具的人。为了使舞会更有神秘感，主办方把面具分为k (k≥3)类，并使用特殊的技术将每个面具的编号标在了面具上，只有戴第i 类面具的人才能看到戴第i+1 类面具的人的编号，戴第k 类面具的人能看到戴第1 类面具的人的编号。 参加舞会的人并不知道有多少类面具，但是栋栋对此却特别好奇，他想自己算出有多少类面具，于是他开始在人群中收集信息。 栋栋收集的信息都是戴第几号面具的人看到了第几号面具的编号。如戴第2号面具的人看到了第5 号面具的编号。栋栋自己也会看到一些编号，他也会根据自己的面具编号把信息补充进去。由于并不是每个人都能记住自己所看到的全部编号，因此，栋栋收集的信 息不能保证其完整性。现在请你计算，按照栋栋目前得到的信息，至多和至少有多少类面具。由于主办方已经声明了k≥3，所以你必须将这条信息也考虑进去。
Input

第一行包含两个整数n, m，用一个空格分隔，n 表示主办方总共准备了多少个面具，m 表示栋栋收集了多少条信息。接下来m 行，每行为两个用空格分开的整数a, b，表示戴第a 号面具的人看到了第b 号面具的编号。相同的数对a, b 在输入文件中可能出现多次。
Output

包含两个数，第一个数为最大可能的面具类数，第二个数为最小可能的面具类数。如果无法将所有的面具分为至少3 类，使得这些信息都满足，则认为栋栋收集的信息有错误，输出两个-1。
Sample Input
【输入样例一】

6 5
1 2
2 3
3 4
4 1
3 5

【输入样例二】

3 3
1 2
2 1
2 3

Sample Output
【输出样例一】

4 4

【输出样例二】

-1 -1
【数据规模和约定】

50%的数据，满足n ≤ 300, m ≤ 1000；
100%的数据，满足n ≤ 100000, m ≤ 1000000。

 

题解

先把正向的边权设为1，反向为-1，然后分情况讨论

1.没有环，那么就把我们找到的每一个联通块的最长链全部串起来是最大的，3为最小（如果最大和最小有冲突，就输出-1）

2.有环，那我们就计算环的gcd，gcd为最大，3为最小（如果最大和最小有冲突，就输出-1）

const
        maxn=100010;
        maxm=1000010;
var
        id,first:array[0..maxn]of longint;
        last,next,w:array[0..2*maxm]of longint;
        flag:array[0..maxn]of boolean;
        n,m,tot,sum,t,max,min:longint;
 
function gcd(a,b:longint):longint;
begin
        if b=0 then exit(a);
        exit(gcd(b,a mod b));
end;
 
procedure insert(x,y,z:longint);
begin
        inc(tot);
        last[tot]:=y;
        next[tot]:=first[x];
        first[x]:=tot;
        w[tot]:=z;
end;
 
procedure init;
var
        i,x,y:longint;
begin
        read(n,m);
        for i:=1 to m do
          begin
            read(x,y);
            insert(x,y,1);
            insert(y,x,-1);
          end;
end;
 
procedure dfs(x:longint);
var
        i:longint;
begin
        flag[x]:=true;
        i:=first[x];
        if id[x]>max then max:=id[x];
        if id[x]<min then min:=id[x];
        while i<>0 do
          begin
            if not flag[last[i]] then
              begin
                id[last[i]]:=id[x]+w[i];
                dfs(last[i]);
              end
            else t:=gcd(t,abs(id[x]+w[i]-id[last[i]]));
            i:=next[i];
          end;
end;
 
procedure work;
var
        i:longint;
begin
        for i:=1 to n do
          if not flag[i] then
          begin
            max:=0;
            min:=0;
            dfs(i);
            inc(sum,max-min+1);
          end;
        if t=0 then
          begin
            if sum<3 then write('-1 -1')
            else write(sum,' ',3);
          end
        else
          begin
            if t<3 then write('-1 -1')
            else
              begin
                for i:=3 to t do
                  if t mod i=0 then break;
                write(t,' ',i);
              end;
          end;
end;
 
begin
        init;
        work;
end.