VBS中WScript.Shell对象的run和exec的使用及区别

VBS中WScript.Shell对象的run和exec的使用及区别

方法声明：
Function Exec(ByVal Command As String) As WshExec
Function Run(ByVal Command As String, [ByVal WindowStyle], [ByVal WaitOnReturn]) As Integer
区别：
 
1，返回值
run的返回值是一个整数，就是0或1成功和失败两个状态，而exec方法的返回值是一个对象，从返回对象中可以获得控制台输出信息和控制台错误信息，即StdOut和StdErr属性等。
如：
Dim oShell,exeRs
Set oShell = CreateObject("WSCript.shell")
commandLine = "xcopy.exe"
Set exeRs = oShell.Exec(commandLine)
errMsg = exeRs.StdErr.ReadAll()
stdMsg = exeRs.StdOut.ReadAll()
WScript.echo "errMsg:" & errMsg & "stdMsg:" & stdMsg
ret = oShell.run(commandLine, 0, true)
WScript.echo "run method return value:" & ret
Set oShell = Nothing
Set exeRs = Nothing
可以取道控制台错误和控制台信息。
 
附记：WshExec类具有属性ExitCode，ProcessID，Status，StdErr，StdIn，StdOut以及一个函数Terminate，这些属性和函数都很好理解。
Status属性具有三个值：
Const WshFailed   = 2
Const WshFinished = 1
Const WshRunning  = 0
 
2，执行参数
Run的后两个参数，一个是cmd窗口的风格，一个是是否等待执行完成。最后一个参数很有用，如果你希望等待本次cmd执行的程序结束后，再执行run后面的语句，设置这个参数为true，否则后面的语句将不等待cmd窗口完成，直接运行。
另外，如果你使用exec 方法的时候，如果希望等待cmd中程序执行完后，再执行后面的语句，也可以通过下面的方法： oExec.StdErr.ReadAll()或者oExec.StdOut.ReadAll（），道理上也应该好理解，要得到输出的信息，肯定要cmd执行完后才会有输出的。
 
WshShell.run函数的参数
set WshShell= CreateObject(“Wscript.Shell”)
WshShell.run       "notepad.exe",,
run函数有三个参数，第一个参数是你要执行的程序的路径，若路径中存在空格，记得要用""括起来，如 """C:\Program Files\nn.exe"""的形式或者Chr(34)&"C:\Program Files\nn.exe"&Chr(34)的形式，第二个程序是窗口的形式，0是在后台运行；1表示正常运行；2表示激活程序并且显示为最小化；3表示激活程序并且显示为最大化；一共有10个这样的参数如下表。 第三个参数是表示这个脚本是等待还是继续执行，如果设为了true,脚本就会等待调用的程序退出后再向后执行。 
其实，run做为函数，前面还有一个接受返回值的变量，一般来说如果返回为0，表示成功执行，如果不为0，则这个返回值就是错误代码，可以通过这个代码找出相应的错误。
 
intWindowStyle 说明
0 隐藏一个窗口并激活另一个窗口。
1 激活并显示窗口。如果窗口处于最小化或最大化状态，则系统将其还原到原始大小和位置。第一次显示该窗口时，应用程序应指定此标志。
2 激活窗口并将其显示为最小化窗口。
3 激活窗口并将其显示为最大化窗口。
4 按最近的窗口大小和位置显示窗口。活动窗口保持活动状态。
5 激活窗口并按当前的大小和位置显示它。
6 最小化指定的窗口，并按照 Z 顺序激活下一个顶部窗口。
7 将窗口显示为最小化窗口。活动窗口保持活动状态。
8 将窗口显示为当前状态。活动窗口保持活动状态。
9 激活并显示窗口。如果窗口处于最小化或最大化状态，则系统将其还原到原始大小和位置。还原最小化窗口时，应用程序应指定此标志。
10 根据启动应用程序的程序状态来设置显示状态。

这篇文章主要介绍了VBS中Run和Exec的区别,需要的朋友可以参考下

Set ws = CreateObject("WScript.Shell")
'这里创建一个对象引用，以便在以下示例代码中使用。
'Demon注：这个变量名怎么这么猥琐（WS）

语法：（常识（Demon注：常识这个词我喜欢）：作为过程使用时，不要加括号，否则出现编译器错误（参数唯一或没有时加括号不会出错，但建议不要加））

复制代码 代码如下:
ws.Run(strCommand, [intWindowStyle], [bWaitOnReturn])
[Set objExec =] ws.Exec(strCommand)

WScript.Shell对象的这两个方法：

都可以用来运行程序，且可以带参数。
都可以在程序路径中使用环境变量。
都不能为程序指定工作目录、不能设置优先级（start命令可以）。
要指定工作目录，只能通过改变脚本宿主（wscript.exe/cscript.exe）的当前工作目录：ws.CurrentDirectory = "工作目录"。（常识：工作目录有何意义：1、有些程序需要相应目录下的dll等相关文件支持 2、相对路径问题）

