关于md5 帮顶有分！

在网上搜了一大圈，代码及例程也下了不少，都是只有对字符串进行md5计算的，没有对一个文件进行md5计算的。
   也找到很多应用程序，就有对文件操作的，然而没有控件或dll，没办法调用。好不容易找到一段源代码，运行结果吓了一跳，一个100K的文件，计算了5分钟还没有结果。

   各位大哥大姐帮帮忙，给一个能在程序中调用与加载的，可以对某个指定文件进行md5计算的控件或函数，小弟先谢谢了。

Email: Yorkness@163.com
QQ:    75665338

9 个解决方案

#1

不需要对整个文件作MD5计算吧？
从文件中提取一部分来作MD5计算也可以吧

#2

见过一个比较完整的

就是忘记在那见过了

#3

编译有运行

Option Explicit

Private Const OFFSET_4 = 4294967296#
Private Const MAXINT_4 = 2147483647
Private State() As Long
Private ByteCounter As Long
Private ByteBuffer() As Byte
Private Const S11 = 7
Private Const S12 = 12
Private Const S13 = 17
Private Const S14 = 22
Private Const S21 = 5
Private Const S22 = 9
Private Const S23 = 14
Private Const S24 = 20
Private Const S31 = 4
Private Const S32 = 11
Private Const S33 = 16
Private Const S34 = 23
Private Const S41 = 6
Private Const S42 = 10
Private Const S43 = 15
Private Const S44 = 21

Public Function Md5_String_Calc(SourceString As String) As String
    Call Init
    MD5Init
    MD5Update LenB(StrConv(SourceString, vbFromUnicode)), StringToArray(SourceString)
    MD5Final
    Md5_String_Calc = GetValues
End Function

Public Function Md5_File_Calc(InFile As String) As String
    Call Init
    On Error GoTo Errorhandler:
    GoSub begin
Errorhandler:
    '    DigestFileToHexStr = ""
    Exit Function

begin:
    Dim FileO As Integer
    FileO = FreeFile
    Call FileLen(InFile)
    Open InFile For Binary Access Read As #FileO
    MD5Init
    Do While Not EOF(FileO)
        Get #FileO, , ByteBuffer
        If Loc(FileO) < LOF(FileO) Then
            ByteCounter = ByteCounter + 64
            MD5Transform ByteBuffer
        End If
    Loop
    ByteCounter = ByteCounter + (LOF(FileO) Mod 64)
    Close #FileO
    MD5Final
    Md5_File_Calc = GetValues
End Function

Private Sub Init()
    ReDim State(1 To 4)
    ReDim ByteBuffer(0 To 63)
End Sub

Private Property Get RegisterA() As String
    RegisterA = State(1)
End Property
Private Property Get RegisterB() As String
    RegisterB = State(2)
End Property

Private Property Get RegisterC() As String
    RegisterC = State(3)
End Property

Private Property Get RegisterD() As String
    RegisterD = State(4)
End Property

Private Function StringToArray(InString As String) As Byte()
    Dim i As Integer, bytBuffer() As Byte
    ReDim bytBuffer(LenB(StrConv(InString, vbFromUnicode)))
    bytBuffer = StrConv(InString, vbFromUnicode)
    StringToArray = bytBuffer
End Function
Private Function GetValues() As String
    GetValues = LongToString(State(1)) & LongToString(State(2)) & LongToString(State(3)) & LongToString(State(4))
End Function
Private Function LongToString(Num As Long) As String
    Dim a As Byte, b As Byte, C As Byte, D As Byte
    a = Num And &HFF&
    If a < 16 Then LongToString = "0" & Hex(a) Else LongToString = Hex(a)
    b = (Num And &HFF00&) \ 256
    If b < 16 Then LongToString = LongToString & "0" & Hex(b) Else LongToString = LongToString & Hex(b)
    C = (Num And &HFF0000) \ 65536
    If C < 16 Then LongToString = LongToString & "0" & Hex(C) Else LongToString = LongToString & Hex(C)
    If Num < 0 Then D = ((Num And &H7F000000) \ 16777216) Or &H80& Else D = (Num And &HFF000000) \ 16777216
    If D < 16 Then LongToString = LongToString & "0" & Hex(D) Else LongToString = LongToString & Hex(D)
