请问查询从x到y条记录的SQL语句怎么写?

通过SQl的 select 来得到 从X到 y 条记录
实现这个功能应该怎么写啊?

11 个解决方案

#1

declare @i int,@j int,@k int 
set @i=10
set @j=20
set @k=@j-@i    -->@k就是相當於从X到 y 条记录

select top @k * from tb where id not in(select top @i id from tb)

#2

declare @x int,@y int 
select @x=10,@y=20
set rowcount @y
select sn=identity(int,1,1),* into #t from [table]
set rowcount 0
select * from #t where sn>=@x
drop table #t

#3

查询第X页,每页Y条记录

最基本的处理方法(原理):

如果表中有主键(记录不重复的字段也可以),可以用类似下面的方法,当然y,(x-1)*y要换成具体的数字,不能用变量:

select top y * from 表 where 主键 not in(select top (x-1)*y 主键 from 表)



如果表中无主键,可以用临时表,加标识字段解决.这里的x,y可以用变量.

select id=identity(int,1,1),*  into #tb from 表
select * from #tb where id between (x-1)*y and x*y-1

#4

什么叫“从X到 y 条记录”？不懂，我也不知道上面的高手是怎么理解的？

#5

create proc sp_a
(@page int,----本返回的页码
@recsperpage int,----每一页的记录数
@table_name varchar (128),----表名
@order_name varchar (128))----排序字段
as 
declare @num int
select @num=@page*@recsperpage-@recsperpage
exec('
select top '+@recsperpage+' * from '+@table_name+' 
where '+@order_name+' not in (select top '+@num+' '+@order_name+'
 from '+@table_name+' order by '+@order_name+') order by '+@order_name+'')

#6

我猜楼主可能是这个意思：
得出结果后从结果集中返回从第X条到第Y条结果吧

select 查询条件 into #1 from 表 
alter table #1 add [id] int identity
select * from #1 where [id]>= X and [id]<=Y
drop table #1

#7

如果我理解错了希望各位高手不要笑话^_^

#8

是不是想查就1页的数据啊

#9

这个好比分页,但一定要注意查询的性能问题:
法一:
SELECT TOP 10 *
FROM TestTable
WHERE (ID NOT IN
          (SELECT TOP 20 id
         FROM TestTable
         ORDER BY id))
ORDER BY ID

法二:
SELECT TOP 10 *
FROM TestTable
WHERE (ID >
          (SELECT MAX(id)
         FROM (SELECT TOP 20 id
                 FROM TestTable
                 ORDER BY id) AS T))  ----from 后的派生表一定要有一个别名.
ORDER BY ID

法三:应用临时表;由于需要对临时表进行插入删除效率极低,所以不推荐使用.

在上面的方法中,通常法二的效率最高.因为如果用in,那么需要到结果集中去一个一个的比较.用'>'是一次性的比较.

如果想将要查找的top 行设置成变量,那么必须应用动态SQL语句.下面是我自己编的针对某一个表的分页存储过程,你可以参照他来实现你要求的功能.
CREATE procedure fy
@rows int ,
@pages int
as
declare @stra varchar(300)            --如果数据类型的长度不够,那么存储过程将不会执行.(造成空格的丢失)
declare @strb varchar(300)
declare @strc varchar(300)
declare @strd varchar(300)
set @stra=' select top  '+cast(@rows as varchar(10))+' * from  people  where [id] >  '
set @strb=' (select max([id]) from  (select  top  '+cast((@rows*(@pages-1)) as varchar(10))+'  [id]  from people order by [id] asc) a) ' 
set @strc='  order by  [id]  asc  '
set @strd=' select  top  '+cast(@rows as varchar(10))+'  *  from  people '
if @pages=1
begin 
exec(@strd)
end
else
begin
exec(@stra+@strb+@strc)
end
GO
建议:在你的程序编完以后,一定要测试他的查询效率.

#10

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_show]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_show]
GO

/*--实现分页的通用存储过程

显示指定表、视图、查询结果的第X页
对于表中主键或标识列的情况,直接从原表取数查询，其它情况使用临时表的方法
如果视图或查询结果中有主键,不推荐此方法
如果使用查询语句,而且查询语句使用了order by,则查询语句必须包含top 语句

--邹建 2003.09(引用请保留此信息)--*/

