将一个windows批处理文件变量设置为一个星期的一天。

I have a windows batch file that runs daily. Wish to log data into a file and want to rotate it (i.e. having at most the last 7 days worth of data).

我有一个每天运行的windows批处理文件。希望将数据记录到一个文件中，并希望将其旋转(即在过去7天的数据中拥有最多的数据)。

Looked into the commands DATE and DELIMS - Cannot figure out a solution.

查看命令日期和DELIMS——无法找到解决方案。

Is there a simple solution to create a file name that contains the day of the week i.e. 0 for monday etc.

是否有一个简单的解决方案来创建一个文件名，该文件名包含周一的日期，即周一的0。

Or do I have to resort to some better shell script.

或者，我必须求助于更好的shell脚本。

16 个解决方案

#1

%DATE% is not your friend. Because the %DATE% environment variable (and the DATE command) returns the current date using the Windows short date format that is fully and endlessly customizable. One user may configure the system to return 07/06/2012 while another might choose Fri060712. Using %DATE% is a complete nightmare for a BAT programmer.

%日期不是你的朋友。因为%DATE%环境变量(和DATE命令)使用Windows短日期格式返回当前日期，这是完全且可无限定制的。一个用户可以配置系统返回07/06/2012，而另一个用户可以选择Fri060712。使用%DATE%对于一个BAT程序员来说是一场噩梦。

There are two possible approaches to solve this problem:

解决这个问题有两种可能的方法:

1. You may be tempted to temporarily change the short date format, by changing the locale settings in the registry value HKCU\Control Panel\International\sShortDate, to your recognizable format. Then access %DATE% to get the date in the format you want; and finally restore the format back to the original user format. Something like this

   您可能想要临时更改短日期格式，通过更改注册表值HKCU\国际\sShortDate的地区设置，以您可识别的格式。然后访问%DATE%以获得所需格式的日期;最后将格式恢复到原来的用户格式。像这样的东西

   reg copy "HKCU\Control Panel\International" "HKCU\Control Panel\International-Temp" /f >nul
   reg add "HKCU\Control Panel\International" /v sShortDate /d "ddd" /f >nul
   set DOW=%DATE%
   reg copy "HKCU\Control Panel\International-Temp" "HKCU\Control Panel\International" /f >nul
   

   but this method has two problems:

   但是这个方法有两个问题:

   • it tampers with a global registry value for its local particular purpouses, so it may interfere with other processes or user tasks that at the very same time query the date in short date format, including itself if run simultaneously.

     它为本地特定的purp提供一个全局注册表值，因此它可能会干扰其他进程或用户任务，这些进程或用户任务在同一时间以短日期格式查询日期，包括如果同时运行的话。

   • and it returns the three letter day of the week in the local language that may be different in different systems or different users.

     它还会以本地语言返回这周的三个字母日，在不同的系统或不同的用户中可能是不同的。

2. use WMIC Win32_LocalTime, that returns the date in a convenient way to directly parse it with a FOR command.

   使用WMIC Win32_LocalTime，它以方便的方式返回日期，以便直接用FOR命令解析它。

   FOR /F "skip=1" %%A IN ('WMIC Path Win32_LocalTime Get DayOfWeek' ) DO (
     set DOW=%%A
   )
   

   this is the method I recommend.

   这是我推荐的方法。

#2

few more ways:

几个方面:

1.Robocopy not available in XP but can be downloaded form with win 2003 resource tool kit .Also might depend on localization:

1。在XP中没有可用的Robocopy，但可以通过win 2003资源工具包下载表单。

@echo off
setlocal 
for /f "skip=8 tokens=2,3,4,5,6,7,8 delims=: " %%D in ('robocopy /l * \ \ /ns /nc /ndl /nfl /np /njh /XF * /XD *') do (
 set "dow=%%D"
 set "month=%%E"
 set "day=%%F"
 set "HH=%%G"
 set "MM=%%H"
 set "SS=%%I"
 set "year=%%J"
)

echo Day of the week: %dow%
endlocal

2.MAKECAB - works on every windows machine (but creates a small temp file).Function provided by carlos:

2。MAKECAB -在每个windows机器上工作(但是创建一个小的临时文件)。卡洛斯:所提供的函数

@Echo Off


Call :GetDate.Init
Rem :GetDate.Init should be called one time in the code before call to :Getdate
Call :GetDate
Echo weekday:%weekday%

Goto :EOF