Run和Exec的区别：

1、Run可以直接运行文件（包括协议文件），会启动相关联的程序打开该文件（没有关联则出错）。start有此功能（更高级，没有关联时会打开“打开方式”对话框）。Exec只能运行程序。

复制代码 代码如下:
ws.Run "c:\boot.ini"
ws.Exec "notepad c:\boot.ini"

2、Run不仅可以直接运行位于path环境变量目录中的程序，还能运行在注册表App Paths中设置的程序“别名”。start有此功能。Exec不行，只能直接运行位于path环境变量目录中的程序。

复制代码 代码如下:
ws.Run "iexplore"
'iexplore 在 App Paths 中登记了别名。
ws.Exec "calc"

3、Run可以等待程序运行结束再执行下面的命令。start有此功能。Exec不行。

复制代码 代码如下:
ws.Run "notepad", ,true

4、Exec运行的程序路径中即使含有空格，也可以不加引号（参数如需引号，它的引号不能省略）。Run、start没有这个本领。（常识：vbs中一个引号字符"本身要用两个引号表示，即写成""。也可以用Chr函数得到引号：chr(34)）

复制代码 代码如下:
ws.Exec "C:\Program Files\Internet Explorer\IEXPLORE.EXE"
ws.Exec """C:\Program Files\Internet Explorer\IEXPLORE.EXE"""
ws.Run  """C:\Program Files\Internet Explorer\IEXPLORE.EXE"""

5、最大的区别是：Run着重于启动控制（设置窗口形式）。（start听名字知道是为了启动，也可以简单设置窗口最大化、最小化。）Exec着重于后续控制，并着重于控制命令行程序。

run可以设置程序运行时的运行模式（前台后台：是否隐藏窗口）、窗口大小、激活状态（是否获取“焦点”），具体参数请参考手册。
Exec在启动程序后还能对其进行控制：获取运行状态、获取PID、强行中止进程。如果运行的是命令行程序，还能提供对 StdIn/StdOut/StdErr 流的访问：写入执行命令、获取命令输出等。运行命令行程序后只能通过StdIn写入命令，控制台窗口不再接受用户输入。

复制代码 代码如下:
ws.Run "notepad", 0
'隐藏窗口
ws.Run "notepad", 4
'运行后不激活，不打扰原来的活动窗口

注意，手册上明确指出，Run不能约束所有程序都按它指定的窗口形式运行，有些程序不听它的话，比如iexplore、calc等。运行ieplore时，它会夺取焦点成为活动窗口。Run无法以最小化运行calc。

复制代码 代码如下:
Set oExec = ws.Exec("mspaint")
WScript.Echo oExec.ProcessId
oExec.Terminate
WScript.Echo oExec.Status '0为运行，1为结束
Set oExec = ws.Exec("ipconfig")
WScript.Echo oExec.StdOut.ReadAll

Exec的应用：

1、Runas自动输入密码：可能是设计时为安全考虑，runas不接收管道传递或从文件重定向得到，输入密码必须手动输入，这个问题困扰了不少人，却又难以解决，用Sendkeys也不一定稳妥（Demon注：我之前也说过很多次，用Sendkeys是不靠谱的，因为无法保证目标窗口一直获得焦点，但是经常见到很多人用，真是不明真相的群众，悲哀）。如果用Exec方法，就能轻松做到自动输入。

复制代码 代码如下:
Set ws = CreateObject("WScript.Shell")
Set oExec = ws.Exec("cmd.exe")
oexec.StdIn.WriteLine "runas /user:username setup.bat"
oexec.StdIn.WriteLine "password"

2、Exec与Run的结合使用：Exec方法无法隐藏窗口，要得到命令行程序的输出，就会有一个黑呼呼的窗口一闪而过，不仅难看，还会让其他使用者误以为是木马什么的，很不完美。如何解决这个问题呢？就让Exec与Run合作吧！

