Excel VBA从另一个名为range的工作簿中拉出非Null行

New to the site with weak VBA skills. Hoping I can find some assistance with something I have been struggling with for days. I have found many examples that are close, and cant seem to marry them together. I am using Excel 2007. I have a "Summary_Reports" WB, as well as several other workbooks named by employee (eg. "Jim.xls", "bob.xls", etc). Each of the employee workbooks has a named range "caps" sourced from sheet "Tasks". This named range in each employee wb is the same width (number of columns) but can vary in height (number of rows), and some of the rows may be empty. Trying to setup a macro in "Summary_Reports" wb that will open each of the employees wb, copy the named range "caps", and insert/paste only the rows of that range containing data in the first column, to the "Report" sheet in the "Summary_Reports" wb. I assumed the easiest paste method would just be to pick a cell at the top and always insert those rows there, that way each employee would just get inserted above the previous one starting at the same spot. That way no counting or looking for the last populated row on the sheet. I attempted at first to open "Jim.xls" and copy the named range directly from the workbook, but had little success and a lot of trouble with syntax. So I ended up with the code below that pulls the employee sheet into "Summery_Reports" and then copies the named range from itself instead of another wb. Would probably end up deleting those sheets at the end.

具有弱VBA技能的网站新手。希望我能找到一些我一直在努力奋斗的东西。我发现许多例子很接近，似乎无法将它们结合在一起。我正在使用Excel 2007.我有一个“Summary_Reports”WB，以及员工命名的其他几个工作簿（例如“Jim.xls”，“bob.xls”等）。每个员工工作簿都有一个来自工作表“任务”的命名范围“大写”。每个员工wb中的此命名范围是相同的宽度（列数），但高度（行数）可能不同，并且某些行可能为空。尝试在“Summary_Reports”wb中设置一个宏，它将打开每个员工wb，复制命名范围“caps”，并仅将包含第一列中数据的范围的行插入/粘贴到“Report”表在“Summary_Reports”wb中。我假设最简单的粘贴方法只是在顶部选择一个单元格并始终在那里插入那些行，这样每个员工就会从同一个位置开始插入到前一个上面。这样就不会计算或查找工作表上最后填充的行。我首先尝试打开“Jim.xls”并直接从工作簿中复制命名范围，但是在语法方面没有什么成功和很多麻烦。所以我最终得到了下面的代码，将员工表拉入“Summery_Reports”，然后从自己复制命名范围而不是另一个wb。可能最终会删除那些表格。

What I have started below kinda works, but the data validation I know isn't correct. Correct me if I am wrong but it is only checking the top left cell of "caps" right; if there are contents, it pastes all of "caps", and if that single cell is empty, it pastes nothing. How do I correct the validation to check the first column of every row and also how do I get it to just give me the rows with data?

我开始下面有点工作，但我知道的数据验证是不正确的。如果我错了，请纠正我，但只检查右上角的“帽子”;如果有内容，它会粘贴所有“大写”，如果该单个单元格为空，则不会粘贴任何内容。如何更正验证以检查每一行的第一列，以及如何让它只给我带有数据的行？

Also, I know there is a better way to get the "caps" data directly from each of the employee wb, without importing the sheet first. If that can be done easily, I would be very interested in any advice in that regard.

此外，我知道有一种更好的方法可以直接从每个员工wb获取“大写”数据，而无需先导入工作表。如果可以轻松完成，我会对这方面的任何建议非常感兴趣。

If you are kind enough to help me, please dumb it down as much as possible as I am really interested in actually knowing what the code does and not just copying and pasting. Thank you in advance.

如果你很友好地帮助我，请尽可能地愚蠢，因为我真的很想知道代码的作用，而不仅仅是复制和粘贴。先谢谢你。

Sub Import_Sheets()
Application.Workbooks.Open ("jim.xls")
Workbooks("jim.xls").Activate
Sheets("Tasks").Copy After:=Workbooks("Summary_Report.xlsm").Sheets("Report")
Application.Workbooks("Jim.xls").Close

'Go to newly copied sheet and name it.
ActiveSheet.Name = "jim"