End Function

#4

Private Sub Decode(Length As Integer, OutputBuffer() As Long, InputBuffer() As Byte)
    Dim intDblIndex As Integer, intByteIndex As Integer, dblSum As Double
    For intByteIndex = 0 To Length - 1 Step 4
        dblSum = InputBuffer(intByteIndex) + InputBuffer(intByteIndex + 1) * 256# + InputBuffer(intByteIndex + 2) * 65536# + InputBuffer(intByteIndex + 3) * 16777216#
        OutputBuffer(intDblIndex) = UnsignedToLong(dblSum)
        intDblIndex = intDblIndex + 1
    Next intByteIndex
End Sub
Private Function FF(a As Long, b As Long, C As Long, D As Long, x As Long, S As Long, ac As Long) As Long
    a = LongOverflowAdd4(a, (b And C) Or (Not (b) And D), x, ac)
    a = LongLeftRotate(a, S)
    a = LongOverflowAdd(a, b)
End Function
Private Function GG(a As Long, b As Long, C As Long, D As Long, x As Long, S As Long, ac As Long) As Long
    a = LongOverflowAdd4(a, (b And D) Or (C And Not (D)), x, ac)
    a = LongLeftRotate(a, S)
    a = LongOverflowAdd(a, b)
End Function
Private Function HH(a As Long, b As Long, C As Long, D As Long, x As Long, S As Long, ac As Long) As Long
    a = LongOverflowAdd4(a, b Xor C Xor D, x, ac)
    a = LongLeftRotate(a, S)
    a = LongOverflowAdd(a, b)
End Function
Private Function II(a As Long, b As Long, C As Long, D As Long, x As Long, S As Long, ac As Long) As Long
    a = LongOverflowAdd4(a, C Xor (b Or Not (D)), x, ac)
    a = LongLeftRotate(a, S)
    a = LongOverflowAdd(a, b)
End Function

Private Function LongLeftRotate(Value As Long, Bits As Long) As Long
    Dim lngSign As Long, lngI As Long
    Bits = Bits Mod 32
    If Bits = 0 Then LongLeftRotate = Value: Exit Function
    For lngI = 1 To Bits
        lngSign = Value And &HC0000000
        Value = (Value And &H3FFFFFFF) * 2
        Value = Value Or ((lngSign < 0) And 1) Or (CBool(lngSign And &H40000000) And &H80000000)
    Next
    LongLeftRotate = Value
