T-SQL查询： TOP N [PERCENT] WITH TIES ORDER BY 顺序排序实例

USE tempdb
GO

--DROP TABLE #TEST
CREATE TABLE #TEST(DEPTNAME VARCHAR(50),AMOUNT INT)

INSERT INTO #TEST(DEPTNAME,AMOUNT)
VALUES
('销售1部',99),
('销售2部',100),
('销售3部',86),
('销售4部',100),
('销售5部',86),
('销售6部',100),
('销售7部',200),
('销售8部',88),
('销售9部',200),
('销售10部',56)

SELECT * FROM #TEST ORDER BY AMOUNT DESC

-- 【问题: 查询业绩最好的前3个部门？】



--错误方法一：
SELECT TOP 3 * FROM #TEST ORDER BY AMOUNT DESC
/*
DEPTNAMEAMOUNT
销售7部200
销售9部200
销售4部100
*/

--这样求解似乎是正确的,但是销售额100(W)的有3个部门是并列的，应该包括进去!



--错误方法二：

SELECT * FROM (
SELECT DENSE_RANK()OVER(ORDER BY AMOUNT DESC) AS ID,* FROM #TEST
) T WHERE ID <= 3

/*
IDDEPTNAMEAMOUNT
1销售7部200
1销售9部200
2销售6部100
2销售2部100
2销售4部100
3销售1部99
*/

--问题只要前3名，但是 “销售1部” 99(W)已属于第6名了，不应包括！




--应要求结果应如下所示：
/*
DEPTNAMEAMOUNT
销售7部200
销售9部200
销售6部100
销售2部100
销售4部100
*/


/*******************解决**********************/


--方法一：常用的一种方法

SELECT * FROM (
SELECT RANK()OVER(ORDER BY AMOUNT DESC) AS ID,* FROM #TEST
) T WHERE ID <= 3



--方法二：用【WITH TIES】
SELECT TOP 3 WITH TIES * FROM #TEST ORDER BY AMOUNT DESC



--【WITH TIES】参考：http://msdn.microsoft.com/zh-cn/library/ms189463.aspx