:GetDate.Init
Set /A "jan=1,feb=2,mar=3,apr=4,may=5,jun=6,jul=7,aug=8,sep=9,oct=10,nov=11,dec=12"
Set /A "mon=1,tue=2,wed=3,thu=4,fri=5,sat=6,sun=7"
(
Echo .Set InfHeader=""
Echo .Set InfSectionOrder=""
Echo .Set InfFooter="%%2"
Echo .Set InfFooter1=""
Echo .Set InfFooter2=""
Echo .Set InfFooter3=""
Echo .Set InfFooter4=""
Echo .Set Cabinet="OFF"
Echo .Set Compress="OFF"
Echo .Set DoNotCopyFiles="ON"
Echo .Set RptFileName="NUL"
) >"%Temp%\~foo.ddf"
Goto :Eof

:GetDate
Set "tf=%Temp%\~%random%"
Makecab /D InfFileName="%tf%" /F "%Temp%\~foo.ddf" >NUL
For /F "usebackq tokens=1-7 delims=: " %%a In ("%tf%") Do (
Set /A "year=%%g,month=%%b,day=1%%c-100,weekday=%%a"
Set /A "hour=1%%d-100,minute=1%%e-100,second=1%%f-100")
Del "%tf%" >NUL 2>&1
Goto :Eof

3.W32TM - uses command switches introduced in Vista so will not work on windows 2003/XP:

3所示。W32TM -使用Vista中引入的命令开关，所以不会在windows 2003/XP上工作:

@echo off
setlocal
call :w32dow day_ow
echo %day_ow%
pause
exit /b 0
endlocal
:w32dow [RrnVar]
setlocal

rem :: prints the day of the week
rem :: works on Vista and above


rem :: getting ansi date ( days passed from 1st jan 1601 ) , timer server hour and current hour
FOR /F "tokens=4,5 delims=:( " %%D in ('w32tm /stripchart /computer:localhost  /samples:1  /period:1 /dataonly /packetinfo^|find "Transmit Timestamp:" ') do (
 set "ANSI_DATE=%%D"
 set  "TIMESERVER_HOURS=%%E"
)

set  "LOCAL_HOURS=%TIME:~0,2%"
if "%TIMESERVER_HOURS:~0,1%0" EQU "00" set TIMESERVER_HOURS=%TIMESERVER_HOURS:~1,1%
if "%LOCAL_HOURS:~0,1%0" EQU "00" set LOCAL_HOURS=%LOCAL_HOURS:~1,1%
set /a OFFSET=TIMESERVER_HOURS-LOCAL_HOURS

rem :: day of the week will be the modulus of 7 of local ansi date +1
rem :: we need need +1 because Monday will be calculated as 0
rem ::  1st jan 1601 was Monday

rem :: if abs(offset)>12 we are in different days with the time server

IF %OFFSET%0 GTR 120 set /a DOW=(ANSI_DATE+1)%%7+1
IF %OFFSET%0 LSS -120 set /a DOW=(ANSI_DATE-1)%%7+1
IF %OFFSET%0 LEQ 120 IF %OFFSET%0 GEQ -120 set /a DOW=ANSI_DATE%%7+1


rem echo Day of the week: %DOW% 
endlocal & if "%~1" neq "" (set "%~1=%DOW%") else echo %DOW%

4..bat/jscript hybrid (must be saved as .bat):

4 . .bat/jscript混合(必须保存为.bat):

 @if (@x)==(@y) @end /***** jscript comment ******
 @echo off
 for /f  %%d in ('cscript //E:JScript //nologo "%~f0"') do echo %%d
 exit /b 0
 *****  end comment *********/
 WScript.Echo((new Date).getDay());

5..bat/vbscript hybrid (must be saved as .bat)

5 . .bat/vbscript混合(必须保存为.bat)

 :sub echo(str) :end sub
echo off
'>nul 2>&1|| copy /Y %windir%\System32\doskey.exe '.exe >nul

'& echo/ 
'& for /f %%w in ('cscript /nologo /E:vbscript %~dpfn0') do echo day of the week %%w
'& echo/
'& del /q "'.exe" >nul 2>&1
'& exit /b

WScript.Echo Weekday(Date)
WScript.Quit

6.powershell can be downloaded from microsoft.Available by default in everything form win7 and above:

6。powershell可以从微软下载。默认情况下，所有表格win7及以上:

@echo off
setlocal
for /f %%d in ('"powershell (Get-Date).Day"') do set dow=%%d

