VBA驱动SAP GUI自动化：查找页面元素FindAllByName

　　我们在VBA中嵌入SAP原生的【脚本录制与回放】功能生成的VBS脚本，可以实现很多自动化操作。但只有我们对SAP做了一系列动作，才会得到这些动作的脚本。然而，一旦我们需要用代码提前做一些判断，然后再决定后续的动作时，这个判断的代码就无法通过【脚本录制与回放】功能录制得到。这个时候，我们需要学会看SAP GUI Scripting API。

　　举个小爬在实际工作中碰到的例子。我们有时候会利用脚本驱动事务代码F-02完成SAP凭证的批量录入。在凭证的行项目录入界面中，某些科目下，SAP需要我们维护【到期日】【基准日】；有些行项目下，则没有这个选项让用户维护，如下图所示：

 

 

 

 　　我们需要先判断有没有【到期日】这个元素，再决定是不是要给这个元素传值。这个判断的代码就无法去录制代码得到了。

　　这也就是小爬今天要分享的知识点：利用FindAllByName()方法去判断是否存在某个元素。这些方法就是通过SAP GUI Scripting API学习得来。

　　之所以这里用到FindAllByName()而不是我们熟悉的FindById()方法，是因为当我们使用FindById()去查找某个页面中没有的元素时，程序会直接报错异常，而VBA的异常响应能力天生不足，使用FindAllByName()则完全不会存在这个问题。

 

 

 　　从上图中可以看到，FindAllByName()方法接收两个参数，一个是元素的Name，另一个是元素的Type，而返回值是一个GuiComponentCollection对象，相当于一个数组。当我们没有找到对应的元素时，会返回一个空数组，并不会报错。

以【到期日】这个字段为例，我们还是需要借助万能的Scripting Tracker工具先找到元素的Name和Type。我们可以点击工具中的望远镜图标【查找对象】,输入关键词【到期日】，此时工具会自动帮我们定位到对应对象（灰色背景），如下图所示：

 

 

 　　这里可以看到，【到期日】对象对应的Name：BSEG-ZFBDT，对应的Type:GuiLabel(注意，这里不用输入Type括号后面的数字）。只要判断有这个【到期日】label元素，就可以断定页面中是否有【到期日】这个GuiCTextField输入框元素。

有了这两点，我们可以这样来组织我们的VBA代码，避免程序出错和写不必要的异常响应，代码示例如下：

Sub Main()

    Dim SapGuiAuto As Object
    Dim app As Object
    Dim connection As Object
    Dim session As Object
    Dim ZFBDT_collection As Object, cnt As Long

     Set SapGuiAuto = GetObject("SAPGUI")
     Set app = SapGuiAuto.GetScriptingEngine
     app.HistoryEnabled = False
     Set connection = app.Children(0)
      If connection.DisabledByServer = True Then
        Exit Sub
      End If
      Set session = connection.Children(0)
      If session.Busy = True Then
        Exit Sub
      End If
      If session.Info.IsLowSpeedConnection = True Then
        Exit Sub
      End If


    session.findById("wnd[0]").maximize
    Set ZFBDT_collection = session.findById("wnd[0]/usr").FindAllByName("BSEG-ZFBDT", "GuiLabel") '基于Name和Type 查找【到期日】元素
    cnt = ZFBDT_collection.Count
    If cnt = 0 Then
        MsgBox "【到期日】元素在当前SAP会话中不存在！"
    Else:
        Debug.Print ZFBDT_collection(0).Text '打印对应的元素的Text属性，佐证是否为【到期日】
        session.findById("wnd[0]/usr/ctxtBSEG-ZFBDT").Text = "2022.01.01" '找到对应的元素，传值
    End If
End Sub

　　   除了FindById，是时候开始学学FindAllByName来查找SAP GUI元素了。尤其是在VBA中做SAP GUI自动化，该方法真心好用，强推~~

　　　欢迎扫码关注我的公众号 获取更多爬虫、数据分析的知识！