常用批处理命令之For命令详解
在批处理中，for是最为强大的命令语句，它的出现，使得解析文本内容、遍历文件路径、数值递增/递减等操作成为可能；配合if、call、goto等流程控制语句，更是可以实现脚本复杂的自动化、智能化操作；合理使用for语句，还能使代码大为简化，免除各位编写大量重复语句之苦。而能否熟练使用for语句，已经成为衡量一个人批处理水平高低最主要的标准。
for语句基本形态：
在cmd窗口中：for %I in (command1) do command2:: for之后的形式变量I必须使用单百分号引用，即%I；
在批处理文件中：for %%I in (command1) do command2:: 而在批处理文件中，for引用形式变量I必须使用双百分号，即%%I
for语句的基本要素有：
1、for、in和do是for语句的关键字，它们三个缺一不可；
2、%%I是for语句中对形式变量的引用，就算它在do后的语句中没有参与语句的执行，也是必须出现的；
3、in之后，do之前的括号不能省略；
4、command1表示字符串或变量，command2表示字符串、变量或命令语句；
for语句的一些注意事项:
1、for语句的形式变量I，可以换成26个字母中的任意一个，这些字母会区分大小写，也就是说，%%I和%%i会被认为不是同一个变量；形式变量I还可以换成其他的字符，但是，为了不与批处理中的%0～%9这10个形式变量发生冲突，请不要随意把%%I替换为%%0 ～%%9中的任意一个；
2、in和do之间的command1表示的字符串或变量可以是一个，也可以是多个，每一个字符串或变量，我们称之为一个元素，每个元素之间，用空格键、跳格键、逗号、分号或等号分隔；
3、for语句依次提取command1中的每一个元素，把它的值赋予形式变量I,带到do后的command2中参与命令的执行；并且每次只提取一个元素，然后执行一次do后的命令语句，而无论这个元素是否被带到command2中参与了command2的运行；当执行完一次do后的语句之后，再提取command1中的下一个元素，再执行一次command2，如此循环，直到command1中的所有元素都已经被提取完毕，该for语句才宣告执行结束；
@echo off
set str=c d e f g h i j k l m n o p q r s t u v w x y z
echo 当前硬盘的分区有：
for %%i in (%str%) do if exist %%i: echo %%i:
pause
这段代码能检测硬盘都有哪些分区，包括U盘和移动硬盘的分区，当光驱中有盘的时候，也会被列出来。
For语句带参数形式
for /参数 %变量 in (集) do 命令(这里写的是在命令行里用的格式，如果是在批处理中,需要把其中%再多加个%形成%%)
参数：FOR分四种参数 ：D 、L、 R、 F，并且有的参数还可附加另外的选项。
变量：(记住如果是在批处理中使用for命令时，变量前的%需改为%%)这个变量名是由单个字母组成且区分大小写， FOR命令会在每次循环中，把in (集)中读取到的值赋于这个变量，以便其后的命令中引用。
集：由系列文件、字符串或由命令产生的内容形成的集合（当然可用通配符 * ？，还可引用环境变量），FOR命令是按一定顺序和规律分次读取集中内容，赋值给变量，并执行do后的命令，进行循环下一轮，直至集中内容读取完毕，而括号是格式必须的(in到后面括号之间要有空格)。
命令：可以是任何合格的DOS命令或外部可被DOS调用的程序，且可采用括号把多条命令括起来，在一次循环中执行。
附注：由于一些目录或文件名可能会有空格，所以很多时候集里和命令里往往需要用英文引号括起来(但有时引号里的内容可能会被认为是字符串)表示是一整体，下面开始的有些例中为简捷起见，忽略文件名或目录名带空格这种情况。
现在按参数分类举例解释其用法：
一、参数 /d
for /d %%变量 in (集) do 命令
/d 参数是指定仅对目录而不是文件执行的for命令。
例1:在命令行输入for /d %a in (c:\*.*) do echo %a运行会把C盘根目录下的全部目录分次显示出来,而不显示文件名
看起来有点乱，如果把命令提示回显关闭就清晰了:for /d %a in (c:\*.*) do @echo %a
二、参数 /R
/R参数之后还可带盘符及路径
for /r 此处可以带有路径%变量 in (集) do 命令
在/r 之后的那个路径，指包含它之下的整个目录树（相当于DOS命令tree里的范围）中的所有目录，如果仅为一个英文句点 . ，是指当前路径下的目录树，如果省略了路径则特指当前目录，而之后的in (集)则相当于与前面每个目录相配的文件集
这里按in(集)中有无通配符分两种情况
1)in(集)中没有通配符
指定的是单个文件或列举的具体文件(多个文件名之间用分隔符分隔，如空格、逗号等)
例2for /r . %i in (abc.txt) do echo. > %i这里for /r 后的路径仅有一个 . 而后面每个循环中echo. > %i相当于创建一个仅有一空行的文本文件，整体效果是在当前目录下包括子录，每个目录中建一个abc.txt。
例3 （放入批处理中）
@echo off
rem 显示d:盘中所有文件名为file1和file2的列表
for /r d:\ %%h in (file1,file2) do if exist %%h echo %%h
pause
2) in(集)中含有通配符*或？
这种里面的do命令将处理前面 /r指定的目录系列里每个含有in(集)中文件的项，而不去理会不含有相配文件的那些目录
例4：
@echo off
rem 删除C盘中所有*.chk的文件
for /r c:\ %%h in (*.chk) do del /q %%h
pause
注：del /q 表示用安静模式删除（不需确认）
三、参数 /L
for /L %%变量 in (起始值，每次增值，结束时的比较值) do 命令
(起始值，每次增值，结束时的比较值)相当于一个等差数字序列，从"起始值"的数字开始，每次增加多少（也可设定为负数）为"每次增值"，并与"结束时的比较值"比较，超出则退出for循环（也不执行本轮后面的do 命令）
例5
@echo off
::在D盘建立aa1~ aa5五个文件夹
for /L %%i in (1,1,5) do md d:\aa %%i
pause
四、参数 /f
如果说，for语句是批处理中最强大的语句的话，那么，for /f 就是精华中的精华。for /f 的强大，和它拥有众多的开关密切相关。因为开关众多，所以用法复杂，基本格式如下：
文件名-集
for /f "选项" %变量 in （ "字符串"-集 ） do 命令
'命令'-集
/f 后可以带有几种选项，不带选项当然也是合格的格式，而带有参数则必须以引号整体括起来，后面的集里主要由三种形式形成的，最终在for循环中的每一轮中会形成读取一行字符串，来给指定的%变量、以及给由于选项中派生出附加变量赋值后，执行do后面的命令
for /f为解析文本而生：读取文件内容；提取某几行字符；截取某个字符片段；对提取到的内容再切分、打乱、杂糅……只要你所能想到的花样，for /f 都会想方设法帮你办到，因为，for /f 就是被设计成专门用于解析文本的。
for /f %%i in (test.txt) do echo %%i这段代码中，虽然执行结果是把test.txt中的所有内容都显示出来了，貌似 for /f 语句是把整个test.txt一次性显示到屏幕上，实际上并非如此。无论for语句做何种变化，它的执行过程仍然遵循基本的for流程：依次处理每个元素，直到所有的元素都被处理为止。只不过在for /f语句中，这里的元素是指文件中的每一行，也就是说，for /f 语句是以行为单位处理文本文件的，这是一条极为重要的规则。
1.切分字符串的利器：delims=
for /f "delims=，" %%i in (test.txt) do echo %%i ::每行第一个逗号之后的所有内容都不见了（如果有不存在逗号的行，则保留原样），也就说，你成功地提取到了每行第一个逗号之前的所有内容！
"delims=，"，它的含义是：以逗号作为被处理的字符串的分隔符号;要是文本内容不是以逗号分隔，而是以其他符号分隔，那么，把"delims=,"的逗号换成相应的符号就可以了。
在批处理中，指定分隔符号的方法是：添加一个形如 "delims=符号列表" 的开关，这样，被处理的每行字符串都会被符号列表中罗列出来的符号切分开来。
需要注意的是：开关中是"符号列表"而非"符号"你可以一次性指定多个分隔符号。如果没有指定"delims=符号列表"这个开关，那么，for /f 语句默认以空格键或跳格键作为分隔符号。
for /f "delims=.，" %%i in (test.txt) do echo %%i ::第一个点号或第一个逗号之前的内容都被提取出来了。执行过程是：逐行读取test.txt中的内容，以点号和逗号切分每一行的内容（不存在点号和逗号的行，则不再切分，为了描述的方便，我们把被点号或逗号切分的一个一个的字符串片段，称之为节），然后，for /f 会提取第一节的内容作为最终结果，显示在屏幕上。需要注意的是， 以上代码只会提取第一节字符串的内容，因为 for /f 语句默认只提取第一节的字符串。
2. 定点提取：tokens=
tokens= 后面一般跟的是数字，如 tokens=2，也可以跟多个，但是每个数字之间用逗号分隔，如 tokens=3,5,8，它们的含义分别是：提取第2节字符串、提取第3、第5和第8节字符串。注意，这里所说的"节"，是由 delims= 这一开关划分的，它的内容并不是一成不变的。
当提取多节时接受如何接受变量，for /f 语句有如下规定：如果 tokens= 后面指定了多个数字，如果形式变量为%%i，那么，第一个数字指代的内容用第一个形式变量%%i来接收，第二个数字指代的内容用第二个形式变量%%j来接收，第三个数字指代的内容用第三个形式变量%%k来接收……第N个数字指代的内容用第N个形式变量来接收，其中，形式变量遵循字母的排序，第N个形式变量具体是什么符号，由第一个形式变量来决定：如果第一个形式变量是%%i，那么，第二个形式变量就是%%j；如果第一个形式变量用的是%%x，那么，第二个形式变量就是%%y。
如果要提取的内容是连续的多"节"的话，那么，连续的数字可以只写最小值和最大值，中间用短横连接起来即可，比如 tokens=1,2,3,4,5 可以简写为 tokens=1-5 。
tokens=后面所接的星号具备这样的功能：字符串从左往右被切分成紧跟在*之前的数值所表示的节数之后，字符串的其余部分保持不变，整体被*所表示的一个变量接收。
for /f "delims=， tokens=1,*" %%i in (test.txt) do echo %%i %%j ::test.txt 内容被切分，切分符号为逗号，当切分完第一节之后，切分动作不再继续下去，因为 tokens=1,* 中，星号前面紧跟的是数字1；第一节字符串被切分完之后，其余部分字符串不做任何切分，整体作为第二节字符串，每行就被切分成了两节，分别被变量%%i和变量%%j接收。
for /f "delims=， tokens=1,3-4,*" %%i in (test.txt) do echo %%i %%j %%k %%l
3. 跳过无关内容，直奔主题：skip=n
很多时候，有用的信息并不是贯穿文本内容的始终，而是位于第N行之后的行内，为了提高文本处理的效率，或者不受多余信息的干扰，for /f 允许你跳过这些无用的行，直接从第N+1行开始处理，这个时候，就需要使用参数 skip=n，其中，n是一个正整数，表示要跳过的行数。例如：for /f "skip=2" %%i in (test.txt) do echo %%i这段代码将跳过头两行内容，从第3行起显示test.txt中的信息。
4. 忽略以指定字符打头的行：eol=
FOR /F "eol=; tokens=2,3* delims=, " %i in (myfile.txt) do @echo %i %j %k会分析 myfile.txt 中的每一行，忽略以分号打头的那些行……
for /f "eol=;" %%i in (test.txt) do echo %%i结果，那些以分号打头的行没有显示出来。
for /f "eol=,;" %%i in (test.txt) do echo %%i此时，屏幕上出现 此时不应有 ;"。 的报错信息。可见，在指定字符的时候，只能指定1个,要忽略多个还得又是if又是findstr加管道来多次过滤。
for /f 语句是默认忽略以分号打头的行内容的，正如它默认以空格键或跳格键作为字符串的切分字符一样。
如果要取消这个默认设置，可选择的办法是：
1、为eol=指定另外一个字符；
2、使用 for /f "eol=" 语句，也就是说，强制指定字符为空，就像对付delims=一样。
5.如何决定该使用 for /f 的哪种句式？(兼谈usebackq的使用)
for /f %%i in (……) do (……) 语句有好几种变形语句，不同之处在于第一个括号里的内容：有的是用单引号括起来，有的是用双引号包住，有的不用任何符号包裹，具体格式为：
1、for /f %%i in (文件名) do (……)
2、for /f %%i in ('命令语句') do (……)
3、for /f %%i in ("字符串") do (……)
1、当你希望读取文本文件中的内容的话，第一个括号中不用任何符号包裹，应该使用的是第1条语句；例如：你想显示test.txt中的内容，那么，就使用 for /f %%i in (test.txt) do echo %%i；
2、当你读取的是命令语句执行结果中的内容的话，第一个括号中的命令语句必须使用单引号包裹，应该使用的是第2条语句；例如：你想显示当前目录下文件名中含有test字符串的文本文件的时候，应该使用 for /f %%i in ('dir /a-d /b *test*.txt') do echo %%i 这样的语句；
3、当你要处理的是一个字符串的时候，第一个括号中的内容必须用双引号括起来，应该是用的是第3条语句；例如：当你想把bbs.bathome.cn这串字符中的点号换为短横线并显示出来的话，可以使用 for /f "delims=. tokens=1-3" %%i in ("bbs.bathome.cn") do echo %%i-%%j-%%k 这样的语句。
很显然，第一个括号里是否需要用符号包裹起来，以及使用什么样的符号包裹，取决于要处理的对象属于什么类型：如果是文件，则无需包裹；如果是命令语句，则用单引号包裹；如果是字符串，则使用双引号括起来。
在第1条语句中，如果文件名中含有空格或&，该怎么办？
usebackq - 指定新语法已在下类情况中使用:在作为命令执行一个后引号的字符串并且一个单引号字符为文字字符串命令并允许在 filenameset中使用双引号扩起文件名称。
FOR /F "usebackq delims==" %i IN (`set`) DO @echo %i会枚举当前环境中的环境变量名称。
当使用了usebackq之后，如果第一个括号中是一条命令语句，那么，就要把单引号'改成后引号`（键盘左上角esc键下面的那个按键，与~在同一键位上）。usebackq 是一个增强型参数，当使用了这个参数之后，原来的for语句中第一个括号内的写法要做如下变动：如果第一个括号里的对象是一条命令语句的话，原来的单引号'要改为后引号`；如果第一个括号里的对象是字符串的话，原来的双引号"要改为单引号'；如果第一个括号里的对象是文件名的话，要用双引号"括起来。
区区一条for /f语句，竟然有多达6种句型：
1、for /f %%i in (文件名) do (……)
2、for /f %%i in ('命令语句') do (……)
3、for /f %%i in ("字符串") do (……)
4、for /f "usebackq" %%i in ("文件名") do (……)
5、for /f "usebackq" %%i in (`命令语句`) do (……)
6、for /f "usebackq" %%i in ('字符串') do (……)
其中，4、5、6由1、2、3发展而来，他们有这样的对应关系：1-->4、2-->5、3-->6。
解释例子for /f "skip=1 tokens=1,4 delims= " %c in (d:\abc.txt) do @echo %c %d如下：
skip=1 表示文本开始忽略的行数为1 ——忽略几行
delims= 在一行中，用什么单个符号（可以有多字符组合，之间也不能加空格，被理解为多项单个字符，如要空格符须放最后）来分隔字符串作为读取赋值的单元(形成一段)，本例中等号后是空的表示仅用空格来分隔。——用什么刀来切分
tokens=1,4 这个等号后的数字表示依次取第几个被分隔的字符串段，来分别赋给%变量及顺序附加的变量，本例取第1个段赋给%c，第4个段赋给c后的一个变量也就是赋给%d，并且，可以写成tokens=1,2,5-7 或tokens=1,2,3* 或tokens=1,2,5,7 分别表示取第1,2,5,6,7（依次赋给%c, %d, %e, %,f, %g共5个变量）、1,2,3及3后的所有段（要赋给3个变量）、1,2,5,7(要赋给4个变量)，tokens=后的数字号可以不按顺序，但书写的顺序与分配给变量的顺序是对应的，这是赋值，至于之后do命令中用不用是另一回事。换句话 ——最多只需取哪几段
in (变量) 中的那个变量，代表起始的一个变量名，按tokens中定义的总个数来扩充附加变量名，如总个数为3，则%c 就附加%d和%e ，要是%C就附加%D%E… 本例中tokens=1,4仅需两个，起始的是in () 括号中的%c 则每行中第一段赋给%c,第4段赋给变量%d
注：如果集里是由多个文件组成，那么处理完一个文件后又处理完又去处理另一个文件，每个文件行数不同循环次数（do命令的次数）也将因此不同。如果集里是由命令产生的系统，那么你必须首先熟悉该命令执行后会产生怎样效果的字符系统，才能正确安排后面的do命令。
总结：无论in后的集是哪种形式，for/f 都最终分解为字符串，按需要是否"忽略几行"（skip=）、"用什么刀来切分"（delims= ）、"最多只需取哪几段"（tokens=）将集里形成的字符串,逐行地分段赋给%或%%后的变量及可能顺延扩展出的变量，以执行do后的命令，每一行即为一轮循环。
对于带有空格的文件名，您需要用双引号将文件名括起来。为了用这种方式来使用双引号，您还需要使用 usebackq 选项，否则，双引号会被理解成是用作定义某个要分析的字符串的。——换句话说,带有usebackq（放在for /f 之后的引号里）参数时 in ()里用双引号表示的仍是文件名。
选项eol= ：默认状况还忽略所有分号" ; "开始的行，如果你想不忽略分号开始的行，或者想忽略自己指定一字符开始的行就可以在for /f 之后那引号参数里使用eol=你自己定义的字符，但它不像delims=的那样可定义多个，只允许定义一个。
可以用 %~ 操作符将文件名分离成文件名、扩展名、盘符等独立部分 ，请看for/?中的解释（其中示例的变量为%I）：
另外，FOR 变量参照的替换已被增强。可以使用下列选项语法:
~I - 删除任何引号(")，扩充 %I
%~fI - 将 %I 扩充到一个完全合格的路径名
%~dI - 仅将 %I 扩充到一个驱动器号
%~pI - 仅将 %I 扩充到一个路径
%~nI - 仅将 %I 扩充到一个文件名
%~xI - 仅将 %I 扩充到一个文件扩展名
%~sI - 扩充的路径只含有短名
%~aI - 将 %I 扩充到文件的文件属性
%~tI - 将 %I 扩充到文件的日期/时间
%~zI - 将 %I 扩充到文件的大小
%~$PATH:I - 查找列在路径环境变量的目录，并将 %I 扩充到找到的第一个完全合格的名称。如果环境变量名未被定义，或者没有找到文件，此组合键会扩充到空字符串
可以组合修饰符来得到多重结果:
%~dpI - 仅将 %I 扩充到一个驱动器号和路径
%~nxI - 仅将 %I 扩充到一个文件名和扩展名
%~fsI - 仅将 %I 扩充到一个带有短名的完整路径名
%~dp$PATH:I - 查找列在路径环境变量的目录，并将 %I 扩充到找到的第一个驱动器号和路径。
%~ftzaI - 将 %I 扩充到类似输出线路的 DIR
凡是 %~ 打头的操作符，都是文件名或环境变量的分离操作。而每项要想运用自如，则需要付出辛勤的练习。