/*--调用示例
exec p_show '地区资料'

exec p_show 'select top 100 percent * from 地区资料 order by 地区名称',5,3,'地区编号,地区名称,助记码'
--*/
CREATE Proc p_show
@QueryStr nvarchar(4000), --表名、视图名、查询语句
@PageSize int=10, --每页的大小(行数)
@PageCurrent int=1, --要显示的页
@FdShow nvarchar (4000)='', --要显示的字段列表,如果查询结果不需要标识字段,需要指定此值,且不包含标识字段
@FdOrder nvarchar (1000)='' --排序字段列表
as
set nocount on
declare @FdName nvarchar(250) --表中的主键或表、临时表中的标识列名
,@Id1 varchar(20),@Id2 varchar(20) --开始和结束的记录号
,@Obj_ID int --对象ID
--表中有复合主键的处理
declare @strfd nvarchar(2000) --复合主键列表
,@strjoin nvarchar(4000) --连接字段
,@strwhere nvarchar(2000) --查询条件


select @Obj_ID=object_id(@QueryStr)
,@FdShow=case isnull(@FdShow,'') when '' then ' *' else ' '+@FdShow end
,@FdOrder=case isnull(@FdOrder,'') when '' then '' else ' order by '+@FdOrder end
,@QueryStr=case when @Obj_ID is not null then ' '+@QueryStr else ' ('+@QueryStr+') a' end

--如果显示第一页，可以直接用top来完成
if @PageCurrent=1
begin
select @Id1=cast(@PageSize as varchar(20))
exec('select top '+@Id1+@FdShow+' from '+@QueryStr+@FdOrder)
return
end

--如果是表,则检查表中是否有标识更或主键
if @Obj_ID is not null and objectproperty(@Obj_ID,'IsTable')=1
begin
select @Id1=cast(@PageSize as varchar(20))
,@Id2=cast((@PageCurrent-1)*@PageSize as varchar(20))

select @FdName=name from syscolumns where id=@Obj_ID and status=0x80
if @@rowcount=0 --如果表中无标识列,则检查表中是否有主键
begin
if not exists(select 1 from sysobjects where parent_obj=@Obj_ID and xtype='PK')
goto lbusetemp --如果表中无主键,则用临时表处理

select @FdName=name from syscolumns where id=@Obj_ID and colid in(
select colid from sysindexkeys where @Obj_ID=id and indid in(
select indid from sysindexes where @Obj_ID=id and name in(
select name from sysobjects where xtype='PK' and parent_obj=@Obj_ID
)))
if @@rowcount>1 --检查表中的主键是否为复合主键
begin
select @strfd='',@strjoin='',@strwhere=''
select @strfd=@strfd+',['+name+']'
,@strjoin=@strjoin+' and a.['+name+']=b.['+name+']'
,@strwhere=@strwhere+' and b.['+name+'] is null'
from syscolumns where id=@Obj_ID and colid in(
select colid from sysindexkeys where @Obj_ID=id and indid in(
select indid from sysindexes where @Obj_ID=id and name in(
select name from sysobjects where xtype='PK' and parent_obj=@Obj_ID
)))
select @strfd=substring(@strfd,2,2000)
,@strjoin=substring(@strjoin,5,4000)
,@strwhere=substring(@strwhere,5,4000)
goto lbusepk
end
end
end
else
goto lbusetemp

/*--使用标识列或主键为单一字段的处理方法--*/
lbuseidentity:
exec('select top '+@Id1+@FdShow+' from '+@QueryStr
+' where '+@FdName+' not in(select top '
+@Id2+' '+@FdName+' from '+@QueryStr+@FdOrder
+')'+@FdOrder
)
return

/*--表中有复合主键的处理方法--*/
lbusepk:
exec('select '+@FdShow+' from(select top '+@Id1+' a.* from
(select top 100 percent * from '+@QueryStr+@FdOrder+') a
left join (select top '+@Id2+' '+@strfd+' 
from '+@QueryStr+@FdOrder+') b on '+@strjoin+'
where '+@strwhere+') a'
)
return

/*--用临时表处理的方法--*/
lbusetemp:
select @FdName='[ID_'+cast(newid() as varchar(40))+']'
,@Id1=cast(@PageSize*(@PageCurrent-1) as varchar(20))
,@Id2=cast(@PageSize*@PageCurrent-1 as varchar(20))

exec('select '+@FdName+'=identity(int,0,1),'+@FdShow+'
into #tb from'+@QueryStr+@FdOrder+'
select '+@FdShow+' from #tb where '+@FdName+' between '
+@Id1+' and '+@Id2
)

GO

#11

谢谢各位了