Linux内核源码分析--内核启动之(1)zImage自解压过程（Linux-3.0 ARMv7）

时间：2021-02-14 16:47:22
研究内核源码和内核运行原理的时候，很总要的一点是要了解内核的初始情况，也就是要了解内核启动过程。我在研究内核的内存管理的时候，想知道内核启动后的页表的放置，页表的初始化等信息，这促使我这次仔细地研究内核的启动代码。

    CPU在bootloader的帮助下将内核载入到了内存中，并开始执行。当然，bootloader必须为zImage做好必要的准备：
 1． CPU 寄存器的设置： R0＝0；
R1＝Machine ID(即Machine Type Number，定义在linux/arch/arm/tools/mach-types)；
R2＝内核启动参数在 RAM 中起始基地址；
 2． CPU 模式： 必须禁止中断（IRQs和FIQs）；
CPU 必须 SVC 模式；
 3． Cache 和 MMU 的设置： MMU 必须关闭；
指令 Cache 可以打开也可以关闭；
数据 Cache 必须关闭；

    知道内核zImage生成的朋友一定知道：真正的内核执行映像其实是在编译时生成arch/$(ARCH)/boot/文件夹中的Image文件（bin文件），而zImage其实是将这个可执行文件作为数据段包含在了自身中，而 zImage的代码功能就是将这个数据（Image）正确地解压到编译时确定的位置中去，并跳到Image中运行 。所以实现bootloader引导的压缩映像zImage的 入口是由arch/arm /boot/compressed/vmlinux.lds 决定的（这个文件是由vmlinux.lds.in生成的）。所以从vmlinux.lds.in中可以看出压缩映像的入口在哪：

  1. ......
  2. OUTPUT_ARCH(arm)
  3. ENTRY(_start)
  4. SECTIONS
  5. {
  6. /DISCARD/ : {
  7. *(.ARM.exidx*)
  8. *(.ARM.extab*)
  9. /*
  10. * Discard any r/w data - this produces a link error if we have any,
  11. * which is required for PIC decompression. Local data generates
  12. * GOTOFF relocations, which prevents it being relocated independently
  13. * of the text/got segments.
  14. */
  15. *(.data)
  16. }
  18. . = TEXT_START;
  19. _text = .;
  21. .text : {
  22. _start = .;
  23. *(.start)
  24. *(.text)
  25. ......
    我们可以在arch/arm/boot/compressed/head.S找到这个start入口，这样就可以从这里开始用代码分析的方法研究bootloader跳转到压缩内核映像后的自解压启动过程：
    再看到MMU设置的时候，我只研究了armv7的指令。看这些代码，必须对ARM的MMU有一定的了解， 建议参考ARMv7的构架手册和网上的一份PDF《ARM MMU中文详解》（就是ARM手册中MMU部分的翻译）

  1. /*
  2. * linux/arch/arm/boot/compressed/head.S
  3. *
  4. * Copyright (C) 1996-2002 Russell King
  5. * Copyright (C) 2004 Hyok S. Choi (MPU support)
  6. *
  7. * This program is free software; you can redistribute it and/or modify
  8. * it under the terms of the GNU General Public License version 2 as
  9. * published by the Free Software Foundation.
  10. */
  11. #include <linux/linkage.h>
  13. /*
  14. * 调试宏
  15. *
  16. * 注意：这些宏必须不包含那些非100%可重定位的代码
  17. * 任何试图这样做的结果是导致程序崩溃
  18. * 当打开调试时请选择以下一个使用
  19. */
  20. #ifdef DEBUG /* 调试宏-中间层 */
  22. #if defined(CONFIG_DEBUG_ICEDCC) /* 使用内部调试协处理器CP14 */
  24. #if defined(CONFIG_CPU_V6) || defined(CONFIG_CPU_V6K) || defined(CONFIG_CPU_V7)
  25. .macro loadsp, rb, tmp
  26. .endm
  27. .macro writeb, ch, rb
  28. mcr p14, 0, \ch, c0, c5, 0
  29. .endm
  30. #elif defined(CONFIG_CPU_XSCALE)
  31. .macro loadsp, rb, tmp
  32. .endm
  33. .macro writeb, ch, rb
  34. mcr p14, 0, \ch, c8, c0, 0
  35. .endm
  36. #else
  37. .macro loadsp, rb, tmp
  38. .endm
  39. .macro writeb, ch, rb
  40. mcr p14, 0, \ch, c1, c0, 0
  41. .endm
  42. #endif
  44. #else /* 使用串口作为调试通道 */
  46. #include <mach/debug-macro.S> /* 包含构架相关的的调试宏的汇编文件 调试宏-底层 */
  48. .macro writeb, ch, rb
  49. senduart \ch, \rb
  50. .endm
  52. #if defined(CONFIG_ARCH_SA1100)
  53. .macro loadsp, rb, tmp
  54. mov \rb, #0x80000000 @ physical base address
  55. #ifdef CONFIG_DEBUG_LL_SER3
  56. add \rb, \rb, #0x00050000 @ Ser3
  57. #else
  58. add \rb, \rb, #0x00010000 @ Ser1
  59. #endif
  60. .endm
  61. #elif defined(CONFIG_ARCH_S3C2410)
  62. .macro loadsp, rb, tmp
  63. mov \rb, #0x50000000
  64. add \rb, \rb, #0x4000 * CONFIG_S3C_LOWLEVEL_UART_PORT
  65. .endm
  66. #else
  67. .macro loadsp, rb, tmp
  68. addruart \rb, \tmp
  69. .endm
  70. #endif
  71. #endif
  72. #endif /* DEBUG */
  75. /* 调试宏-上层 */
  76. .macro kputc,val /* 打印字符 */
  77. mov r0, \val
  78. bl putc
  79. .endm
  81. .macro kphex,val,len /* 打印十六进制数 */
  82. mov r0, \val
  83. mov r1, #\len
  84. bl phex
  85. .endm
  87. .macro debug_reloc_start /* 重定位内核调试宏-开始 */
  88. #ifdef DEBUG
  89. kputc #'\n'
  90. kphex r6, 8 /* 处理器 id */
  91. kputc #':'
  92. kphex r7, 8 /* 构架 id */
  93. #ifdef CONFIG_CPU_CP15
  94. kputc #':'
  95. mrc p15, 0, r0, c1, c0
  96. kphex r0, 8 /* 控制寄存器 */
  97. #endif
  98. kputc #'\n'
  99. kphex r5, 8 /* 解压后的内核起始地址 */
  100. kputc #'-'
  101. kphex r9, 8 /* 解压后的内核结束地址 */
  102. kputc #'>'
  103. kphex r4, 8 /* 内核执行地址 */
  104. kputc #'\n'
  105. #endif
  106. .endm
  108. .macro debug_reloc_end /* 重定位内核调试宏-结束 */
  109. #ifdef DEBUG
  110. kphex r5, 8 /* 内核结束地址 */
  111. kputc #'\n'
  112. mov r0, r4
  113. bl memdump /* 打印内核起始处 256 字节 */
  114. #endif
  115. .endm
  117. .section ".start", #alloc, #execinstr
  118. /*
  119. * 清理不同的调用约定
  120. */
  121. .align
  122. .arm @ 启动总是进入ARM状态
  123. start:
  124. .type start,#function
  125. .rept 7
  126. mov r0, r0
  127. .endr
  128. ARM( mov r0, r0 )
  129. ARM( b 1f )
  130. THUMB( adr r12, BSYM(1f) )
  131. THUMB( bx r12 )
  133. .word 0x016f2818 @ 用于boot loader的魔数
  134. .word start @ 加载/运行zImage的绝对地址（编译时确定）
  135. .word _edata @ zImage结束地址
  136. THUMB( .thumb )
  1. 1: mov r7, r1 @ 保存构架ID到r7（此前由bootloader放入r1）
  2.    mov r8, r2 @ 保存内核启动参数地址到r8（此前由bootloader放入r2）
  4. #ifndef __ARM_ARCH_2__
  5. /*
  6. * 通过Angel调试器启动 - 必须进入 SVC模式且关闭FIQs/IRQs
  7. * (numeric definitions from angel arm.h source).
  8. * 如果进入时在user模式下，我们只需要做这些
  9. */
  10. mrs r2, cpsr @ 获取当前模式
  11. tst r2, #3 @ 判断是否是user模式
  12. bne not_angel
  13. mov r0, #0x17 @ angel_SWIreason_EnterSVC
  14. ARM( swi 0x123456 ) @ angel_SWI_ARM
  15. THUMB( svc 0xab ) @ angel_SWI_THUMB
  16. not_angel:
  17. mrs r2, cpsr @ 关闭中断
  18. orr r2, r2, #0xc0 @ 以保护调试器的运作
  19. msr cpsr_c, r2
  20. #else
  21. teqp pc, #0x0c000003 @ 关闭中断（此外bootloader已设置模式为SVC）
  22. #endif
  24. /*
  25. * 注意一些缓存的刷新和其他事务可能需要在这里完成
  26. * - is there an Angel SWI call for this?
  27. */
  29. /*
  30. * 一些构架的特定代码可以在这里被连接器插入，
  31. * 但是不应使用 r7（保存构架ID）, r8（保存内核启动参数地址）, and r9.
  32. */
  34. .text
  36. /*
  37. * 此处确定解压后的内核映像的绝对地址（物理地址），保存于r4
  38. * 由于配置的不同可能有的结果
  39. * （1）定义了CONFIG_AUTO_ZRELADDR
  40. *      ZRELADDR是已解压内核最终存放的物理地址
  41. *      如果AUTO_ZRELADDR被选择了, 这个地址将会在运行是确定：
  42. *      将当pc值和0xf8000000做与操作，
  43. *      并加上TEXT_OFFSET（内核最终存放的物理地址与内存起始的偏移）
  44. *      这里假定zImage被放在内存开始的128MB内
  45. * （2）没有定义CONFIG_AUTO_ZRELADDR
  46. *      直接使用zreladdr（此值位于arch/arm/mach-xxx/Makefile.boot文件确定）
  47. */
  48. #ifdef CONFIG_AUTO_ZRELADDR
  49. @ 确定内核映像地址
  50. mov r4, pc
  51. and r4, r4, #0xf8000000
  52. add r4, r4, #TEXT_OFFSET
  53. #else
  54. ldr r4, =zreladdr
  55. #endif
  57. bl cache_on /* 开启缓存（以及MMU） */
  59. restart: adr r0, LC0
  60. ldmia r0, {r1, r2, r3, r6, r10, r11, r12}
  61. ldr sp, [r0, #28]
  63. /*
  64. * 我们可能运行在一个与编译时定义的不同地址上，
  65. * 所以我们必须修正变量指针
  66. */
  67. sub r0, r0, r1 @ 计算偏移量
  68. add r6, r6, r0 @ 重新计算_edata
  69. add r10, r10, r0 @ 重新获得压缩后的内核大小数据位置
  71. /*
  72. * 内核编译系统将解压后的内核大小数据
  73. * 以小端格式
  74. * 附加在压缩数据的后面(其实是“gzip -f -9”命令的结果)
  75. * 下面代码的作用是将解压后的内核大小数据正确地放入r9中（避免了大小端问题）
  76. */
  77. ldrb r9, [r10, #0]
  78. ldrb lr, [r10, #1]
  79. orr r9, r9, lr, lsl #8
  80. ldrb lr, [r10, #2]
  81. ldrb r10, [r10, #3]
  82. orr r9, r9, lr, lsl #16
  83. orr r9, r9, r10, lsl #24
  85. /*
  86. * 下面代码的作用是将正确的当前执行映像的结束地址放入r10
  87. */
  88. #ifndef CONFIG_ZBOOT_ROM
  89. /* malloc 获取的内存空间位于重定向的栈指针之上 (64k max) */
  90. add sp, sp, r0
  91. add r10, sp, #0x10000
  92. #else
  93. /*
  94. * 如果定义了 ZBOOT_ROM， bss/stack 是非可重定位的,
  95. * 但有些人依然可以将其放在RAM中运行,
  96. * 这时我们可以参考 _edata.
  97. */
  98. mov r10, r6
  99. #endif
  101. /*
  102. * 检测我们是否会发生自我覆盖的问题
  103. * r4 = 解压后的内核起始地址（最终执行位置）
  104. * r9 = 解压后内核的大小
  105. * r10 = 当前执行映像的结束地址, 包含了 bss/stack/malloc 空间（假设是非XIP执行的）
  106. * 我们的基本需求是:
  107. * （若最终执行位置r4在当前映像之后）r4 - 16k 页目录 >= r10 -> OK
  108. * （若最终执行位置r4在当前映像之前）r4 + 解压后的内核大小 <= 当前位置 (pc) -> OK
  109. * 如果上面的条件不满足，就会自我覆盖，必须先搬运当前映像
  110. */
  111. add r10, r10, #16384
  112. cmp r4, r10         @ 假设最终执行位置r4在当前映像之后
  113. bhs wont_overwrite
  114. add r10, r4, r9     @ 假设最终执行位置r4在当前映像之前
  115. ARM( cmp r10, pc )  @ r10 = 解压后的内核结束地址
  116. THUMB( mov lr, pc )
  117. THUMB( cmp r10, lr )
  118. bls wont_overwrite
  120. /*
  121. * 将当前的映像重定向到解压后的内核之后（会发生自我覆盖时才执行，否则就被跳过）
  122. * r6 = _edata（已校正）
  123. * r10 = 解压后的内核结束地址
  124. * 因为我们要把当前映像向后移动, 所以我们必须由后往前复制代码，
  125. * 以防原数据和目标数据的重叠
  126. */
  127. /*
  128. * 将解压后的内核结束地址r10扩展（reloc_code_end - restart），
  129. * 并对齐到下一个256B边界。
  130. * 这样避免了当搬运的偏移较小时的自我覆盖
  131. */
  132. add r10, r10, #((reloc_code_end - restart + 256) & ~255)
  133. bic r10, r10, #255
  135. /* 获取需要搬运的当前映像的起始位置r5，并向下做32B对齐. */
  136. adr r5, restart
  137. bic r5, r5, #31
  139. sub r9, r6, r5 @ _edata - restart（已向下对齐）= 需要搬运的大小
  140. add r9, r9, #31
  141. bic r9, r9, #31 @ 做32B对齐 ，r9 = 需要搬运的大小
  142. add r6, r9, r5 @ r6 = 当前映像需要搬运的结束地址
  143. add r9, r9, r10 @ r9 = 当前映像搬运的目的地的结束地址
  145. /* 搬运当前执行映像，不包含 bss/stack/malloc 空间*/
  146. 1: ldmdb r6!, {r0 - r3, r10 - r12, lr}
  147. cmp r6, r5
  148. stmdb r9!, {r0 - r3, r10 - r12, lr}
  149. bhi 1b
  151. /* 保存偏移量，用来修改sp和实现代码跳转 */
  152. sub r6, r9, r6
  154. #ifndef CONFIG_ZBOOT_ROM
  155. /* cache_clean_flush 可能会使用栈，所以重定向sp指针 */
  156. add sp, sp, r6
  157. #endif
  159. bl cache_clean_flush @ 刷新缓存
  161. /* 通过搬运的偏移和当前的实际 restart 地址来实现代码跳转*/
  162. adr r0, BSYM(restart)
  163. add r0, r0, r6
  164. mov pc, r0
  165. /* 在上面的跳转之后，程序又从restart开始。
  166. * 但这次在检查自我覆盖的时候，新的执行位置必然满足
  167. * 最终执行位置r4在当前映像之前，r4 + 压缩后的内核大小 <= 当前位置 (pc)
  168. * 所以必然直接跳到了下面的wont_overwrite执行
  169. */
  172. wont_overwrite:
  173. /*
  174. * 如果delta（当前映像地址与编译时的地址偏移）为0, 我们运行的地址就是编译时确定的地址.
  175. * r0 = delta
  176. * r2 = BSS start（编译值）
  177. * r3 = BSS end（编译值）
  178. * r4 = 内核最终运行的物理地址
  179. * r7 = 构架ID(bootlodaer传递值)
  180. * r8 = 内核启动参数指针(bootlodaer传递值)
  181. * r11 = GOT start（编译值）
  182. * r12 = GOT end（编译值）
  183. * sp = stack pointer（修正值）
  184. */
  185. teq r0, #0 @测试delta值
  186. beq not_relocated @如果delta为0，无须对GOT表项和BSS进行重定位
  187. add r11, r11, r0 @重定位GOT start
  188. add r12, r12, r0 @重定位GOT end
  190. #ifndef CONFIG_ZBOOT_ROM
  191. /*
  192. * 如果内核配置 CONFIG_ZBOOT_ROM = n,
  193. * 我们必须修正BSS段的指针
  194. * 注意：sp已经被修正
  195. */
  196. add r2, r2, r0 @重定位BSS start
  197. add r3, r3, r0 @重定位BSS end
  199. /*
  200. * 重定位所有GOT表的入口项
  201. */
  202. 1: ldr r1, [r11, #0] @ 重定位GOT表的入口项
  203. add r1, r1, r0 @ 这个修正了 C 引用
  204. str r1, [r11], #4
  205. cmp r11, r12
  206. blo 1b
  207. #else
  209. /*
  210. * 重定位所有GOT表的入口项.
  211. * 我们只重定向在（已重定向后）BSS段外的入口
  212. */
  213. 1: ldr r1, [r11, #0] @ 重定位GOT表的入口项
  214. cmp r1, r2 @ entry < bss_start ||
  215. cmphs r3, r1 @ _end < entry table
  216. addlo r1, r1, r0 @ 这个修正了 C 引用
  217. str r1, [r11], #4
  218. cmp r11, r12
  219. blo 1b
  220. #endif
  222. /*
  223. * 至此当前映像的搬运和调整已经完成
  224. * 可以开始真正的工作的
  225. */
  226. not_relocated: mov r0, #0
  227. 1: str r0, [r2], #4 @ 清零 bss（初始化BSS段）
  228. str r0, [r2], #4
  229. str r0, [r2], #4
  230. str r0, [r2], #4
  231. cmp r2, r3
  232. blo 1b
  234. /*
  235. * C运行时环境已经充分建立.
  236. * 设置一些指针就可以解压内核了.
  237. * r4 = 内核最终运行的物理地址
  238. * r7 = 构架ID
  239. * r8 = 内核启动参数指针
  240. *
  241. * 下面对r0～r3的配置是decompress_kernel函数对应参数
  242. * r0 = 解压后的输出位置首地址
  243. * r1 = 可用RAM空间首地址
  244. * r2 = 可用RAM空间结束地址
  245. * r3 = 构架ID
  246. * 就是这个decompress_kernel（C函数）输出了"Uncompressing Linux..."
  247. * 以及" done, booting the kernel.\n"
  248. */
  249. mov r0, r4
  250. mov r1, sp @ malloc 获取的内存空间位于栈指针之上
  251. add r2, sp, #0x10000 @ 64k max
  252. mov r3, r7
  253. bl decompress_kernel
  254. /*
  255. * decompress_kernel(misc.c)--调用-->
  256. * do_decompress(decompress.c)--调用-->
  257. * decompress(../../../../lib/decompress_xxxx.c根据压缩方式的配置而不同)
  258. */
  260. /*
  261. * 以下是为跳入解压后的内核，再次做准备（恢复解压前的状态）
  262. */
  263. bl cache_clean_flush
  264. bl cache_off@ 数据缓存必须关闭（内核的要求）
  265. mov r0, #0 @ r0必须为0
  266. mov r1, r7@ 恢复构架ID到r1
  267. mov r2, r8 @ 恢复内核启动参数指针到r2
  268. mov pc, r4 @ 跳入解压后的内核映像(Image)入口（arch/arm/kernel/head.S）
  270. /*
  271. * 以下是为了确定当前运行时的地址和编译时确定的地址偏差，
  272. * 而将编译时确定的映像数据保存如下，用于检测对比
  273. */
  274. .align 2
  275. .type LC0, #object
  276. LC0: .word LC0 @ r1
  277. .word __bss_start @ r2
  278. .word _end @ r3
  279. .word _edata @ r6
  280. .word input_data_end - 4 @ r10 (inflated size location)
  281. .word _got_start @ r11
  282. .word _got_end @ ip
  283. .word .L_user_stack_end @ sp
  284. .size LC0, . - LC0
  286. #ifdef CONFIG_ARCH_RPC
  287. .globl params
  288. params: ldr r0, =0x10000100 @ params_phys for RPC
  289. mov pc, lr
  290. .ltorg
  291. .align
  292. #endif
  294. /*
  295. * 开启缓存.
  296. * 我们必须创建页表（并开启MMU）才可以开启数据和指令缓存。
  297. * 我们把页表（节描述符）放在内核执行地址前16k（0x4000）的空间中,
  298. * 且我们希望没人会去用这段地址空间.
  299. * 如果我们使用了,可能会出问题的!
  300. *
  301. * 进入时,
  302. * r4 = 内核最终运行的物理地址
  303. * r7 = 构架ID
  304. * r8 = 内核启动参数指针
  305. * 退出时,
  306. * r0, r1, r2, r3, r9, r10, r12 被修改
  307. * 此例程必须保护:
  308. * r4, r7, r8
  309. */
  310. .align 5
  311. cache_on: mov r3, #8 @ 调用cache_on 函数
  312. b call_cache_fn
  314. /*
  315. * Initialize the highest priority protection region, PR7
  316. * to cover all 32bit address and cacheable and bufferable.
  317. */
  318. __armv4_mpu_cache_on:
  319. mov r0, #0x3f @ 4G, the whole
  320. mcr p15, 0, r0, c6, c7, 0 @ PR7 Area Setting
  321. mcr p15, 0, r0, c6, c7, 1
  323. mov r0, #0x80 @ PR7
  324. mcr p15, 0, r0, c2, c0, 0 @ D-cache on
  325. mcr p15, 0, r0, c2, c0, 1 @ I-cache on
  326. mcr p15, 0, r0, c3, c0, 0 @ write-buffer on
  328. mov r0, #0xc000
  329. mcr p15, 0, r0, c5, c0, 1 @ I-access permission
  330. mcr p15, 0, r0, c5, c0, 0 @ D-access permission
  332. mov r0, #0
  333. mcr p15, 0, r0, c7, c10, 4 @ drain write buffer
  334. mcr p15, 0, r0, c7, c5, 0 @ flush(inval) I-Cache
  335. mcr p15, 0, r0, c7, c6, 0 @ flush(inval) D-Cache
  336. mrc p15, 0, r0, c1, c0, 0 @ read control reg
  337. @ ...I .... ..D. WC.M
  338. orr r0, r0, #0x002d @ .... .... ..1. 11.1
  339. orr r0, r0, #0x1000 @ ...1 .... .... ....
  341. mcr p15, 0, r0, c1, c0, 0 @ write control reg
  343. mov r0, #0
  344. mcr p15, 0, r0, c7, c5, 0 @ flush(inval) I-Cache
  345. mcr p15, 0, r0, c7, c6, 0 @ flush(inval) D-Cache
  346. mov pc, lr
  348. __armv3_mpu_cache_on:
  349. mov r0, #0x3f @ 4G, the whole
  350. mcr p15, 0, r0, c6, c7, 0 @ PR7 Area Setting
  352. mov r0, #0x80 @ PR7
  353. mcr p15, 0, r0, c2, c0, 0 @ cache on
  354. mcr p15, 0, r0, c3, c0, 0 @ write-buffer on
  356. mov r0, #0xc000
  357. mcr p15, 0, r0, c5, c0, 0 @ access permission
  359. mov r0, #0
  360. mcr p15, 0, r0, c7, c0, 0 @ invalidate whole cache v3
  361. /*
  362. * ?? ARMv3 MMU does not allow reading the control register,
  363. * does this really work on ARMv3 MPU?
  364. */
  365. mrc p15, 0, r0, c1, c0, 0 @ read control reg
  366. @ .... .... .... WC.M
  367. orr r0, r0, #0x000d @ .... .... .... 11.1
  368. /* ?? this overwrites the value constructed above? */
  369. mov r0, #0
  370. mcr p15, 0, r0, c1, c0, 0 @ write control reg
  372. /* ?? invalidate for the second time? */
  373. mcr p15, 0, r0, c7, c0, 0 @ invalidate whole cache v3
  374. mov pc, lr
  376. /*
  377. * 初始化MMU页表
  378. * 内核最终运行的物理地址向下16K的空间
  379. * 存放可以寻址4G空间节描述符
  380. * （16KB/4B=4K个描述符，每个描述符映射1MB空间，4K*1MB = 4GB）
  381. * 进入时,
  382. * r4 = 内核最终运行的物理地址
  383. * r7 = 构架ID
  384. * r8 = 内核启动参数指针
  385. * 退出时,
  386. * r0, r1, r2, r3, r9, r10 被修改
  387. * 此例程必须保护:
  388. * r4, r7, r8
  389. */
  390. __setup_mmu: sub r3, r4, #16384 @ 页目录大小为16K
  391. bic r3, r3, #0xff @ 页目录指针向下对齐
  392. bic r3, r3, #0x3f00 @ 对齐方式-16KB
  393. /*
  394. * 对于这个对齐，是MMU硬件的要求
  395. * 转换表基址寄存器（CP15的寄存器2）保存着第一级转换表基址的物理地址。
  396. * 只有bits[31:14]有效，bits[13:0]应该是零（SBZ）。
  397. * 所以第一级表必须16KB对齐。
  398. */
  400. /*
  401. * 初始化页表, 仅针对RAM（最大到256MB）开启
  402. * 缓存（cacheable）和缓冲（bufferable）位
  403. * r3 = 页目录基址(内核最终运行的物理地址向下16K的位置)
  404. */
  405. mov r0, r3 @ 页目录指针给r0
  406. mov r9, r0, lsr #18
  407. mov r9, r9, lsl #18 @ 通过移位清零低18bit，得到RAM基地址（推测值,r9）
  408. add r10, r9, #0x10000000 @ 加一个合理的RAM大小（猜测值） = RAM结束地址（猜测值,r10）
  409. mov r1, #0x12
  410. orr r1, r1, #3 << 10 @ 初始化节描述符r1 = 0b110000010010(完全访问:0域:XN:节)
  411. add r2, r3, #16384 @ r2 = 内核最终运行的物理地址（可能）
  412. 1: cmp r1, r9 @ if virt > start of RAM（针对RAM开启缓存和缓冲）
  413. #ifdef CONFIG_CPU_DCACHE_WRITETHROUGH
  414. orrhs r1, r1, #0x08 @ 设置 cacheable
  415. #else
  416. orrhs r1, r1, #0x0c @ 设置 cacheable, bufferable
  417. #endif
  418. cmp r1, r10 @ if virt > end of RAM
  419. bichs r1, r1, #0x0c @ 清除 cacheable, bufferable
  420. str r1, [r0], #4 @ 设置节描述符-1:1 映射（虚拟地址 == 物理地址）
  421. add r1, r1, #1048576 @ r1 + 1MB（每节管理的地址长度）下一个节描述符
  422. teq r0, r2
  423. bne 1b
  424. /*
  425. * 如果我们在flash中运行, 那么我们一定要为我们当前的代码开启缓存。
  426. * 我们映射2MB的代码，
  427. * 所以对于多达1MB压缩的内核没有映射重叠的问题？？
  428. * 如果我们在RAM中运行, 那么我们只需要完成上面的工作即可，下面重复了.
  429. */
  430. mov r1, #0x1e
  431. orr r1, r1, #3 << 10 @ 初始化节描述符r1 = 0b110000011110(完全访问:0域:XN:cacheable:bufferable:节)
  432. mov r2, pc
  433. mov r2, r2, lsr #20 @ 当前执行地址的节基址
  434. orr r1, r1, r2, lsl #20 @ 生成节描述符
  435. add r0, r3, r2, lsl #2 @ 获得页目录中相应的入口
  436. str r1, [r0], #4 @ 设置节描述符-1:1 映射（虚拟地址 == 物理地址）
  437. add r1, r1, #1048576 @ r1 + 1MB（每节管理的地址长度）下一个节描述符
  438. str r1, [r0] @ 设置节描述符（只做2MB映射）
  439. mov pc, lr
  440. ENDPROC(__setup_mmu)
  442. __arm926ejs_mmu_cache_on:
  443. #ifdef CONFIG_CPU_DCACHE_WRITETHROUGH
  444. mov r0, #4 @ put dcache in WT mode
  445. mcr p15, 7, r0, c15, c0, 0
  446. #endif
  448. __armv4_mmu_cache_on:
  449. mov r12, lr
  450. #ifdef CONFIG_MMU
  451. bl __setup_mmu
  452. mov r0, #0
  453. mcr p15, 0, r0, c7, c10, 4 @ drain write buffer
  454. mcr p15, 0, r0, c8, c7, 0 @ flush I,D TLBs
  455. mrc p15, 0, r0, c1, c0, 0 @ read control reg
  456. orr r0, r0, #0x5000 @ I-cache enable, RR cache replacement
  457. orr r0, r0, #0x0030
  458. #ifdef CONFIG_CPU_ENDIAN_BE8
  459. orr r0, r0, #1 << 25 @ big-endian page tables
  460. #endif
  461. bl __common_mmu_cache_on
  462. mov r0, #0
  463. mcr p15, 0, r0, c8, c7, 0 @ flush I,D TLBs
  464. #endif
  465. mov pc, r12
  467. __armv7_mmu_cache_on:
  468. mov r12, lr @保存lr到r12
  469. #ifdef CONFIG_MMU
  470. mrc p15, 0, r11, c0, c1, 4 @ 读取CP15的ID_MMFR0（内存模块特性）寄存器
  471. tst r11, #0xf @ 测试VMSA（虚拟内存系统构架）A8 = 0x3
  472. blne __setup_mmu @ 如果VMSA不是0xf，就进入mmu页表初始化（节模式）
  473. mov r0, #0
  474. mcr p15, 0, r0, c7, c10, 4 @ 数据内存屏障（保证上面的写操作完成才继续）
  475. tst r11, #0xf @ 测试VMSA（虚拟内存系统构架）A8 = 0x3
  476. mcrne p15, 0, r0, c8, c7, 0 @ flush I,D TLBs缓存
  477. #endif
  478. mrc p15, 0, r0, c1, c0, 0 @ 读系统控制寄存器
  479. orr r0, r0, #0x5000 @ I-cache 使能, RR cache replacement
  480. orr r0, r0, #0x003c @ write buffer
  481. #ifdef CONFIG_MMU
  482. #ifdef CONFIG_CPU_ENDIAN_BE8
  483. orr r0, r0, #1 << 25 @ 大端模式页表
  484. #endif
  485. orrne r0, r0, #1 @ 设置MMU 开启位
  486. movne r1, #-1
  487. mcrne p15, 0, r3, c2, c0, 0 @ 载入页表基址到TTBR0
  488. mcrne p15, 0, r1, c3, c0, 0 @ 载入域访问控制数据到DACR（所有域都是Manager，所以XN会被忽略）
  489. #endif
  490. mcr p15, 0, r0, c1, c0, 0 @ 写系统控制寄存器
  491. mrc p15, 0, r0, c1, c0, 0 @ 回读系统控制寄存器
  492. mov r0, #0
  493. mcr p15, 0, r0, c7, c5, 4 @ 指令同步屏障（确保上面指令完成才返回）
  494. mov pc, r12 @ 此处返回（此时MMU已启用，RAM缓存已开启）
  496. __fa526_cache_on:
  497. mov r12, lr
  498. bl __setup_mmu
  499. mov r0, #0
  500. mcr p15, 0, r0, c7, c7, 0 @ Invalidate whole cache
  501. mcr p15, 0, r0, c7, c10, 4 @ drain write buffer
  502. mcr p15, 0, r0, c8, c7, 0 @ flush UTLB
  503. mrc p15, 0, r0, c1, c0, 0 @ read control reg
  504. orr r0, r0, #0x1000 @ I-cache enable
  505. bl __common_mmu_cache_on
  506. mov r0, #0
  507. mcr p15, 0, r0, c8, c7, 0 @ flush UTLB
  508. mov pc, r12
  510. __arm6_mmu_cache_on:
  511. mov r12, lr
  512. bl __setup_mmu
  513. mov r0, #0
  514. mcr p15, 0, r0, c7, c0, 0 @ invalidate whole cache v3
  515. mcr p15, 0, r0, c5, c0, 0 @ invalidate whole TLB v3
  516. mov r0, #0x30
  517. bl __common_mmu_cache_on
  518. mov r0, #0
  519. mcr p15, 0, r0, c5, c0, 0 @ invalidate whole TLB v3
  520. mov pc, r12
  522. __common_mmu_cache_on:
  523. #ifndef CONFIG_THUMB2_KERNEL
  524. #ifndef DEBUG
  525. orr r0, r0, #0x000d @ Write buffer, mmu
  526. #endif
  527. mov r1, #-1
  528. mcr p15, 0, r3, c2, c0, 0 @ load page table pointer
  529. mcr p15, 0, r1, c3, c0, 0 @ load domain access control
  530. b 1f
  531. .align 5 @ cache line aligned
  532. 1: mcr p15, 0, r0, c1, c0, 0 @ load control register
  533. mrc p15, 0, r0, c1, c0, 0 @ and read it back to
  534. sub pc, lr, r0, lsr #32 @ properly flush pipeline
  535. #endif
  537. #define PROC_ENTRY_SIZE (4*5)
  539. /*
  540. * 这里是为不同的处理器提供遵循可重定向缓存支持的函数
  541. * 这是一个通用的为 定位入口 和 跳入一个（从块起始处到）特定偏移的指令 的钩子函数。
  542. * 请注意这是一个位置无关代码。
  543. *
  544. * r1 = 被修改
  545. * r2 = 被修改
  546. * r3 = 相对每个入口的功能函数位置偏移（on:#08|off:#12|flush:#16）
  547. * r9 = 被修改
  548. * r12 = 被修改
  549. */
  551. call_cache_fn: adr r12, proc_types
  552. #ifdef CONFIG_CPU_CP15
  553. mrc p15, 0, r9, c0, c0 @ 动态获取处理器ID
  554. #else
  555. ldr r9, =CONFIG_PROCESSOR_ID @ 使用预编译的处理器ID
  556. #endif
  557. 1: ldr r1, [r12, #0] @ 获取ID值
  558. ldr r2, [r12, #4] @ 获取对应的掩码
  559. eor r1, r1, r9 @ (real ^ match) 检测是否匹配
  560. tst r1, r2 @ & mask 将检测结果做掩码
  561. ARM( addeq pc, r12, r3 ) @ 如果匹配就调用缓存函数
  562. THUMB( addeq r12, r3 )
  563. THUMB( moveq pc, r12 ) @ call cache function
  564. add r12, r12, #PROC_ENTRY_SIZE @ 如果不匹配就跳过这个入口，进入下个测试
  565. b 1b
  567. /*
  568. * 缓存操作表. 这些是最基本的:
  569. * - CPU ID 匹配
  570. * - CPU ID 掩码
  571. * - 'cache on' 方法代码
  572. * - 'cache off' 方法代码
  573. * - 'cache flush' 方法代码
  574. *
  575. * 我们通过这个公式匹配入口: ((real_id ^ match) & mask) == 0
  576. *
  577. * 写通式缓存一般只需要 'on' 和 'off' 方法
  578. * 回写式缓存必须有 flush 方法定义
  579. *
  580. */
  581. .align 2
  582. .type proc_types,#object
  583. proc_types:
  584. .word 0x41560600 @ ARM6/610
  585. .word 0xffffffe0
  586. W(b) __arm6_mmu_cache_off @ 可以使用但是较慢
  587. W(b) __arm6_mmu_cache_off
  588. mov pc, lr
  589. THUMB( nop )
  590. @ b __arm6_mmu_cache_on @ 未测试
  591. @ b __arm6_mmu_cache_off
  592. @ b __armv3_mmu_cache_flush
  594. .word 0x00000000 @ old ARM ID
  595. .word 0x0000f000
  596. mov pc, lr
  597. THUMB( nop )
  598. mov pc, lr
  599. THUMB( nop )
  600. mov pc, lr
  601. THUMB( nop )
  603. .word 0x41007000 @ ARM7/710
  604. .word 0xfff8fe00
  605. W(b) __arm7_mmu_cache_off
  606. W(b) __arm7_mmu_cache_off
  607. mov pc, lr
  608. THUMB( nop )
  610. .word 0x41807200 @ ARM720T (写通式)
  611. .word 0xffffff00
  612. W(b) __armv4_mmu_cache_on
  613. W(b) __armv4_mmu_cache_off
  614. mov pc, lr
  615. THUMB( nop )
  617. .word 0x41007400 @ ARM74x
  618. .word 0xff00ff00
  619. W(b) __armv3_mpu_cache_on
  620. W(b) __armv3_mpu_cache_off
  621. W(b) __armv3_mpu_cache_flush
  623. .word 0x41009400 @ ARM94x
  624. .word 0xff00ff00
  625. W(b) __armv4_mpu_cache_on
  626. W(b) __armv4_mpu_cache_off
  627. W(b) __armv4_mpu_cache_flush
  629. .word 0x41069260 @ ARM926EJ-S (v5TEJ)
  630. .word 0xff0ffff0
  631. W(b) __arm926ejs_mmu_cache_on
  632. W(b) __armv4_mmu_cache_off
  633. W(b) __armv5tej_mmu_cache_flush
  635. .word 0x00007000 @ ARM7 IDs
  636. .word 0x0000f000
  637. mov pc, lr
  638. THUMB( nop )
  639. mov pc, lr
  640. THUMB( nop )
  641. mov pc, lr
  642. THUMB( nop )
  644. @ 以下使用新的 ID 系统.
  646. .word 0x4401a100 @ sa110 / sa1100
  647. .word 0xffffffe0
  648. W(b) __armv4_mmu_cache_on
  649. W(b) __armv4_mmu_cache_off
  650. W(b) __armv4_mmu_cache_flush
  652. .word 0x6901b110 @ sa1110
  653. .word 0xfffffff0
  654. W(b) __armv4_mmu_cache_on
  655. W(b) __armv4_mmu_cache_off
  656. W(b) __armv4_mmu_cache_flush
  658. .word 0x56056900
  659. .word 0xffffff00 @ PXA9xx
  660. W(b) __armv4_mmu_cache_on
  661. W(b) __armv4_mmu_cache_off
  662. W(b) __armv4_mmu_cache_flush
  664. .word 0x56158000 @ PXA168
  665. .word 0xfffff000
  666. W(b) __armv4_mmu_cache_on
  667. W(b) __armv4_mmu_cache_off
  668. W(b) __armv5tej_mmu_cache_flush
  670. .word 0x56050000 @ Feroceon
  671. .word 0xff0f0000
  672. W(b) __armv4_mmu_cache_on
  673. W(b) __armv4_mmu_cache_off
  674. W(b) __armv5tej_mmu_cache_flush
  676. #ifdef CONFIG_CPU_FEROCEON_OLD_ID
  677. /* this conflicts with the standard ARMv5TE entry */
  678. .long 0x41009260 @ Old Feroceon
  679. .long 0xff00fff0
  680. b __armv4_mmu_cache_on
  681. b __armv4_mmu_cache_off
  682. b __armv5tej_mmu_cache_flush
  683. #endif
  685. .word 0x66015261 @ FA526
  686. .word 0xff01fff1
  687. W(b) __fa526_cache_on
  688. W(b) __armv4_mmu_cache_off
  689. W(b) __fa526_cache_flush
  691. @ 这些匹配构架ID
  693. .word 0x00020000 @ ARMv4T
  694. .word 0x000f0000
  695. W(b) __armv4_mmu_cache_on
  696. W(b) __armv4_mmu_cache_off
  697. W(b) __armv4_mmu_cache_flush
  699. .word 0x00050000 @ ARMv5TE
  700. .word 0x000f0000
  701. W(b) __armv4_mmu_cache_on
  702. W(b) __armv4_mmu_cache_off
  703. W(b) __armv4_mmu_cache_flush
  705. .word 0x00060000 @ ARMv5TEJ
  706. .word 0x000f0000
  707. W(b) __armv4_mmu_cache_on
  708. W(b) __armv4_mmu_cache_off
  709. W(b) __armv5tej_mmu_cache_flush
  711. .word 0x0007b000 @ ARMv6
  712. .word 0x000ff000
  713. W(b) __armv4_mmu_cache_on
  714. W(b) __armv4_mmu_cache_off
  715. W(b) __armv6_mmu_cache_flush
  717. .word 0x000f0000 @ new CPU Id
  718. .word 0x000f0000
  719. W(b) __armv7_mmu_cache_on
  720. W(b) __armv7_mmu_cache_off
  721. W(b) __armv7_mmu_cache_flush
  723. .word 0 @ 未识别类型
  724. .word 0
  725. mov pc, lr
  726. THUMB( nop )
  727. mov pc, lr
  728. THUMB( nop )
  729. mov pc, lr
  730. THUMB( nop )
  732. .size proc_types, . - proc_types
  734. /*
  735. * 如果你获得了一个 "非常量的表达式".如果汇编器从这行返回" 申明"错误
  736. * 请检查下你是否偶尔在应该使用“W(b)”的地方写了"b"指令
  737. * 这是一个缓存方法跳转表的对齐检查机制
  738. * 在写汇编的时候可以借鉴
  739. */
  740. .if (. - proc_types) % PROC_ENTRY_SIZE != 0
  741. .error "The size of one or more proc_types entries is wrong."
  742. .endif
  744. /*
  745. * 关闭缓存和MMU. ARMv3不支持控制寄存器的读取，
  746. * 但ARMv4支持.
  747. *
  748. * 在退出时,
  749. * r0, r1, r2, r3, r9, r12 被篡改
  750. * 这个例程必须保护:
  751. * r4, r7, r8
  752. */
  753. .align 5
  754. cache_off: mov r3, #12 @ 缓存关闭函数
  755. b call_cache_fn
  757. __armv4_mpu_cache_off:
  758. mrc p15, 0, r0, c1, c0
  759. bic r0, r0, #0x000d
  760. mcr p15, 0, r0, c1, c0 @ turn MPU and cache off
  761. mov r0, #0
  762. mcr p15, 0, r0, c7, c10, 4 @ drain write buffer
  763. mcr p15, 0, r0, c7, c6, 0 @ flush D-Cache
  764. mcr p15, 0, r0, c7, c5, 0 @ flush I-Cache
  765. mov pc, lr
  767. __armv3_mpu_cache_off:
  768. mrc p15, 0, r0, c1, c0
  769. bic r0, r0, #0x000d
  770. mcr p15, 0, r0, c1, c0, 0 @ turn MPU and cache off
  771. mov r0, #0
  772. mcr p15, 0, r0, c7, c0, 0 @ invalidate whole cache v3
  773. mov pc, lr
  775. __armv4_mmu_cache_off:
  776. #ifdef CONFIG_MMU
  777. mrc p15, 0, r0, c1, c0
  778. bic r0, r0, #0x000d
  779. mcr p15, 0, r0, c1, c0 @ turn MMU and cache off
  780. mov r0, #0
  781. mcr p15, 0, r0, c7, c7 @ invalidate whole cache v4
  782. mcr p15, 0, r0, c8, c7 @ invalidate whole TLB v4
  783. #endif
  784. mov pc, lr
  786. __armv7_mmu_cache_off:
  787. mrc p15, 0, r0, c1, c0 @ 读取系统控制寄存器SCTLR
  788. #ifdef CONFIG_MMU
  789. bic r0, r0, #0x000d @ 清零MMU和cache使能位
  790. #else
  791. bic r0, r0, #0x000c @ 清零cache使能位
  792. #endif
  793. mcr p15, 0, r0, c1, c0 @ 关闭MMU和cache
  794. mov r12, lr @ 保存lr到r12
  795. bl __armv7_mmu_cache_flush
  796. mov r0, #0
  797. #ifdef CONFIG_MMU
  798. mcr p15, 0, r0, c8, c7, 0 @ 废止整个TLB
  799. #endif
  800. mcr p15, 0, r0, c7, c5, 6 @ 废止BTC
  801. mcr p15, 0, r0, c7, c10, 4 @ 数据同步屏障
  802. mcr p15, 0, r0, c7, c5, 4 @ 指令同步屏障（确保上面指令完成才返回）
  803. mov pc, r12
  805. __arm6_mmu_cache_off:
  806. mov r0, #0x00000030 @ ARM6 control reg.
  807. b __armv3_mmu_cache_off
  809. __arm7_mmu_cache_off:
  810. mov r0, #0x00000070 @ ARM7 control reg.
  811. b __armv3_mmu_cache_off
  813. __armv3_mmu_cache_off:
  814. mcr p15, 0, r0, c1, c0, 0 @ turn MMU and cache off
  815. mov r0, #0
  816. mcr p15, 0, r0, c7, c0, 0 @ invalidate whole cache v3
  817. mcr p15, 0, r0, c5, c0, 0 @ invalidate whole TLB v3
  818. mov pc, lr
  820. /*
  821. * 清空和flush缓存以保持一致性
  822. *
  823. * 退出时,
  824. * r1, r2, r3, r9, r10, r11, r12 被篡改
  825. * 这个例程必须保护:
  826. * r4, r6, r7, r8
  827. */
  828. .align 5
  829. cache_clean_flush:
  830. mov r3, #16
  831. b call_cache_fn
  833. __armv4_mpu_cache_flush:
  834. mov r2, #1
  835. mov r3, #0
  836. mcr p15, 0, ip, c7, c6, 0 @ invalidate D cache
  837. mov r1, #7 << 5 @ 8 segments
  838. 1: orr r3, r1, #63 << 26 @ 64 entries
  839. 2: mcr p15, 0, r3, c7, c14, 2 @ clean & invalidate D index
  840. subs r3, r3, #1 << 26
  841. bcs 2b @ entries 63 to 0
  842. subs r1, r1, #1 << 5
  843. bcs 1b @ segments 7 to 0
  845. teq r2, #0
  846. mcrne p15, 0, ip, c7, c5, 0 @ invalidate I cache
  847. mcr p15, 0, ip, c7, c10, 4 @ drain WB
  848. mov pc, lr
  850. __fa526_cache_flush:
  851. mov r1, #0
  852. mcr p15, 0, r1, c7, c14, 0 @ clean and invalidate D cache
  853. mcr p15, 0, r1, c7, c5, 0 @ flush I cache
  854. mcr p15, 0, r1, c7, c10, 4 @ drain WB
  855. mov pc, lr
  857. __armv6_mmu_cache_flush:
  858. mov r1, #0
  859. mcr p15, 0, r1, c7, c14, 0 @ clean+invalidate D
  860. mcr p15, 0, r1, c7, c5, 0 @ invalidate I+BTB
  861. mcr p15, 0, r1, c7, c15, 0 @ clean+invalidate unified
  862. mcr p15, 0, r1, c7, c10, 4 @ drain WB
  863. mov pc, lr
  865. __armv7_mmu_cache_flush:
  866. mrc p15, 0, r10, c0, c1, 5 @ read ID_MMFR1
  867. tst r10, #0xf << 16 @ hierarchical cache (ARMv7)
  868. mov r10, #0
  869. beq hierarchical
  870. mcr p15, 0, r10, c7, c14, 0 @ clean+invalidate D
  871. b iflush
  872. hierarchical:
  873. mcr p15, 0, r10, c7, c10, 5 @ DMB
  874. stmfd sp!, {r0-r7, r9-r11}
  875. mrc p15, 1, r0, c0, c0, 1 @ read clidr
  876. ands r3, r0, #0x7000000 @ extract loc from clidr
  877. mov r3, r3, lsr #23 @ left align loc bit field
  878. beq finished @ if loc is 0, then no need to clean
  879. mov r10, #0 @ start clean at cache level 0
  880. loop1:
  881. add r2, r10, r10, lsr #1 @ work out 3x current cache level
  882. mov r1, r0, lsr r2 @ extract cache type bits from clidr
  883. and r1, r1, #7 @ mask of the bits for current cache only
  884. cmp r1, #2 @ see what cache we have at this level
  885. blt skip @ skip if no cache, or just i-cache
  886. mcr p15, 2, r10, c0, c0, 0 @ select current cache level in cssr
  887. mcr p15, 0, r10, c7, c5, 4 @ isb to sych the new cssr&csidr
  888. mrc p15, 1, r1, c0, c0, 0 @ read the new csidr
  889. and r2, r1, #7 @ extract the length of the cache lines
  890. add r2, r2, #4 @ add 4 (line length offset)
  891. ldr r4, =0x3ff
  892. ands r4, r4, r1, lsr #3 @ find maximum number on the way size
  893. clz r5, r4 @ find bit position of way size increment
  894. ldr r7, =0x7fff
  895. ands r7, r7, r1, lsr #13 @ extract max number of the index size
  896. loop2:
  897. mov r9, r4 @ create working copy of max way size
  898. loop3:
  899. ARM( orr r11, r10, r9, lsl r5 ) @ factor way and cache number into r11
  900. ARM( orr r11, r11, r7, lsl r2 ) @ factor index number into r11
  901. THUMB( lsl r6, r9, r5 )
  902. THUMB( orr r11, r10, r6 ) @ factor way and cache number into r11
  903. THUMB( lsl r6, r7, r2 )
  904. THUMB( orr r11, r11, r6 ) @ factor index number into r11
  905. mcr p15, 0, r11, c7, c14, 2 @ clean & invalidate by set/way
  906. subs r9, r9, #1 @ decrement the way
  907. bge loop3
  908. subs r7, r7, #1 @ decrement the index
  909. bge loop2
  910. skip:
  911. add r10, r10, #2 @ increment cache number
  912. cmp r3, r10
  913. bgt loop1
  914. finished:
  915. ldmfd sp!, {r0-r7, r9-r11}
  916. mov r10, #0 @ swith back to cache level 0
  917. mcr p15, 2, r10, c0, c0, 0 @ select current cache level in cssr
  918. iflush:
  919. mcr p15, 0, r10, c7, c10, 4 @ DSB
  920. mcr p15, 0, r10, c7, c5, 0 @ invalidate I+BTB
  921. mcr p15, 0, r10, c7, c10, 4 @ DSB
  922. mcr p15, 0, r10, c7, c5, 4 @ ISB
  923. mov pc, lr
  925. __armv5tej_mmu_cache_flush:
  926. 1: mrc p15, 0, r15, c7, c14, 3 @ test,clean,invalidate D cache
  927. bne 1b
  928. mcr p15, 0, r0, c7, c5, 0 @ flush I cache
  929. mcr p15, 0, r0, c7, c10, 4 @ drain WB
  930. mov pc, lr
  932. __armv4_mmu_cache_flush:
  933. mov r2, #64*1024 @ default: 32K dcache size (*2)
  934. mov r11, #32 @ default: 32 byte line size
  935. mrc p15, 0, r3, c0, c0, 1 @ read cache type
  936. teq r3, r9 @ cache ID register present?
  937. beq no_cache_id
  938. mov r1, r3, lsr #18
  939. and r1, r1, #7
  940. mov r2, #1024
  941. mov r2, r2, lsl r1 @ base dcache size *2
  942. tst r3, #1 << 14 @ test M bit
  943. addne r2, r2, r2, lsr #1 @ +1/2 size if M == 1
  944. mov r3, r3, lsr #12
  945. and r3, r3, #3
  946. mov r11, #8
  947. mov r11, r11, lsl r3 @ cache line size in bytes
  948. no_cache_id:
  949. mov r1, pc
  950. bic r1, r1, #63 @ align to longest cache line
  951. add r2, r1, r2
  952. 1:
  953. ARM( ldr r3, [r1], r11 ) @ s/w flush D cache
  954. THUMB( ldr r3, [r1] ) @ s/w flush D cache
  955. THUMB( add r1, r1, r11 )
  956. teq r1, r2
  957. bne 1b
  959. mcr p15, 0, r1, c7, c5, 0 @ flush I cache
  960. mcr p15, 0, r1, c7, c6, 0 @ flush D cache
  961. mcr p15, 0, r1, c7, c10, 4 @ drain WB
  962. mov pc, lr
  964. __armv3_mmu_cache_flush:
  965. __armv3_mpu_cache_flush:
  966. mov r1, #0
  967. mcr p15, 0, r1, c7, c0, 0 @ invalidate whole cache v3
  968. mov pc, lr
  970. /*
  971. * Various debugging routines for printing hex characters and
  972. * memory, which again must be relocatable.
  973. */
  974. #ifdef DEBUG
  975. .align 2
  976. .type phexbuf,#object
  977. phexbuf: .space 12
  978. .size phexbuf, . - phexbuf
  980. @ phex corrupts {r0, r1, r2, r3}
  981. phex: adr r3, phexbuf
  982. mov r2, #0
  983. strb r2, [r3, r1]
  984. 1: subs r1, r1, #1
  985. movmi r0, r3
  986. bmi puts
  987. and r2, r0, #15
  988. mov r0, r0, lsr #4
  989. cmp r2, #10
  990. addge r2, r2, #7
  991. add r2, r2, #'0'
  992. strb r2, [r3, r1]
  993. b 1b
  995. @ puts corrupts {r0, r1, r2, r3}
  996. puts: loadsp r3, r1
  997. 1: ldrb r2, [r0], #1
  998. teq r2, #0
  999. moveq pc, lr
  1000. 2: writeb r2, r3
  1001. mov r1, #0x00020000
  1002. 3: subs r1, r1, #1
  1003. bne 3b
  1004. teq r2, #'\n'
  1005. moveq r2, #'\r'
  1006. beq 2b
  1007. teq r0, #0
  1008. bne 1b
  1009. mov pc, lr
  1010. @ putc corrupts {r0, r1, r2, r3}
  1011. putc:
  1012. mov r2, r0
  1013. mov r0, #0
  1014. loadsp r3, r1
  1015. b 2b
  1017. @ memdump corrupts {r0, r1, r2, r3, r10, r11, r12, lr}
  1018. memdump: mov r12, r0
  1019. mov r10, lr
  1020. mov r11, #0
  1021. 2: mov r0, r11, lsl #2
  1022. add r0, r0, r12
  1023. mov r1, #8
  1024. bl phex
  1025. mov r0, #':'
  1026. bl putc
  1027. 1: mov r0, #' '
  1028. bl putc
  1029. ldr r0, [r12, r11, lsl #2]
  1030. mov r1, #8
  1031. bl phex
  1032. and r0, r11, #7
  1033. teq r0, #3
  1034. moveq r0, #' '
  1035. bleq putc
  1036. and r0, r11, #7
  1037. add r11, r11, #1
  1038. teq r0, #7
  1039. bne 1b
  1040. mov r0, #'\n'
  1041. bl putc
  1042. cmp r11, #64
  1043. blt 2b
  1044. mov pc, r10
  1045. #endif
  1047. .ltorg
  1048. reloc_code_end:
  1050. .align
  1051. .section ".stack", "aw", %nobits
  1052. .L_user_stack: .space 4096
  1053. .L_user_stack_end:

     看了上面的源码，可能就算是分析过了也是比较模糊的，通过下面的一个代码流程图，大家就可以清楚的了解内核自解压的全过程了：

Linux内核源码分析--内核启动之(1)zImage自解压过程（Linux-3.0 ARMv7）


标签：

相关文章