echo day of the week : %dow%
endlocal

7.WMIC already used as an answer but just want to have a full reference.And with cleared <CR>:

7所示。WMIC已经作为一个答案，但只是想要有一个完整的参考。和清除< CR >:

@echo off
setlocal
for /f "delims=" %%a in ('wmic path win32_localtime get dayofweek /format:list ') do for /f "delims=" %%d in ("%%a") do set %%d

echo day of the week : %dayofweek%
endlocal

9.Selfcompiled jscript.net (must be saved as .bat):

9。自编译jscript.net(必须保存为.bat):

@if (@X)==(@Y) @end /****** silent line that start jscript comment ******

@echo off
::::::::::::::::::::::::::::::::::::
:::       compile the script    ::::
::::::::::::::::::::::::::::::::::::
setlocal
if exist "%~n0.exe" goto :skip_compilation

set "frm=%SystemRoot%\Microsoft.NET\Framework\"
:: searching the latest installed .net framework
for /f "tokens=* delims=" %%v in ('dir /b /s /a:d /o:-n "%SystemRoot%\Microsoft.NET\Framework\v*"') do (
    if exist "%%v\jsc.exe" (
        rem :: the javascript.net compiler
        set "jsc=%%~dpsnfxv\jsc.exe"
        goto :break_loop
    )
)
echo jsc.exe not found && exit /b 0
:break_loop


call %jsc% /nologo /out:"%~n0.exe" "%~dpsfnx0"
::::::::::::::::::::::::::::::::::::
:::       end of compilation    ::::
::::::::::::::::::::::::::::::::::::
:skip_compilation

"%~n0.exe"

exit /b 0


****** end of jscript comment ******/
import System;
import System.IO;

var dt=DateTime.Now;
 Console.WriteLine(dt.DayOfWeek);

#3

@ECHO OFF
REM GET DAY OF WEEK VIA DATE TO JULIAN DAY NUMBER CONVERSION
REM ANTONIO PEREZ AYALA
REM GET MONTH, DAY, YEAR VALUES AND ELIMINATE LEFT ZEROS
FOR /F "TOKENS=1-3 DELIMS=/" %%A IN ("%DATE%") DO SET /A MM=10%%A %% 100, DD=10%%B %% 100, YY=%%C
REM CALCULATE JULIAN DAY NUMBER, THEN DAY OF WEEK
IF %MM% LSS 3 SET /A MM+=12, YY-=1
SET /A A=YY/100, B=A/4, C=2-A+B, E=36525*(YY+4716)/100, F=306*(MM+1)/10, JDN=C+DD+E+F-1524
SET /A DOW=(JDN+1)%%7

DOW is 0 for Sunday, 1 for Monday, etc.

道琼斯指数周日为0，周一为1，等等。

#4

I thought that my first answer gives the correct day of week as a number between 0 and 6. However, because you had not indicated why this answer does not give the result you want, I can only guess the reason.

我想我的第一个答案是把一周的正确时间作为一个数字在0到6之间。然而，因为你没有说明为什么这个答案没有给出你想要的结果，我只能猜测原因。

The Batch file below create a log file each day with a digit in the name, 0=Sunday, 1=Monday, etc... The program assume that echo %date% show the date in MM/DD/YYYY format; if this is not the case, just change the position of mm and dd variables in the for command.

下面的批处理文件以名称中的一个数字创建一个日志文件，0=Sunday, 1=Monday，等等。该程序假定回波%日期%显示日期为MM/DD/YYYY格式;如果不是这样，只需更改for命令中mm和dd变量的位置。

@echo off
for /F "tokens=1-3 delims=/" %%a in ("%date%") do set /A mm=10%%a %% 100, dd=10%%b %% 100, yy=%%c
if %mm% lss 3 set /A mm+=12, yy-=1
set /A a=yy/100, b=a/4, c=2-a+b, e=36525*(yy+4716)/100, f=306*(mm+1)/10, dow=(c+dd+e+f-1523)%%7
echo Today log data > Day-%dow%.txt

If this is not what you want, please indicate the problem so I can fix it.

如果这不是你想要的，请指出问题，以便我能解决。

EDIT: The version below get date parts independent of locale settings:

编辑:以下版本的日期部分独立于地区设置:

