验证一下cmd的几种延时方法

时间：2022-05-03 00:24:37

最近工作用到cmd批处理的延时方法，网站找了找，发现一个介绍延时处理的博客，这是地址：http://blog.163.com/cb_dt/blog/static/481041420090322011317/?latestBlog （人家8年前就学会了，我今天才来学，不过8年前我还在上初中……）

根据那位网友的博客，我挑选里面比较好的延时方法， 写了一个验证的bat文件，在这里记录一下，免得以后用到的时候忘了。（发现自己越来越健忘了……）

注意：在vscode新建bat文件后，需要选择编码格式为GBK，否则在cmd窗口里面中文字符会显示乱码

 

1.废话不多说，直接上bat脚本文件吧（另存为bat后缀的文件，执行下看效果就可以了）：

 

@echo off

:start_agin
@cls
echo 请选择延时方法：
echo 1.使用ping方法延时
echo 2.使用vbs延时
echo 3.使用cscript执行vbs延时
echo 4.使用choice延时（推荐）
echo 5.退出

choice /c:12345 /m:"请选择延时方法（5秒后超时，默认选择第4种方法）" /d:4 /t:5

if %errorlevel%==255 echo "意外的错误！"
if %errorlevel%==5 goto exit_cmd
if %errorlevel%==4 goto method_choice
if %errorlevel%==3 goto method_vbs_cscript
if %errorlevel%==2 goto method_vbs_cript
if %errorlevel%==1 goto method_ping
if %errorlevel%==0 echo "错误！"

:exit_cmd
echo 按任意键退出
pause
exit

:method_choice
echo 开始执行延时，使用的方法：method_choice
@choice /c:q /t 5 /d q /m "需要保证用户不进行输入！" /n >nul
echo 延时执行完毕
pause
goto start_agin

:method_vbs_cscript
echo 开始执行延时，使用的方法：method_vbs_cscript
echo wscript.sleep 5000>sleep.vbs
@cscript sleep.vbs >nul
@del /f /s /q sleep.vbs>nul
echo 延时执行完毕
pause
goto start_agin

:method_vbs_cript
echo 开始执行延时，使用的方法：method_vbs_cript
echo wscript.sleep 5000>sleep.vbs
@start /wait sleep.vbs
@del /f /s /q sleep.vbs>nul
echo 延时执行完毕
pause
goto start_agin

:method_ping
echo 开始执行延时，使用的方法：method_ping
@ping 127.0.0.1 -n 6 >nul
echo 延时执行完毕
pause
goto start_agin

 

2.另附上hithub地址（下载后双击运行查看结果即可）：https://github.com/qianlizhe/-bat-

 

标签：

相关文章