VB：关于ByVal和ByRef关键字的问题！

各位前辈：
您们好！
请问在VB中，在函数过程或子过程中用ByVal和用ByRef声明的形参有什么不同？很多书本都只是简略地说明一个是按值传递，一个是按地址传递，根本就没有举例说明。
我也不知道按值传递和按地址传递分别是什么概念。各位高手可以为我解释下这两个概念吗？最好就分别举一个程序例题说明下。
期待您的回复！
衷心感谢！

18 个解决方案

#1

实例：

sub Add1(ByVal no as int32)
    no=no+100
end sub

sub Add2(ByRef no as int32)
    no=no+100
end sub

private sub button1_click(sender as object,e as eventargs)handles button1.click
    dim a as int32
    a=100
    Add1(a)
    msgbox ("a的值为：" & a)     '显示：a的值为100

    Add2(a)
    msgbox ("a的值为：" & a)     '显示：a的值为200,因为Add2中的参数no为ByRef,即
                                 '按地址传递，因此在Add2中对no进行修改后，将会导致
                                 '源参数a的值也被修改。
End Sub

ByVal是传递值源数据不会被修改
你可以把这个值当作自己的局部变量来使用

ByRef是传递地址，源数据可能被修改
你对这个变量的操作将对你传入的那个变量产生影响，就像指针的感觉

#2

ByVal 传送参数内存的一个拷贝给被调用者。也就是说，栈中压入的直接就是所传的值。

ByRef 传送参数内存的实际地址给被调用者。也就是说，栈中压入的是实际内容的地址。被调用者可以直接更改该地址中的内容。

实际上，牵涉到指针时就没有这么简单。例如 ByVal a As String，实际上还是传送字符串的地址。因为字符串实际上由对象指针和字符串缓冲区两部分组成。对象指针中有长度和地址。

#3

ByVal 传送参数内存的一个拷贝给被调用者

ByRef 传送参数内存的实际地址给被调用者。

#4

呵呵，，，星魂老兄，的例子不错呀，，，，

好好学习吧，

慢慢进步。

#5

ByVal
一种将参数值而不是将地址传递给过程的方式，这就使过程访问到变量的复本。结果，过程不可改变变量的真正值

ByRef
一种将参数地址而不是将值传递给过程的方式，这就使过程访问到实际的变量。结果，过程可改变变量的真正值。除非另作说明，否则按地址传递参数。

#6

3、ByVal和ByRef
    ByVal传递的参数值，而ByRef传递的参数的地址。在这里，我们不用去区别传指针/传地址/传引用的不同，在VB里，它们根本就是一个东西的三种不同说法，即使VB的文档里也有地方在混用这些术语（但在C++里的确要区分指针和引用）
    初次接触上面的程序二SwapPtr的朋友，一定要搞清在里面的CopyMemory调用中，在什么地方要加ByVal，什么地方不加（不加ByVal就是使用VB缺省的ByRef）
    准确的理解传值和传地址（指针）的区别，是在VB里正确使用指针的基础。
    现在一个最简单的实验来看这个问题，如下面的程序三：
【程序三】：'体会ByVal和ByRef
    Sub TestCopyMemory()
        Dim k As Long
        k = 5
Note:   CopyMemory ByVal VarPtr(k), 40000, 4
        Debug.Print k
    End Sub
    上面标号Note处的语句的目的，是将k赋值为40000，等同于语句k=40000，你可以在"立即"窗口试验一下，会发现k的值的确成了40000。
    实际上上面这个语句，翻译成白话:
-----------------------------------------------------------------
就是从保存常数40000的临时变量处拷贝4个字节到变量k所在的内存中。
-----------------------------------------------------------------
    现在我们来改变一个Note处的语句，若改成下面的语句：
Note2:   CopyMemory ByVal VarPtr(k), ByVal 40000, 4
    这句话的意思就成了，从地址40000拷贝4个字节到变量k所在的内存中。由于地址40000所在的内存我们无权访问，操作系统会给我们一个Access Violation内存越权访问错误，告诉我们"试图读取位置0x00009c40处内存时出错，该内存不能为'Read'"。
    我们再改成如下的语句看看。