@echo off
for /F "skip=1 tokens=2-4 delims=(-/)" %%A in ('date ^< NUL') do (
   for /F "tokens=1-3 delims=/" %%a in ("%date%") do (
      set %%A=%%a
      set %%B=%%b
      set %%C=%%c
   )
)
set /A mm=10%mm% %% 100, dd=10%dd% %% 100
if %mm% lss 3 set /A mm+=12, yy-=1
set /A a=yy/100, b=a/4, c=2-a+b, e=36525*(yy+4716)/100, f=306*(mm+1)/10, 

dow=(c+dd+e+f-1523)%%7
echo Today log data > Day-%dow%.txt

EDIT: The version below insert day of week as 3-letter short name:

编辑:以下版本为每周的3个字母短名称:

@echo off
for /F "skip=1 tokens=2-4 delims=(-/)" %%A in ('date ^< NUL') do (
   for /F "tokens=1-3 delims=/" %%a in ("%date%") do (
      set %%A=%%a
      set %%B=%%b
      set %%C=%%c
   )
)
set /A mm=10%mm% %% 100, dd=10%dd% %% 100
if %mm% lss 3 set /A mm+=12, yy-=1
set /A a=yy/100, b=a/4, c=2-a+b, e=36525*(yy+4716)/100, f=306*(mm+1)/10, 

dow=(c+dd+e+f-1523)%%7 + 1
for /F "tokens=%dow%" %%a in ("Sun Mon Tue Wed Thu Fri Sat") do set dow=%%a
echo Today log data > Day-%dow%.txt

Regards,

问候,

Antonio

安东尼奥

#5

This turned out way more complex then I first suspected, and I guess that's what intrigued me, I searched every where and all the methods given wouldnt work on Windows 7.

这让我的想法变得更加复杂，于是我开始怀疑，我想这就是吸引我的地方，我搜索了每一个地方，所有的方法都不会在Windows 7上运行。

So I have an alternate solution which uses a Visual Basic Script.

所以我有一个替代的解决方案，它使用了一个可视化的基本脚本。

The batch creates and executes the script(DayOfWeek.vbs), assigns the scripts output (Monday, Tuesday etc) to a variable (dow), the variable is then checked and another variable (dpwnum) assigned with the days number, afterwards the VBS is deleted hope it helps:

该批处理创建并执行脚本(DayOfWeek.vbs)，将脚本输出(星期一、星期二等)分配给一个变量(dow)，然后检查变量，然后将另一个变量(dpwnum)分配给天数，然后删除VBS希望它可以帮助:

@echo off

REM Create VBS that will get day of week in same directory as batch
echo wscript.echo WeekdayName(Weekday(Date))>>DayOfWeek.vbs

REM Cycle through output to get day of week i.e monday,tuesday etc
for /f "delims=" %%a in ('cscript /nologo DayOfWeek.vbs') do @set dow=%%a

REM delete vbs
del DayOfWeek.vbs

REM Used for testing outputs days name
echo %dow%

REM Case of the days name is important must have a capital letter at start
REM Check days name and assign value depending
IF %dow%==Monday set downum=0
IF %dow%==Tuesday set downum=1
IF %dow%==Wednesday set downum=2
IF %dow%==Thursday set downum=3
IF %dow%==Friday set downum=4
IF %dow%==Saturday set downum=5
IF %dow%==Sunday set downum=6

REM print the days number 0-mon,1-tue ... 6-sun
echo %downum%

REM set a file name using day of week number
set myfile=%downum%.bak

echo %myfile%

pause
exit

EDIT:

编辑:

Though I turned to VBS, It can be done in pure batch, took me a while to get it working and a lot of searching lol, but this seems to work:

虽然我求助于VBS，但它可以在纯批处理中完成，花了我一段时间来实现它的工作和大量的搜索lol，但这似乎是可行的:

 @echo off
SETLOCAL enabledelayedexpansion
SET /a count=0
FOR /F "skip=1" %%D IN ('wmic path win32_localtime get dayofweek') DO (
    if "!count!" GTR "0" GOTO next
    set dow=%%D
    SET /a count+=1
)
:next
echo %dow%
pause

The only caveat for you on the above batch is that its day of weeks are from 1-7 and not 0-6

以上批次的唯一警告是，它的周数是1-7，而不是0-6。

#6

This works for me

这适合我

FOR /F "tokens=3" %%a in ('robocopy ^|find "Started"') DO SET TODAY=%%a

#7

This is not my work (well, I modified it slightly from the example), and it's late to the game, but this works on Server 2003 for me;

