问：
您好，脚本专家！如何使用脚本来确定是否安装了某个特定的补丁？
-- GM
答：
您好，GM。您知道，不久以前这个问题可能被我们“不小心”扔进了废纸篓并且假装从未看到。为什么？嗯，以前的时候，我们获得关于补丁、快速修复和其他更新的信息的唯一方法就是使用 WMI 类 Win32_QuickFixEngineering。这样挺好的，但是由于各种原因，Win32_QuickFixEngineering 偶尔会丢失确实已经安装了的补丁；更糟糕的是，在 Windows 2000 计算机上，Win32_QuickFixEngineering 有时会处于待命状态，而不返回任何信息。（如何解决这一问题？当然是指通过安装补丁来解决。）无论如何都不能算一件好事。
但是，那些日子都过去了。现在，多亏具有重大改进的新 Windows Update 服务，要确定计算机上已安装了和尚未安装哪些更新非常容易。例如，以下脚本可以告诉我们计算机上是否已安装了补丁 Security Update for Windows XP (KB899587)：
Set objSession = CreateObject("Microsoft.Update.Session")
Set objSearcher = objSession.CreateUpdateSearcher
Set objResults = objSearcher.Search("Type='Software'")
Set colUpdates = objResults.Updates
For i = 0 to colUpdates.Count - 1
If colUpdates.Item(i).Title = _
"Security Update for Windows XP (KB899587)" Then
If colUpdates.Item(i).IsInstalled <> 0 Then
Wscript.Echo "This update is installed."
Wscript.Quit
Else
Wscript.Echo "This update is not installed."
Wscript.Quit
End If
End If
Next
Wscript.Echo "This update is not installed."
我们将不详细介绍每一行代码，解释 Windows Update 服务的详细情况有点超出了本专栏的范围。如果您想了解有关 Windows Update（尤其是诸如 Microsoft.Update.Session 之类的对象）的详细信息，请参阅我们的“脚本故事”专栏中的我要得到你，我的美人…并且我们也要管理 Windows Update 啦！
但是，我们会发现，尽管有 Search 方法，但我们并不是真的搜索某个具体的更新。搜索意味着只去查找所需的项，其精确度是极低的。因此我们不能真的那样做。相反，我们在此要做的是返回所有更新的集合，然后筛选整个集合，查找标题为 Security Update for Windows XP (KB899587) 的更新。最终结果是一样的，但是我们达到这一最终结果的过程稍有不同。
不，没有什么不同。就您想了解的内容而言。
那么，我们在此采用的过程是什么？嗯，首先使用下面四行代码来检索本地计算机的更新集合：
Set objSession = CreateObject("Microsoft.Update.Session")
Set objSearcher = objSession.CreateUpdateSearcherSet
objResults = objSearcher.Search("Type='Software'")
Set colUpdates = objResults.Updates
注意：是的，此脚本可针对远程计算机运行。有关详细信息，请参阅脚本故事专栏。
检索该集合之后，设置一个 For Next 循环以遍历所有项。在该循环内，使用下面一行代码来确定更新的“标题”是否为 Security Update for Windows XP (KB899587)：
If colUpdates.Item(i).Title = _
"Security Update for Windows XP (KB899587)" Then
我们假定“标题”是Security Update for Windows XP (KB899587)。在这种情况下，接下来要检查 IsInstalled 属性的值。如果 IsInstalled 等于 0，则表示实际没有安装该更新（可能安装失败了，也可能安装了该更新但后来又删除了）。如果 IsInstalled 不等于 0，则表示已经安装了该更新。检查该值，然后回显相应的消息：
If colUpdates.Item(i).IsInstalled <> 0 Then
Wscript.Echo "This update is installed."
Wscript.Quit
Else
Wscript.Echo "This update is not installed."
Wscript.Quit
End If
您会发现，回显消息之后，我们就会终止该脚本。为什么？嗯，更新标题是唯一的：既然我们已经找到了要查找的更新，就无需继续遍历剩下的集合了。因此，我们也就终止了脚本，并回到我们的生活中。
如果“标题”不是Security Update for Windows XP (KB899587) 怎么办？在这种情况下，我们只要进入下一轮循环并检查集合中的下一项即可。如果我们确实再也找不到具有指定标题的更新，则最终会退出该循环，然后执行最后一行代码，仅报告没有安装该更新。