WebGL光照阴影映射

时间：2021-10-25 04:21:28

  原文地址：WebGL光照阴影映射
  经过前面的学习,webgl的基本功能都已经掌握了,我们不仅掌握了着色器的编写,图形的绘制,矩阵的变换,添加光照,还通过对webgl的基础api封装,编写出了便利的工具库. 是时候进一步深入学习webgl的高级功能了,我认为要做逼真的3D特效,阴影绝对是一个必不可少的环节.现在我们就在之前光照的基础上添加阴影效果吧.
  首先看一下阴影效果的实例：
阴影综合(多物体高精度PCF)
点光源聚光灯阴影
WebGL光照阴影映射

内容大纲

   我们以阴影综合(多物体高精度PCF)为例, 开始学习阴影相关知识.

  1. 帧缓冲
  2. 阴影映射(shadow mapping)
  3. 提高阴影精度
  4. 抗锯齿(PCF)

帧缓冲

  我们实现阴影效果使用的是叫阴影映射的技术, 在此之前要提到以下两个对象:帧缓冲区对象和渲染缓冲区对象.
  帧缓冲区对象(framebuffer object)可以用来代替颜色缓冲区或深度缓冲区.绘制在帧缓冲区中的对象并不会直接显示canvas上，可以先对帧缓冲区中的内容进行一些处理再显示，或者直接用其中的内容作为纹理图像.在帧缓冲区中进行绘制的过程又称为离屏绘制(offscreen drawing).
  而渲染缓冲区对象就是我们绘图使用的缓冲区, 它会直接把内容渲染到canvas中.
  而我们现在先有这个概念,来看看帧缓冲区的创建和配置:
1. 创建帧缓冲区对象 gl.createFramebffer().
2. 创建文理对象并设置其尺寸和参数 gl.createTexture()、gl.bindTexture()、gl.texImage2D()、gl.Parameteri().
3. 创建渲染缓冲区对象 gl.createRenderbuffer().
4. 绑定渲染缓冲区对象并设置其尺寸 gl.bindRenderBuffer()、gl.renderbufferStorage().
5. 将帧缓冲区的颜色关联对象指定为一个文理对象 gl.frambufferTexture2D().
6. 将帧缓冲区的深度关联对象指定为一个渲染缓冲区对象 gl.framebufferRenderbuffer().
7. 检查帧缓冲区是否正确配置 gl.checkFramebufferStatus().
8. 在帧缓冲区中进行绘制 gl.bindFramebuffer().

  它的创建和配置是一个非常繁琐的过程,我们先熟悉了怎么使用,再慢慢研究它内部的原理,所以先把上面的步骤封装成一个黑盒子,我这里就是initFramebufferObject这个函数.

阴影映射(shadow mapping)

  阴影映射的原理很简单,我们从光的角度渲染场景,从光的角度看到的所有东西都被点亮了,而看不见的部分一定是在阴影里. 想象有一个盒子和它的光源照射下的地板,由于光源会看到这个盒子而它后面的地板部分是看不到的.那么当视线角度变化的时候,从光源角度照不到的那部分地板就渲染为阴影,原理如下图
WebGL光照阴影映射
  接着我们使用阴影映射的算法实现, 它要使用到前面介绍的帧缓冲区. 阴影映射要渲染两遍:
第一遍是从光源的角度渲染场景,同时把场景的深度值当成纹理渲染到帧缓冲区,也就是把它当作数据容器.
第二遍是从眼睛的角度渲染场景,把物体真正渲染到画布中,同时对比纹理的深度值,将阴影部分也渲染出来.

  左边的图像是第一遍渲染的原理, 一个方向光源（所有的光线都是平行的）在立方体下面的表面投下阴影.我们通过用光源的视图投影矩阵渲染场景(从光线的角度)来创建景深图然后把它存储到帧缓冲区中.
  右边的图形是第二遍渲染的原理, 从眼睛的视图投影矩阵渲染场景(从眼睛的角度), 光源角度下的xy坐标相同的c点和p点,p深度值比c要大, 那么它一定处于阴影当中,那么p点就渲染为阴影.
WebGL光照阴影映射
  来看实现以上功能的着色器代码,因为要渲染两遍,所以也就要建立两对的着色器(顶点/片段),顶点着色器比较简单,基本不涉及阴影映射,在此省略:

阴影片段着色器

    #ifdef GL_ES 
    precision mediump float; 
#endif
void main() { 
gl_FragColor = vec4(gl_FragCoord.z, 0.0, 0.0, 0.0); //将深度值z存放到第一个分量r中
    }

正常片段着色器

  深度值后面加了0.005,稍微大于1/256,即8位的表示范围(因为一个分量就是8位),这个是消除马赫带用的,不加这个值,画面会产生难看的条纹,具体的原理可查找马赫带,在此不细讲.

    #ifdef GL_ES
    precision mediump float;