这不是我的工作(嗯，我稍微修改了一下示例)，这已经很晚了，但是这是我的服务器2003年的工作;

@echo off  
set daysofweek=Monday,Tuesday,Wednesday,Thursday,Friday,Saturday,Sunday  
for /F "skip=2 tokens=2-4 delims=," %%A in ('WMIC Path Win32_LocalTime Get DayOfWeek /Format:csv') do set daynumber=%%A  
for /F "tokens=%daynumber% delims=," %%B in ("%daysofweek%") do set day=%%B

Citation: TechSupportForum

引文:TechSupportForum

#8

First - Copy CON SETUPDAY.001 SET WORKDAY=^Z (very important - no cr/lf)

第1 - 2个工作日= Z(非常重要-没有cr/lf)

DATE /T >SETUPDAY.002
COPY SETUPDAY.001+SETUPDAY.002 NEWDAY.BAT >nul
CALL NEWDAY.BAT

SET WEEKDAY=%WORKDAY:~0,3%
SET MDY=%WORKDAY:~4,10%

USE %WEEKDAY% IN YOUR SCRIPT

在脚本中使用%工作日%。

#9

Locale-dependent version: In some environments, the following will extract the day name from the date:

依赖于语言环境的版本:在某些环境中，以下将从日期中提取日期:

set dayname=%date:~0,3%

It assumes that the day name is the first part of %date%. Depending on the machine settings, though, the substring part (~0,3) would need to change.

它假定日名是%日期%的第一部分。但是，根据机器的设置，substring部分(~0,3)需要更改。

A statement such as this would dump to a file with a three character day name:

这样的语句将转储到具有三个字符日名称的文件:

set logfile=%date:~0,3%.log
echo some stuff > %logfile%

Locale-independent version: If you need it less dependent on the current machine's day format, another way of doing it would be to write a tiny application that prints the day of the week. Then use the output of that program from the batch file. For example, the following C application prints dayN where N=0..6.

独立于语言环境的版本:如果您需要更少的依赖于当前机器的日格式，另一种方法是编写一个小的应用程序来打印一周的一天。然后从批处理文件中使用该程序的输出。例如，下面的C应用程序打印dayN，其中N=0。

#include <stdio.h>
#include <time.h>

int main( int argc, char* argv[] )
{
   time_t curtime;
   struct tm * tmval;

   time( &curtime );
   tmval = localtime( &curtime );
   // print dayN.  Or use a switch statement and print
   // the actual day name if you want
   printf( "day%d", tmval->tm_wday );
}

If the above were compiled and linked as myday.exe, then you could use it from a batch file like this:

如果以上内容被编译并链接为myday。exe，然后可以从批处理文件中使用它:

for /f %%d in ('myday.exe') do set logfile=%%d.log
echo some stuff > %logfile%

#10

