概述
Tomcat 的三个最重要的启动脚本:
- startup.bat
- catalina.bat
- setclasspath.bat
上一篇咱们分析了 startup.bat 脚本
这一篇咱们来分析 catalina.bat 脚本.
至于 setclasspath.bat 这个脚本, 相信看完这一篇, 就可以自己看懂这个脚本了.
可以点击下载 [ setclasspath.bat 脚本 ]查看附注释的 setclasspath.bat 脚本
catalina.bat
这个脚本的代码有点多, 就单独弄了一篇展示 catalina.bat 脚本中的内容. 点击 [catalina.bat 脚本 ]下载查看.
下面咱们就按照脚本中的内容一行行的来分析.
|
1
2
|
@echo off
setlocal
|
这两个命令可以参考上一篇的文章（解析Tomcat的启动脚本--startup.bat）的解释
第一块脚本代码
|
1
2
3
4
5
6
7
8
9
10
11
12
13
14
|
rem Suppress Terminate batch job on CTRL+C
if not ""%1"" == ""run"" goto mainEntry
if "%TEMP%" == "" goto mainEntry
if exist "%TEMP%\%~nx0.run" goto mainEntry
echo Y>"%TEMP%\%~nx0.run"
if not exist "%TEMP%\%~nx0.run" goto mainEntry
echo Y>"%TEMP%\%~nx0.Y"
call "%~f0" %* <"%TEMP%\%~nx0.Y"
rem Use provided errorlevel
set RETVAL=%ERRORLEVEL%
del /Q "%TEMP%\%~nx0.Y" >NUL 2>&1
exit /B %RETVAL%
:mainEntry
del /Q "%TEMP%\%~nx0.run" >NUL 2>&1
|
脚本的作用
判断用户是否使用
catalina.bat run
来启动 Tomcat 的.
如果用户使用 startup.bat 脚本启动 Tomcat, 那么这段脚本不会被执行.
这段代码看起来很乱, 慢慢分析.
第一行:
注释, 意思就是: 禁止使用 CTRL+C 来终止批处理任务, 也不知道是怎么禁止的.
第二行:
if not ""%1"" == ""run"" goto mainEntry
首先明白这里的这个 "%1" 这个变量代表的是什么? 正常情况下, 这个脚本是被 startup.bat 脚本调用的, 被调用的同时传递了一个 start 参数过来(上一篇分析得出的). 在 批处理命令 中 %1 就表示命令之后的第一个参数, 在这里指的就是 start. 所以 "%1" = start. 如果用户用 catalina.bat run 命令启动 Tomcat 的话, 那么这里的 "%1" = run.
第三行:
if "%TEMP%" == "" goto mainEntry
这里的 %TEMP% 很有可能被认为是 空, 其实这里可以读取到系统的环境变量. 所以, 这里的 %TEMP% 就是系统的环境变量值, 通常装完 windows 系统的话, 系统会自动配置上这个环境变量. 所以这里一般是有值的. 大家可以去系统的环境变量看一下它指向那个目录, 一般就是 C:\Users\用户名\AppData\Local\Temp. 注意: AppData 是一个隐藏目录.
第四行:
if exist "%TEMP%\%~nx0.run" goto mainEntry
这里又出现了一个新的东西 %~nx0 . 在批处理中, 我们知道 %1 表示的是程序之后的第一个参数, 那么 %0 呢? %0 表示这个可执行程序的名称, %~nx0 的话就是程序的名称+扩展名
在这里就是 catalina.bat . 大家可以写一个小脚本(test.bat)验证一下: (我的脚本放在 D 盘下)
脚本内容:
|
1
2
3
|
@echo off
echo "%~nx0"
echo "%1"
|
执行结果:
|
1
2
3
4
|
PS D:\> .\test.bat Hello
"test.bat"
"Hello"
PS D:\>
|
第五行:
echo Y>"%TEMP%\%~nx0.run"
这段代码很简单, 就是写入字符 Y 到 %TEMP%\catalina.bat.run 文件中.
第六行:
if not exist "%TEMP%\%~nx0.run" goto mainEntry
又判断了一下 %TEMP%\catalina.bat.run 文件是否存在.
第七行:
echo Y>"%TEMP%\%~nx0.Y"
同第五行, 写入 Y 到 %TEMP%\catalina.bat.Y . 如果文件不存在, 则新建一个.
第八行:
call "%~f0" %* <"%TEMP%\%~nx0.Y"
这一行有点意思. 又出现了两个新的东西:
(因为 markdown 语法限制, 把下面代码写到代码块里)
- "%~f0" : 简单说就是表示当前命令的绝对路径.
- "%*" : 我们知道 %1 表示第一个参数, 依次类推, %2 表示第二个.... 那么 %* 就很好理解了, 代表所有参数.
验证一下
脚本内容:
|
1
2
3
|
@echo off
echo "%*"
echo "%~f0"
|
执行结果:
|
1
2
3
4
|
PS D:\> .\test.bat Hello World
"Hello World"
"D:\test.bat"
PS D:\>
|
那么后面的 <"%TEMP%\%~nx0.Y" 意思就是读取 %TEMP%\catalina.bat.Y 文件中的内容.
之后又通过 call 进行调用.
我们自己写一个例子, 在 D 盘建立 test.bat 文件, 再建立 catalina.bat.Y 文件
脚本内容:
call "%~f0" %* < D:/catalina.bat.Y
catalina.bat.Y 文件内容
Y
执行结果:
|
1
2
3
4
5
6
7
8
9
10
11
|
........
D:\>call "D:\test.bat" Hello World 0<D:/catalina.bat.Y
D:\>call "D:\test.bat" Hello World 0<D:/catalina.bat.Y
D:\>call "D:\test.bat" Hello World 0<D:/catalina.bat.Y
D:\>call "D:\test.bat" Hello World 0<D:/catalina.bat.Y
D:\>call "D:\test.bat" Hello World 0<D:/catalina.bat.Y
D:\>call "D:\test.bat" Hello World 0<D:/catalina.bat.Y
D:\>call "D:\test.bat" Hello World 0<D:/catalina.bat.Y
****** B A T C H R E C U R S I O N exceeds STACK limits ******
Recursion Count=593, Stack Usage=90 percent
****** B A T C H PROCESSING IS A B O R T E D ******
|
最上面省略了很多重复代码, 从这里发现它不断地调用自己本身, 直到超出了堆栈的限制才停止.
我们如果加上 @echo off 的话
|
1
2
|
@echo off
call "%~f0" %* < D:/catalina.bat.Y
|
结果只会出现
|
1
2
3
4
|
D:\>.\test.bat Hello World
****** B A T C H R E C U R S I O N exceeds STACK limits ******
Recursion Count=593, Stack Usage=90 percent
****** B A T C H PROCESSING IS A B O R T E D ******
|
我们这里只需要明白这些命令的作用就可以, 稍后我们会总结 Tomcat 执行这些命令的目的.
第十行:
set RETVAL=%ERRORLEVEL%
我们如果了解 Linux 的话都知道, 每个命令的执行都会返回一个执行完成之后的退出码. Linux执行完一条命令之后用 echo $? 来查看上一条命令的退出码. 在 Windows 中也是一样的, 命令执行完之后都有自己的退出码. 这里的 %ERRORLEVEL% 就是取的上面的 call 命令的退出码. 赋值给一个变量 RETVAL
第十一行:
del /Q "%TEMP%\%~nx0.Y" >NUL 2>&1
这里又出现了一个 del 命令, 很容易联想到 delete, 那么 /Q 是什么意思呢? 静默删除, 不会给你任何提示, 就比如 Linux 中的 rm -f 一样, 这里是删除 %TEMP%\catalina.bat.Y 这个文件.
后面的 >NUL 2>&1 又是什么意思呢?
于 Linux 中的输出流的重定向原理是一样的.
(因为 markdown 语法限制, 把下面代码写到代码块里)
|
1
2
3
|
- >NUL : 表示将输出重定向到 NUL 中, 你什么也看不到
- 2>&1 : 2:错误输出, &1: 标准输出, 意思就是将错误消息输出到标准输出中.
- >NUL 2>&1 : 就是先将错误消息输出到标准输出中, 然后再输出到 NUL 中.
|
第十二行:
exit /B %RETVAL%
退出当前批处理, /B 指定退出时的编号, 把 RETVAL 最为 退出码, 也就是 call 执行的命令 的退出码.
最后两行:
|
1
2
|
:mainEntry
del /Q "%TEMP%\%~nx0.run" >NUL 2>&1
|
定义一个 mainEntry 标签, 然后删除 临时目录中的 catalina.bat.run 文件.
总结第一段脚本的功能
简单说, 这段代码的作用就是调用本身, 判断临时目录中的文件是否存在来避免二次回调自己. 感觉写的好复杂.
下面就进入 Tomcat 的正式启动过程, 并没有开始执行 main 方法
第二段脚本代码
|
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
|
rem Guess CATALINA_HOME if not defined
set "CURRENT_DIR=%cd%"
if not "%CATALINA_HOME%" == "" goto gotHome
set "CATALINA_HOME=%CURRENT_DIR%"
if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
cd ..
set "CATALINA_HOME=%cd%"
cd "%CURRENT_DIR%"
:gotHome
if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
echo The CATALINA_HOME environment variable is not defined correctly
echo This environment variable is needed to run this program
goto end
:okHome
rem Copy CATALINA_BASE from CATALINA_HOME if not defined
if not "%CATALINA_BASE%" == "" goto gotBase
set "CATALINA_BASE=%CATALINA_HOME%"
:gotBase
|
这段脚本还是比较简单的, 主要是设置了两个环境变量 CATALINA_HOME 和 CATALINA_BASE .
如果没有配置 CATALINA_BASE 环境变量的话, 直接引用 CATALINA_HOME 的值
静下心来稍微看一下就懂了.
第三段脚本代码
|
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
|
rem Ensure that neither CATALINA_HOME nor CATALINA_BASE contains a semi-colon
rem as this is used as the separator in the classpath and Java provides no
rem mechanism for escaping if the same character appears in the path. Check this
rem by replacing all occurrences of ';' with '' and checking that neither
rem CATALINA_HOME nor CATALINA_BASE have changed
if "%CATALINA_HOME%" == "%CATALINA_HOME:;=%" goto homeNoSemicolon
echo Using CATALINA_HOME: "%CATALINA_HOME%"
echo Unable to start as CATALINA_HOME contains a semicolon (;) character
goto end
:homeNoSemicolon
if "%CATALINA_BASE%" == "%CATALINA_BASE:;=%" goto baseNoSemicolon
echo Using CATALINA_BASE: "%CATALINA_BASE%"
echo Unable to start as CATALINA_BASE contains a semicolon (;) character
goto end
:baseNoSemicolon
|
这里主要是判断 CATALINA_HOME 环境变量的值 和 CATALINA_BASE 环境变量的值是否以 分号为结尾, 如果以 分号为结尾的话, 就报错退出.
第四段脚本代码
|
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
|
rem Ensure that any user defined CLASSPATH variables are not used on startup,
rem but allow them to be specified in setenv.bat, in rare case when it is needed.
set CLASSPATH=
rem Get standard environment variables
if not exist "%CATALINA_BASE%\bin\setenv.bat" goto checkSetenvHome
call "%CATALINA_BASE%\bin\setenv.bat"
goto setenvDone
:checkSetenvHome
if exist "%CATALINA_HOME%\bin\setenv.bat" call "%CATALINA_HOME%\bin\setenv.bat"
:setenvDone
rem Get standard Java environment variables
if exist "%CATALINA_HOME%\bin\setclasspath.bat" goto okSetclasspath
echo Cannot find "%CATALINA_HOME%\bin\setclasspath.bat"
echo This file is needed to run this program
goto end
:okSetclasspath
call "%CATALINA_HOME%\bin\setclasspath.bat" %1
if errorlevel 1 goto end
|
设置一个临时环境变量: CLASSPATH.
如果 Tomcat 的 bin 目录下面存在 setnv.bat 脚本的话, 就执行它. 通常情况下是没有的.
继而又判断 setclasspath.bat 脚本是否存在, 如果不存在的话, 直接报错, 停止启动 Tomcat.
如果存在的话, 就去调用它, 并把 第一个参数传进去.
setclasspath.bat 这个脚本主要设置了几个环境变量
- JAVA_HOME
- JRE_HOME
- JAVA_ENDORSED_DIRS = %CATALINA_HOME%\endorsed
- _RUNJAVA = %JRE_HOME%\bin\java.exe
- _RUNJDB = %JAVA_HOME%\bin\jdb.exe
第五段脚本代码
|
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
|
rem Add on extra jar file to CLASSPATH
rem Note that there are no quotes as we do not want to introduce random
rem quotes into the CLASSPATH
if "%CLASSPATH%" == "" goto emptyClasspath
set "CLASSPATH=%CLASSPATH%;"
:emptyClasspath
set "CLASSPATH=%CLASSPATH%%CATALINA_HOME%\bin\bootstrap.jar"
if not "%CATALINA_TMPDIR%" == "" goto gotTmpdir
set "CATALINA_TMPDIR=%CATALINA_BASE%\temp"
:gotTmpdir
rem Add tomcat-juli.jar to classpath
rem tomcat-juli.jar can be over-ridden per instance
if not exist "%CATALINA_BASE%\bin\tomcat-juli.jar" goto juliClasspathHome
set "CLASSPATH=%CLASSPATH%;%CATALINA_BASE%\bin\tomcat-juli.jar"
goto juliClasspathDone
:juliClasspathHome
set "CLASSPATH=%CLASSPATH%;%CATALINA_HOME%\bin\tomcat-juli.jar"
:juliClasspathDone
|
这段代码主要做了三件事:
- 把 Tomcat bin 目录下的 bootstrap.jar 加入到环境变量中
- 设置 CATALINA_TMPDIR 环境变量的值为 Tomcat 目录下的 temp 目录
- 把 Tomcat bin 目录下的 tomcat-juli.jar 加入到环境变量中
第六段脚本代码
|
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
|
if not "%JSSE_OPTS%" == "" goto gotJsseOpts
set JSSE_OPTS="-Djdk.tls.ephemeralDHKeySize=2048"
:gotJsseOpts
set "JAVA_OPTS=%JAVA_OPTS% %JSSE_OPTS%"
rem Register custom URL handlers
rem Do this here so custom URL handles (specifically 'war:...') can be used in the security policy
set "JAVA_OPTS=%JAVA_OPTS% -Djava.protocol.handler.pkgs=org.apache.catalina.webresources"
if not "%LOGGING_CONFIG%" == "" goto noJuliConfig
set LOGGING_CONFIG=-Dnop
if not exist "%CATALINA_BASE%\conf\logging.properties" goto noJuliConfig
set LOGGING_CONFIG=-Djava.util.logging.config.file="%CATALINA_BASE%\conf\logging.properties"
:noJuliConfig
set "JAVA_OPTS=%JAVA_OPTS% %LOGGING_CONFIG%"
if not "%LOGGING_MANAGER%" == "" goto noJuliManager
set LOGGING_MANAGER=-Djava.util.logging.manager=org.apache.juli.ClassLoaderLogManager
:noJuliManager
set "JAVA_OPTS=%JAVA_OPTS% %LOGGING_MANAGER%"
|
主要是追加一系列的启动参数到 JAVA_OPTS 这个环境变量中.
第八段脚本代码
|
1
2
3
4
5
6
7
8
9
10
|
echo Using CATALINA_BASE: "%CATALINA_BASE%"
echo Using CATALINA_HOME: "%CATALINA_HOME%"
echo Using CATALINA_TMPDIR: "%CATALINA_TMPDIR%"
if ""%1"" == ""debug"" goto use_jdk
echo Using JRE_HOME: "%JRE_HOME%"
goto java_dir_displayed
:use_jdk
echo Using JAVA_HOME: "%JAVA_HOME%"
:java_dir_displayed
echo Using CLASSPATH: "%CLASSPATH%"
|
主要是打印相关的环境变量信息.
第九段脚本代码
|
1
2
3
4
5
6
|
set _EXECJAVA=%_RUNJAVA%
set MAINCLASS=org.apache.catalina.startup.Bootstrap
set ACTION=start
set SECURITY_POLICY_FILE=
set DEBUG_OPTS=
set JPDA=
|
设置一些列的环境变量:
- _RUNJAVA : %JRE_HOME%\bin\java.exe
- MAINCLASS : 指定了 Tomcat 的启动类, 没错 main 方法就是在这个类里面.
- ACTION : 动作: 就是启动
- SECURITY_POLICY_FILE : 安全策略文件, 如果启动的时候加上了 -security 参数的话, 下面会对这个参数指定到 Tomcat 的 conf 目录下的 catalina.policy 文件.
- JPDA : 这个参数可以百度一下, 我们平时几乎用不到.
第十段代码
|
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
|
if not ""%1"" == ""jpda"" goto noJpda
set JPDA=jpda
if not "%JPDA_TRANSPORT%" == "" goto gotJpdaTransport
set JPDA_TRANSPORT=dt_socket
:gotJpdaTransport
if not "%JPDA_ADDRESS%" == "" goto gotJpdaAddress
set JPDA_ADDRESS=localhost:8000
:gotJpdaAddress
if not "%JPDA_SUSPEND%" == "" goto gotJpdaSuspend
set JPDA_SUSPEND=n
:gotJpdaSuspend
if not "%JPDA_OPTS%" == "" goto gotJpdaOpts
set JPDA_OPTS=-agentlib:jdwp=transport=%JPDA_TRANSPORT%,address=%JPDA_ADDRESS%,server=y,suspend=%JPDA_SUSPEND%
:gotJpdaOpts
shift
:noJpda
|
好像直接从第一行跳到了最后一行, 没错, 一般我没启动的时候没有加 jpda 参数的话, 这里会直接跳过, 里面的脚本是关于 JPDA 的设置等.
第十一段脚本代码
|
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
|
if ""%1"" == ""debug"" goto doDebug
if ""%1"" == ""run"" goto doRun
if ""%1"" == ""start"" goto doStart
if ""%1"" == ""stop"" goto doStop
if ""%1"" == ""configtest"" goto doConfigTest
if ""%1"" == ""version"" goto doVersion
echo Usage: catalina ( commands ... )
echo commands:
echo debug Start Catalina in a debugger
echo debug -security Debug Catalina with a security manager
echo jpda start Start Catalina under JPDA debugger
echo run Start Catalina in the current window
echo run -security Start in the current window with security manager
echo start Start Catalina in a separate window
echo start -security Start in a separate window with security manager
echo stop Stop Catalina
echo configtest Run a basic syntax check on server.xml
echo version What version of tomcat are you running?
goto end
|
好似一个 switch 开关.
- 如果我们用 startup.bat 启动 Tomcat 的话, 这里的 "%1" 的值是 start
- 如果通过 catalina.bat run 启动 Tomcat 的话, 这里的 "%1" 的值是 run
第十二段脚本代码
|
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
|
:doRun
shift
if not ""%1"" == ""-security"" goto execCmd
shift
echo Using Security Manager
set "SECURITY_POLICY_FILE=%CATALINA_BASE%\conf\catalina.policy"
goto execCmd
:doStart
shift
if "%TITLE%" == "" set id="codetool">
首先分析一下其中的两个 shift 命令 第一个 shift 是把 start 或者 run 参数移除, 然后下面 还是利用 "%1" 来取参数, 这时候, 取出来的就是参数列表中的第二个. 第二个 shift 是在第二个参数移除掉. 我们再来比较一下 start 和 run 的启动区别. 差别
|