'Copy the "caps" named range.
With Range("Caps")
    If .Cells(1, 1).Value = "" Then
    Else
        Range("Caps").Select
        Selection.Copy
        Sheets("Report").Select
        Range("B2").Select
        Selection.Insert Shift:=xlDown
    End If
End With
End Sub

1 个解决方案

#1

Commented code:

评论代码：

Sub Import_Sheets()

    'Declare variables
    Dim wsDest As Worksheet 'This is the sheet that data will be pasted to
    Dim rngCaps As Range    'This is used to determine if there is a named range "Caps"
    Dim rngFound As Range   'This is used to loop through the first column in the named range "Caps"
    Dim rngSearch As Range  'This is used to determine where to search
    Dim rngCopy As Range    'This is used to store the rows with data that will be copied
    Dim strFirst As String  'This is used to store the first cell address to prevent an infinite loop
    Dim i As Long           'This is used to loop through the selected workbooks

    'Create an "Open File" dialogue for the user to choose which files to import
    With Application.FileDialog(msoFileDialogFilePicker)
        .Filters.Clear                          'Clear existing filters (if any)
        .Filters.Add "Excel Files", "*.xls*"    'Filter for Excel files
        .AllowMultiSelect = True                'Allow user to select multiple files at a time with Shift or Ctrl

        If .Show = False Then Exit Sub  'Pressed cancel, exit macro

        'The destination is this workbook, sheet 'Report'
        Set wsDest = ActiveWorkbook.Sheets("Report")

        'Turn off screenupdating.  This prevents "Screen Flickering" and allows the code to run faster
        Application.ScreenUpdating = False

        'Begin loop through selected files
        For i = 1 To .SelectedItems.Count

            'Open a selected file
            With Workbooks.Open(.SelectedItems(i))

                'Attempt to find a sheet named 'TimeEntry' with a named range "Caps"
                On Error Resume Next
                Set rngCaps = .Sheets("TimeEntry").Range("Caps")
                On Error GoTo 0 'Remove the On Error Resume Next condition

                'Was it able to set rngCaps successfully?
                If Not rngCaps Is Nothing Then
                    'Yes, proceed to find rows with data
                    'Define rngSearch which will be used to find rows with data
                    Set rngSearch = Intersect(rngCaps, rngCaps.Cells(1).MergeArea.EntireColumn)

                    'Use a find loop to only get rows with data
                    'We can do this by utilizing the wildcard *
                    'The .Resize(, 1) will make sure we are only looking in the first column of rngCaps
                    Set rngFound = rngSearch.Find("*", rngSearch.Cells(rngSearch.Cells.Count), xlValues, xlWhole)

                    'Was there a cell found with data?
                    If Not rngFound Is Nothing Then
                        'Yes, record this first cell's address to prevent infinite loop
                        strFirst = rngFound.Address

                        'Also start storing the rows where data was found
                        Set rngCopy = rngFound

                        'Begin the find loop
                        Do
                            'Add found rows to the rngCopy variable
                            Set rngCopy = Union(rngCopy, rngFound)

                            'Advance loop to the next cell that contains data
                            Set rngFound = rngSearch.Find("*", rngFound, xlValues, xlWhole)

                        'Exit the loop when we are back to the first cell
                        Loop While rngFound.Address <> strFirst

                        'Copy the rows with data and paste them into the next available row in the destination worksheet
                        Intersect(rngCaps, rngCopy.EntireRow).Copy wsDest.Cells(wsDest.Rows.Count, "B").End(xlUp).Offset(1)

                        'Clear rngFound and rngCopy to get ready for next workbook
                        Set rngFound = Nothing
                        Set rngCopy = Nothing
                    End If

                    'Clear rngCaps to get ready for next workbook
                    Set rngCaps = Nothing
                End If

                'Close this opened workbook and don't save changes
                .Close False
            End With

        'Advance to the next workbook that was selected
        Next i

        'Re-enable screen updating
        Application.ScreenUpdating = True

        'Object variable cleanup
        Set wsDest = Nothing

    End With

End Sub