End Function
Private Function LongOverflowAdd(Val1 As Long, Val2 As Long) As Long
    Dim lngHighWord As Long, lngLowWord As Long, lngOverflow As Long
    lngLowWord = (Val1 And &HFFFF&) + (Val2 And &HFFFF&)
    lngOverflow = lngLowWord \ 65536
    lngHighWord = (((Val1 And &HFFFF0000) \ 65536) + ((Val2 And &HFFFF0000) \ 65536) + lngOverflow) And &HFFFF&
    LongOverflowAdd = UnsignedToLong((lngHighWord * 65536#) + (lngLowWord And &HFFFF&))
End Function
Private Function LongOverflowAdd4(Val1 As Long, Val2 As Long, val3 As Long, val4 As Long) As Long
    Dim lngHighWord As Long, lngLowWord As Long, lngOverflow As Long
    lngLowWord = (Val1 And &HFFFF&) + (Val2 And &HFFFF&) + (val3 And &HFFFF&) + (val4 And &HFFFF&)
    lngOverflow = lngLowWord \ 65536
    lngHighWord = (((Val1 And &HFFFF0000) \ 65536) + ((Val2 And &HFFFF0000) \ 65536) + ((val3 And &HFFFF0000) \ 65536) + ((val4 And &HFFFF0000) \ 65536) + lngOverflow) And &HFFFF&
    LongOverflowAdd4 = UnsignedToLong((lngHighWord * 65536#) + (lngLowWord And &HFFFF&))
End Function

Private Function UnsignedToLong(Value As Double) As Long
    If Value < 0 Or Value >= OFFSET_4 Then Error 6
    If Value <= MAXINT_4 Then UnsignedToLong = Value Else UnsignedToLong = Value - OFFSET_4
End Function
Private Function LongToUnsigned(Value As Long) As Double
    If Value < 0 Then LongToUnsigned = Value + OFFSET_4 Else LongToUnsigned = Value
End Function

#5

Private Sub MD5Init()
    ByteCounter = 0
    State(1) = UnsignedToLong(1732584193#)
    State(2) = UnsignedToLong(4023233417#)
    State(3) = UnsignedToLong(2562383102#)
    State(4) = UnsignedToLong(271733878#)
End Sub

Private Sub MD5Final()
    Dim dblBits As Double, padding(72) As Byte, lngBytesBuffered As Long
    padding(0) = &H80
    dblBits = ByteCounter * 8
    lngBytesBuffered = ByteCounter Mod 64
    If lngBytesBuffered <= 56 Then MD5Update 56 - lngBytesBuffered, padding Else MD5Update 120 - ByteCounter, padding
    padding(0) = UnsignedToLong(dblBits) And &HFF&
    padding(1) = UnsignedToLong(dblBits) \ 256 And &HFF&
    padding(2) = UnsignedToLong(dblBits) \ 65536 And &HFF&
    padding(3) = UnsignedToLong(dblBits) \ 16777216 And &HFF&
    padding(4) = 0
    padding(5) = 0
    padding(6) = 0
    padding(7) = 0
    MD5Update 8, padding
End Sub

Private Sub MD5Update(InputLen As Long, InputBuffer() As Byte)
    Dim II As Integer, i As Integer, j As Integer, K As Integer, lngBufferedBytes As Long, lngBufferRemaining As Long, lng        As Long

    lngBufferedBytes = ByteCounter Mod 64
    lngBufferRemaining = 64 - lngBufferedBytes
    ByteCounter = ByteCounter + InputLen

    If InputLen >= lngBufferRemaining Then
        For II = 0 To lngBufferRemaining - 1
            ByteBuffer(lngBufferedBytes + II) = InputBuffer(II)
        Next II
        MD5Transform ByteBuffer
        lng = (InputLen) Mod 64
        For i = lngBufferRemaining To InputLen - II - lng Step 64
            For j = 0 To 63
                ByteBuffer(j) = InputBuffer(i + j)
            Next j
            MD5Transform ByteBuffer
        Next i
        lngBufferedBytes = 0
    Else
        i = 0
    End If
    For K = 0 To InputLen - i - 1
        ByteBuffer(lngBufferedBytes + K) = InputBuffer(i + K)
    Next K
End Sub

Private Sub MD5Transform(Buffer() As Byte)
    Dim x(16) As Long, a As Long, b As Long, C As Long, D As Long

    a = State(1)
    b = State(2)
    C = State(3)
    D = State(4)
    Decode 64, x, Buffer
    FF a, b, C, D, x(0), S11, -680876936
    FF D, a, b, C, x(1), S12, -389564586
    FF C, D, a, b, x(2), S13, 606105819
    FF b, C, D, a, x(3), S14, -1044525330
    FF a, b, C, D, x(4), S11, -176418897
    FF D, a, b, C, x(5), S12, 1200080426
    FF C, D, a, b, x(6), S13, -1473231341
    FF b, C, D, a, x(7), S14, -45705983
    FF a, b, C, D, x(8), S11, 1770035416
    FF D, a, b, C, x(9), S12, -1958414417
    FF C, D, a, b, x(10), S13, -42063
    FF b, C, D, a, x(11), S14, -1990404162
    FF a, b, C, D, x(12), S11, 1804603682
    FF D, a, b, C, x(13), S12, -40341101
    FF C, D, a, b, x(14), S13, -1502002290
    FF b, C, D, a, x(15), S14, 1236535329

    GG a, b, C, D, x(1), S21, -165796510
    GG D, a, b, C, x(6), S22, -1069501632
    GG C, D, a, b, x(11), S23, 643717713
    GG b, C, D, a, x(0), S24, -373897302
    GG a, b, C, D, x(5), S21, -701558691
    GG D, a, b, C, x(10), S22, 38016083
    GG C, D, a, b, x(15), S23, -660478335
    GG b, C, D, a, x(4), S24, -405537848
    GG a, b, C, D, x(9), S21, 568446438
    GG D, a, b, C, x(14), S22, -1019803690
    GG C, D, a, b, x(3), S23, -187363961
    GG b, C, D, a, x(8), S24, 1163531501
    GG a, b, C, D, x(13), S21, -1444681467
    GG D, a, b, C, x(2), S22, -51403784
    GG C, D, a, b, x(7), S23, 1735328473
    GG b, C, D, a, x(12), S24, -1926607734

    HH a, b, C, D, x(5), S31, -378558
    HH D, a, b, C, x(8), S32, -2022574463
    HH C, D, a, b, x(11), S33, 1839030562
    HH b, C, D, a, x(14), S34, -35309556
    HH a, b, C, D, x(1), S31, -1530992060
    HH D, a, b, C, x(4), S32, 1272893353
    HH C, D, a, b, x(7), S33, -155497632
    HH b, C, D, a, x(10), S34, -1094730640
    HH a, b, C, D, x(13), S31, 681279174
    HH D, a, b, C, x(0), S32, -358537222
    HH C, D, a, b, x(3), S33, -722521979
    HH b, C, D, a, x(6), S34, 76029189
    HH a, b, C, D, x(9), S31, -640364487
    HH D, a, b, C, x(12), S32, -421815835
    HH C, D, a, b, x(15), S33, 530742520
    HH b, C, D, a, x(2), S34, -995338651

    II a, b, C, D, x(0), S41, -198630844
    II D, a, b, C, x(7), S42, 1126891415
    II C, D, a, b, x(14), S43, -1416354905
    II b, C, D, a, x(5), S44, -57434055
    II a, b, C, D, x(12), S41, 1700485571
    II D, a, b, C, x(3), S42, -1894986606
    II C, D, a, b, x(10), S43, -1051523
    II b, C, D, a, x(1), S44, -2054922799
    II a, b, C, D, x(8), S41, 1873313359
    II D, a, b, C, x(15), S42, -30611744
    II C, D, a, b, x(6), S43, -1560198380
    II b, C, D, a, x(13), S44, 1309151649
    II a, b, C, D, x(4), S41, -145523070
    II D, a, b, C, x(11), S42, -1120210379
    II C, D, a, b, x(2), S43, 718787259
    II b, C, D, a, x(9), S44, -343485551

    State(1) = LongOverflowAdd(State(1), a)
    State(2) = LongOverflowAdd(State(2), b)
    State(3) = LongOverflowAdd(State(3), C)
    State(4) = LongOverflowAdd(State(4), D)
End Sub

#6

up，好让楼上的把代码贴完。:)

#7

完了，编译后运行效率更高。

#8

用c语言写效率更高

#9

谢谢各位，已经成功了，一个85.1M的文件不到一秒！

#1

不需要对整个文件作MD5计算吧？
从文件中提取一部分来作MD5计算也可以吧

秒客网

关于md5 帮顶有分！

9 个解决方案

#1

#2

#3

#4

#5

#6

#7

#8

#9

#1

#2

#3

#4

#5

#6

#7

#8

#9

相关文章