I am in the US. I can run this code in Windows 7, Windows 2008 R2, Windows Server 2003, Windows XP (All OS's are current with Windows Updates and patches). All with short date setting without ddd (or dddd) (day of week).

我在美国。我可以在Windows 7、Windows 2008 R2、Windows Server 2003、Windows XP(所有操作系统的当前都是Windows更新和补丁)中运行这个代码。没有ddd(或dddd)的所有时间设置都很短。

@echo off
for /f %%a in ('date /t') do set DAY=%%a
echo.
echo The Day Is: %DAY%
echo.

If today is Thursday, it would output "The Day Is: Thu".

如果今天是星期四，它将输出“今天是:Thu”。

This returns the day on all 4 Windows versions I have tested on. And only the day. When I changed my short date setup to be "ddd, M/d/yyyy", my output would show the day with a comma (e.g. Thu,) which tells me this code does use the short date format. But what also may be happening is that if the short date does not contain the day of week, it may look to the long date format which on all 4 machines I tested on, have dddd in the format.

这将返回我测试过的所有4个Windows版本的一天。只有一天。当我将我的短日期设置更改为“ddd, M/d/yyyy”时，我的输出将用逗号(例如Thu)来显示这一天，它告诉我这段代码使用的是短日期格式。但也可能发生的是，如果短日期不包含一周的日期，它可能会查找我测试过的所有4台机器上的长日期格式，有dddd格式。

#11

I have this solution working for me:

我有一个解决办法:

Create a file named dayOfWeek.vbs in the same dir where the cmd file will go.

创建一个名为dayOfWeek的文件。vbs在cmd文件将要运行的目录中。

dayOfWeek.vbs contains a single line:

dayOfWeek。vbs包含一行:

wscript.stdout.write weekdayname(weekday(date))

or, if you want day number instead of name:

或者，如果你想要一天的号码而不是名字:

wscript.stdout.write weekday(date)

The cmd file will have this line:

cmd文件将有这一行:

For /F %%A In ('CScript dayOfWeek.vbs //NoLogo') Do Set dayName=%%A

Now you can use variable dayName like:

现在可以使用变量dayName:

robocopy c:\inetpub \\DCStorage1\Share1\WebServer\InetPub_%dayName% /S /XD history logs

#12

If you can change format of short date in the PC to "ddd yyyy-MM-dd" (only first parameter 'ddd' is compulsory), then following command returns-

如果您可以将PC中的短日期格式更改为“ddd yyy- mm -dd”(只有第一个参数“ddd”是强制的)，那么下面的命令返回——。

c:\>vol | date
The current date is: Mon 2014-12-01

Then you can write you batch file -

然后您可以编写批处理文件。

@echo off

vol | date | find /i "sun" > nul 
if not errorlevel 1 goto SUN

vol | date | find /i "mon" > nul 
if not errorlevel 1 goto MON

      # write block for other week days    

goto END

:SUN
set fname="sun"
goto BACKUP

:MON
set fname="mon"
goto BACKUP

      # write block for other week days

:BACKUP
echo %fname%

:END

#13

Rem Remove the end comma and add /A to set for this line worked for me.
set /A a=yy/100, b=a/4, c=2-a+b, e=36525*(yy+4716)/100, f=306*(mm+1)/10 

#14

Was looking to do this myself and saw complaints about blank lines:

我自己也想这样做，并看到了关于空行的抱怨:

rem Make the win32_localtime output all one line, though some versions may contain blank lines as well.
rem So ignore blank lines and just pick up the number after the equal sign.
for /f "delims== tokens=2" %%a in ('wmic path win32_localtime get dayofweek /format:list') do (
    rem Increment the DOW as it is documented to be a zero-based index starting with Sunday.
    set /a DayOfWeekIndex=%%a+1
)
rem Also get name day of week. The DOW coming in is now a one-based index.
rem This is used to reference the "array" of week day names.
set DayOfWeekNames=Sun Mon Tue Wed Thu Fri Sat
for /f "tokens=%DayOfWeekIndex%" %%b in ("%DayOfWeekNames%") do (
    set DayOfWeekName=%%b
)

#15

I Improved Aacini Answer to make it Echo Full day of week Name

我改进了Aacini的答案，使它与周的名称一致。

So here's my Code

这是我的代码

@echo off
for /F "skip=1 tokens=2-4 delims=(-/)" %%A in ('date ^< NUL') do (
   for /F "tokens=1-3 delims=/" %%a in ("%date%") do (
      set %%A=%%a
      set %%B=%%b
      set %%C=%%c
   )
)
set /A mm=10%mm% %% 100, dd=10%dd% %% 100
if %mm% lss 3 set /A mm+=12, yy-=1
set /A a=yy/100, b=a/4, c=4-a+b, e=36525*(yy+4716)/100, f=306*(mm+1)/10,dow=(c+dd+e+f-1523)%%7 + 1
for /F "tokens=%dow%" %%a in ("Sunday Monday Tuesday Wednesday Thursday Friday Saturday ") do set dow=%%a
echo Today is %dow%>"Today is %dow%.txt"
echo Today is %dow%
Pause>Nul

REM Sun Mon Tue Wed Thu Fri Sat
REM Sunday Monday Tuesday Wednesday Thursday Friday Saturday  

#16

A version using MSHTA and javascript. Change %jsfunc% to whateve jscript function you want to call

一个使用MSHTA和javascript的版本。将%jsfunc%更改为您想要调用的jscript函数。

@echo off
::Invoke a javascript function using mhta

set jsfunc=new Date().getDay()
set dialog="about:<script>resizeTo(0,0);new ActiveXObject('Scripting.FileSystemObject').
set dialog=%dialog%GetStandardStream(1).WriteLine(%jsfunc%);close();</script>"

for /f "tokens=* delims=" %%p in ('mshta.exe %dialog%') do set ndow=%%p

::get dow string from array of strings  
for /f "tokens=%ndow%"  %%d in ("Mon Tue Wed Thu Fri Sat Sun") do set dow=%%d 

echo dow is : %ndow%  %dow%
pause