#endif
uniform sampler2D u_ShadowMap;
varying vec4 v_PositionFromLight;
varying vec4 v_color;
void main() {
// 获取纹理的坐标
vec3 shadowCoord = (v_PositionFromLight.xyz/v_PositionFromLight.w)/2.0 + 0.5;
// 根据阴影xy坐标,获取纹理中对应的点,z值已经被之前的阴影着色器存放在该点的r分量中了,直接使用即可
vec4 rgbaDepth = texture2D(u_ShadowMap, shadowCoord.xy);// 获取指定纹理坐标处的像素颜色rgba
float visibility = (shadowCoord.z > rgbaDepth.r + 0.005) ? 0.6 : 1.0;//大于阴影的z轴,说明在阴影中并显示为阴影*0.6,否则为正常颜色*1.0
gl_FragColor = vec4(v_color.rgb * visibility, v_color.a);
    }

提高精度

  完成了最简单的阴影效果,但是当你把光源与物体的距离拉远,问题出来了,怎么看不到阴影了?这是距离超过了8位的存储范围,溢出的缘故.之前我们只使用了一个分量来存储,现在我们把其他的分量也利用起来吧,rgba一共32位.

阴影片段着色器

  这中间进行复杂的分解运算,并同时去除异常值,请看如下代码

    // ...
/**
 * 分解保存深度值
 */
vec4 pack (float depth) {
// 使用rgba 4字节共32位来存储z值,1个字节精度为1/256
const vec4 bitShift = vec4(1.0, 256.0, 256.0 * 256.0, 256.0 * 256.0 * 256.0);
const vec4 bitMask = vec4(1.0/256.0, 1.0/256.0, 1.0/256.0, 0.0);
// gl_FragCoord:片元的坐标,fract():返回数值的小数部分
vec4 rgbaDepth = fract(depth * bitShift); //计算每个点的z值 
        rgbaDepth -= rgbaDepth.gbaa * bitMask; // Cut off the value which do not fit in 8 bits
return rgbaDepth;
    }
void main() {
gl_FragColor = pack(gl_FragCoord.z);// 将z值分开存储到rgba分量中,阴影颜色的同时也是深度值z
    }

正常片段着色器

  这里对应就要解码出深度值

    // ...
/**
 * 释出深度值z
 */
float unpack(const in vec4 rgbaDepth) {
const vec4 bitShift = vec4(1.0, 1.0/256.0, 1.0/(256.0*256.0), 1.0/(256.0*256.0*256.0));
return dot(rgbaDepth, bitShift);
    }
// ...

抗锯齿(PCF)

  解决了精度的问题,接着继续优化. 运行起来吧,阴影很粗糙有木有? 你看看下面左图,很严重的锯齿, 抗锯齿有很多种解决方案,我这里使用PCF, 也就是百分比渐近式过滤算法,因为它基于代码实现的,所以也叫软阴影.
  PCF的原理也很简单, 采集当前点周围像素的阴影值，并将其深度与所有采集的样本进行比较，最后对结果进行平均，这样就得到光线和阴影之间更平滑的过渡效果.下面右图是经过PCF处理之后的阴影,效果要自然得多了.
WebGL光照阴影映射
  我们看正常着色器的实现代码

    // ...
vec3 shadowCoord = (v_positionFromLight.xyz/v_positionFromLight.w)/2.0 + 0.5;
float shadows =0.0;
float opacity=0.6;// 阴影alpha值, 值越小暗度越深
float texelSize=1.0/1024.0; // 阴影像素尺寸,值越小阴影越逼真
vec4 rgbaDepth;
// 消除阴影边缘的锯齿
for(float y=-1.5; y <= 1.5; y += 1.0){
for(float x=-1.5; x <=1.5; x += 1.0){
            rgbaDepth = texture2D(u_shadowMap, shadowCoord.xy+vec2(x,y)*texelSize);
            shadows += shadowCoord.z-bias > unpack(rgbaDepth) ? 1.0 : 0.0;
        }
    }
    shadows/=16.0; // 4*4的样本
float visibility=min(opacity+(1.0-shadows),1.0);
    specular=visibility < 1.0 ? vec3(0.0,0.0,0.0): specular; // 阴影处没有高光
gl_FragColor = vec4((diffuse + ambient + specular) * visibility, v_color.a);

总结

  WebGL的阴影部分,涉及到了很多opengGL的底层,计算机图形学,算法. 为了深入理解它,可真是花费了很多脑力,是到目前为止学习webgl的第一道坎,它里面的水很深.比如光是反锯齿部分就涉及到很多低层细节,算法的实现,显卡的性能问题等都是需要考虑的, 阴影部分后续还要慢慢查资料继续优化.
  越是深入学习WebGL,就越觉得它相关的资料真是少,必须看openGL ES相关的东西才能解决,伤不起啊.

标签：

相关文章