如何处理HTTP文件上传？

How would I write a Perl CGI script that receives a file via a HTTP post and saves that to the file system?

如何编写通过HTTP帖子接收文件的Perl CGI脚本并将其保存到文件系统?

4 个解决方案

#1

Just a note: however you will write it, don't save it in a place accessible from your web-server.

只需注意:但是您会编写它,不要将其保存在可从Web服务器访问的位置。

And now to the point: below is a script which I was using for some time for photo-uploading. It might need some tweaking, but should show you the way.

现在到了这一点:下面是我用了一段时间进行照片上传的脚本。它可能需要一些调整,但应该告诉你的方式。

As the image isnt uploaded to web-accesible directory, we then have separate process checking it, resizing, putting a watermark and placing it where it can be accessed.

由于图像没有上传到网络可访问的目录,我们有单独的进程检查它,调整大小,放置水印并将其放置在可以访问的位置。

 #!/usr/bin/perl -wT

use strict;
use CGI;
use CGI::Carp qw ( fatalsToBrowser );
use File::Basename;

$CGI::POST_MAX = 1024 * 5000;
my $safe_filename_characters = "a-zA-Z0-9_.-";
my $upload_dir = "/home/www/upload";

my $query = new CGI;
my $filename = $query->param("photo");
my $email_address = $query->param("email_address");

if ( !$filename )
{
 print $query->header ( );
 print "There was a problem uploading your photo (try a smaller file).";
 exit;
}

my ( $name, $path, $extension ) = fileparse ( $filename, '\..*' );
$filename = $name . $extension;
$filename =~ tr/ /_/;
$filename =~ s/[^$safe_filename_characters]//g;

if ( $filename =~ /^([$safe_filename_characters]+)$/ )
{
 $filename = $1;
}
else
{
 die "Filename contains invalid characters";
}

my $upload_filehandle = $query->upload("photo");

open ( UPLOADFILE, ">$upload_dir/$filename" ) or die "$!";
binmode UPLOADFILE;

while ( <$upload_filehandle> )
{
 print UPLOADFILE;
}

close UPLOADFILE;

print $query->header ( );
print <<END_HTML;
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "DTD/xhtml1-strict.dtd">
<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
 <head>
   <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
   <title>Thanks!</title>
 </head>
 <body>
   <p>Thanks for uploading your photo!</p>
 </body>
</html>
END_HTML

#2

Use the CGI module.

使用CGI模块。

my $fh = $query->upload('upload_field');
while(<$fh>) {
  print SAVE_FILE $_;
}

#3

See the CGI.pm documentation for file uploads.

有关文件上载,请参阅CGI.pm文档。

#4

I'd start by using CGI and reading CREATING A FILE UPLOAD FIELD, and using open to create a file and print to write to it. (and then close to close it).

我首先使用CGI并阅读CREATING A FILE UPLOAD FIELD,然后使用open创建一个文件并打印以写入它。 (然后关闭它)。

#1