Note3:   CopyMemory VarPtr(k), 40000, 4
    这句话的意思就成了，从保存常数40000的临时变量处拷贝4个字节到到保存变量k所在内存地址值的临时变量处。这不会出出内存越权访问错误，但k的值并没有变。
    我们可以把程序改改以更清楚的休现这种区别，如下面的程序四：
【程序四】：'看看我们的东西被拷贝到哪儿去了
    Sub TestCopyMemory()
        Dim i As Long, k As Long
        k = 5
        i = VarPtr(k)
NOTE4:  CopyMemory i, 40000, 4
        Debug.Print k
        Debug.Print i
        i = VarPtr(k)
NOTE5:  CopyMemory ByVal i, 40000, 4
        Debug.Print k
    End Sub

程序输出：
5
40000
40000
    由于NOTE4处使用缺省的ByRef，传递的是i的地址（也就是指向i的指针），所以常量40000拷贝到了变量i里，因此i的值成了40000，而k的值却没有变化。但是，在NOTE4前有：i=VarPtr(k)，本意是要把i本身做为一个指针来使用。这时，我们必须如NOTE5那样用ByVal来传递指针i，由于i是指向变量k的指针，所以最后常量40000被拷贝了变量k里。

#7

你可以这样理解，传址是直接对原变量操作，传值是复制一个值给新变量，原变量保持不变

#8

Private Sub Command1_Click()
Dim i As Integer
Dim j As Integer
i = 1
j = 1
Call statar(i, j)
Debug.Print i　‘i=2
Call statar2(i, j)
Debug.Print i　‘i=1
End Sub

Private Sub statar(ByRef stri As Integer, ByRef strj As Integer)
stri = stri + 1
strj = strj + 1
End Sub
Private Sub statar2(Byval stri As Integer, Byval strj As Integer)
stri = stri + 1
strj = strj + 1
End Sub

#9

哇噻~~!! 大力水手兄，简直太牛了，，，，解释的太妙了。

收藏~~!!!

#10

啊....csdn不厚道，我看这贴得时候明明才一个人，进来发现里面居然有这么多人.....郁闷....

#11

其实就是形参与实参的区别嘛。可以这样理解不？

#12

    楼上的都是高手，但是很多小弟小妹都是刚起步，你们这么一大篇一大篇的刷下来。我们只知道你们牛，里面尽是一些我们不知道的术语。其他就是晕了~
    我觉得刚开始学的时候还是哪不懂，就弄清楚哪一个，你这一扯一大片。就好像一下子被丢到海里，游啊游啊！都不知道该往哪走了~
    当菜鸟可真是惨呐！

#13

呵呵，这些都是别人写的，我只是照抄一遍而已，不过牛人写的dd就是好啊
哈哈

#14

那请问传值/传址是函数过程/子过程传值/传址给调用过程，还是调用过程传值/传址给函数过程/子过程呢？
菜鸟一个，还望各位多指教！
谢谢！

#15

楼上的好拗口啊！！！！
当然是函数传值/传址给子函数啦。

#16

那请问传值/传址是函数过程/子过程传值/传址给调用过程，还是调用过程传值/传址给函数过程/子过程呢？
菜鸟一个，还望各位多指教！
谢谢！

是后者啦.
其实也不是这个意思.你调用的时候,传个变量进给过程或者函数,那这时就要考虑是Byval还是Byref,如果是前者,那么在你调用的过程中,将不改变原值,也就是说你调用时传的是5,那么在过程中将它变为10,但这个被调过程执行完毕后,那个变量还是5.反过来如时是Byref的话,那么在被调过程中对变量的修改,也直接反映到调用这个过程的函数中的原变量.

说这么多!讲讲原理就是传的原变的时复本还是传的地址的.

但要记住啦,这个只针对值类型,对于对象的类型这个不适用.

#17

好像在C里面对这个问题的讲解比较明白，

#18

mark

#1

#2

#3