复制代码 代码如下:
Set ws = CreateObject("WScript.Shell")
host = WScript.FullName
'Demon注：这里不用这么复杂吧，LCase(Right(host, 11))不就行了
If LCase( right(host, len(host)-InStrRev(host,"\")) ) = "wscript.exe" Then
    ws.run "cscript """ & WScript.ScriptFullName & chr(34), 0
    WScript.Quit
End If
Set oexec = ws.Exec( "ipconfig")
Msgbox oExec.StdOut.ReadAll, , "ipconfig"
'此时不要用WScript.Echo，因为当前是在控制台运行
'WScript.Echo的结果会在控制台输出，不会弹出对话框。

vbsRun方法

object.Run(strCommand, [intWindowStyle], [bWaitOnReturn])

【参数】
object
WshShell 对象。
strCommand
表示要运行的命令行的字符串值。包括要传递到可执行文件的所有参数。
intWindowStyle
可选。表示程序窗口外观的整数值。
请注意，并非所有程序都使用此信息。
bWaitOnReturn
可选。布尔值，表示在继续执行脚本中的下一条语句之前，脚本是否等待执行完程序。
如果设为 true，则在执行完程序后才执行脚本，Run 方法返回由程序返回的任何错误代码。
如果设为 false（默认值），则 Run 方法将自动在启动程序后立即返回 0（不是错误代码）。
 
【说明】
Run 方法返回一个整数。Run 方法启动在新 Windows 进程中运行的程序。
可以让脚本等到程序执行完后再继续执行。这允许您同步运行脚本和程序。
strCommand 参数内的环境变量自动扩展。
如果某个文件类型已正确注册到某个程序中，则对该类型的文件调用 Run 方法时将执行该程序。例如，如果您的计算机系统中装有 Word，则对 *.doc 文件调用 Run 方法时将启动 Word 并加载该文档。
【intWindowStyle 说明 】
0 隐藏一个窗口并激活另一个窗口。
1 激活并显示窗口。如果窗口处于最小化或最大化状态，则系统将其还原到原始大小和位置。第一次显示该窗口时，应用程序应指定此标志。
2 激活窗口并将其显示为最小化窗口。
3 激活窗口并将其显示为最大化窗口。
4 按最近的窗口大小和位置显示窗口。活动窗口保持活动状态。
5 激活窗口并按当前的大小和位置显示它。
6 最小化指定的窗口，并按照 Z 顺序激活下一个顶部窗口。
7 将窗口显示为最小化窗口。活动窗口保持活动状态。
8 将窗口显示为当前状态。活动窗口保持活动状态。
9 激活并显示窗口。如果窗口处于最小化或最大化状态，则系统将其还原到原始大小和位置。还原最小化窗口时，应用程序应指定此标志。
10 根据启动应用程序的程序状态来设置显示状态。
 
【示例 1】

下面的 VBScript 代码用记事本打开当前运行脚本的副本。

复制代码 代码如下:
Set WshShell = WScript.CreateObject("WScript.Shell")
WshShell.Run "%windir%\notepad " & WScript.ScriptFullName

下面的 VBScript 代码与上述代码完成的操作相同，不同之处在于，它指定窗口类型，等待用户关闭记事本，关闭记事本时保存从记事本返回的错误代码。
 

复制代码 代码如下:
Set WshShell = WScript.CreateObject("WScript.Shell")
Return = WshShell.Run("notepad " & WScript.ScriptFullName, 1, true)

【示例 2】
下面的 VBScript 代码打开一个命令窗口，将路径改为 C:\，并执行 DIR 命令。

复制代码 代码如下:
Dim oShell
Set oShell = WScript.CreateObject ("WSCript.shell")
oShell.run "cmd /K CD C:\ & Dir"
Set oShell = Nothing

 

Run 方法:

Run方法有三个参数，
第一个参数是你要执行的程序的路径，
第二个参数是窗口的形式，0后台运行；1正常运行；2最小化；3最大化；缺省的话表示正常运行
第三个参数是表示这个脚本是等待还是继续执行，如果设为了True,脚本就会等待调用的程序退出后再向后执行。

例1：

复制代码 代码如下:
Set ws = CreateObject("WScript.Shell")
ws.Run "notepad",,True
ws.Run "iexplore"

例2：隐藏BAT执行窗口

复制代码 代码如下:
Set ws = CreateObject("WScript.Shell")
ws.Run "x.bat",0

例3：
复制代码 代码如下:
Set ws = CreateObject("WScript.Shell")
ws.Run "cmd /c netstat -an>>x.txt",0

例4：
复制代码 代码如下:
Set ws = CreateObject("WScript.Shell")
ws.Run "taskkill /f /im iexplore.exe",0

Exec 方法

例1：运行文件

复制代码 代码如下:
Set ws = CreateObject("WScript.Shell")
ws.Exec "notepad c:/x.txt" ‘对于Exec应指明程序，此notepad是必须的

例2：运行程序>获取进程PID值>强行结束进程（没有Run+taskkill强：如在记事本未保存的情况下结束进程，Exec会出错，而Run不会）>判断进程是否在运行（这个功能不错）
复制代码 代码如下:
Set ws = CreateObject("WScript.Shell")
Set e = ws.Exec("notepad")
MsgBox e.ProcessId
e.Terminate
WSH.Sleep 1000
MsgBox e.Status ‘0为运行，1为结束

例3：直接获取dos命令输出,dos窗口会闪一下，Exec没有窗口控制功能
复制代码 代码如下:
Set ws = CreateObject("WScript.Shell")
Set e = ws.Exec("ipconfig")
MsgBox e.Stdout.ReadAll

例4：
复制代码 代码如下:
Set ws = CreateObject("WScript.Shell")
Set e = ws.Exec("cmd /c echo Hi")
MsgBox e.Stdout.ReadAll

您可能感兴趣的文章:

• vbScript中WScript.Shell对象的run和exec使用心得分享