显式是相对与隐式cursor而言的，就是有一个明白的声明的cursor。显式游标的声明类似例如以下（具体的语法參加plsql ref doc ）：
cursor cursor_name (parameter list) is select ...
游标从declare、open、fetch、close是一个完整的生命旅程。
当然了一个这种游标是能够被多次open进行使用的，显式cursor是静态cursor，她的作用域是全局的，但也必须明确，静态cursor也仅仅有pl/sql代码才干够使用她。以下看一个简单的静态显式cursor的演示样例：
declare
cursor get_gsmno_cur (p_nettype in varchar2) is
select gsmno
from gsm_resource
where nettype=p_nettype and status='0';
v_gsmno gsm_resource.gsmno%type;
begin
open get_gsmno_cur('139');
loop
fetch get_gsmno_cur into v_gsmno;
exit when get_gsmno_cur%notfound;
dbms_output.put_line(v_gsmno);
end loop;
close emp_cur;
open get_gsmno_cur('138');
loop
fetch get_gsmno_cur into v_gsmno;
exit when get_gsmno_cur%notfound;
dbms_output.put_line(v_gsmno);
end loop;
close get_gsmno_cur;
end;
/
上面这段匿名块用来实现选号的功能，我们显式的定义了一个get_gsmno_cur，然后依据不同的号段输出当前系统中该号短相应的可用手机号码。当然了，实际应用中没人这么用的，我仅仅是用来说应一个显式cursor的使用方法。
二、隐式cursor
隐式cursor当然是相对于显式而言的，就是没有明白的cursor的declare。
在Oracle的PL/SQL中，全部的DML操作都被Oracle内部解析为一个cursor名为SQL的隐式游标，仅仅是对我们透明罢了。
另外，我们前面提到的一些循环操作中的指针for 循环。都是隐式cursor。
隐式cursor演示样例一：
CREATE TABLE zrp (str VARCHAR2(10));
insert into zrp values ('ABCDEFG');
insert into zrp values ('ABCXEFG');
insert into zrp values ('ABCYEFG');
insert into zrp values ('ABCDEFG');
insert into zrp values ('ABCZEFG');
COMMIT;
SQL> begin
2 update zrp SET str = 'updateD' where str like '%D%';
3 ifSQL%ROWCOUNT= 0 then
4 insert into zrp values ('1111111');
5 end if;
6 end;
7 /
PL/SQL procedure successfully completed
SQL> select * from zrp;
STR
----------
updateD
ABCXEFG
ABCYEFG
updateD
ABCZEFG
SQL>
SQL> begin
2 update zrp SET str = 'updateD' where str like '%S%';
3 ifSQL%ROWCOUNT= 0 THEN
4 insert into zrp values ('0000000');
5 end if;
6 end;
7 /
PL/SQL procedure successfully completed
SQL> select * from zrp;
STR
----------
updateD
ABCXEFG
ABCYEFG
updateD
ABCZEFG
0000000
6 rows selected
SQL>
隐式cursor演示样例二：
begin
for rec in (select gsmno,status from gsm_resource) loop
dbms_output.put_line(rec.gsmno||'--'||rec.status);
end loop;
end;
/
三、REFcursor
Ref cursor属于动态cursor(直到执行时才知道这条查询)。
从技术上讲。在最主要的层次静态cursor和ref cursor是同样的。
一个典型的PL/SQL光标按定义是静态的。
Ref光标正好相反，能够动态地打开，或者利用一组SQL静态语句来打开，选择哪种方法由逻辑确定（一个IF/THEN/ELSE代码块将打开一个或其他的查询）。比如，以下的代码块显示一个典型的静态SQL光标，光标C。
此外，还显示了怎样通过使用动态SQL或静态SQL来用ref光标（在本例中为L_CURSOR）来打开一个查询：
Declare
type rc is ref cursor;
cursor c is select * from dual;
l_cursor rc;
begin
if (to_char(sysdate,'dd') = 30) then
-- ref cursor with dynamic sql
open l_cursor for 'select * from emp';
elsif (to_char(sysdate,'dd') = 29) then
-- ref cursor with static sql
open l_cursor for select * from dept;
else
-- with ref cursor with static sql
open l_cursor for select * from dual;
end if;
-- the "normal" static cursor
open c;
end;
/
在这段代码块中，能够看到了最显而易见的差别：不管执行多少次该代码块。光标C总是select * from dual。相反，ref光标能够是不论什么结果集。由于"select * from emp"字符串能够用实际上包括不论什么查询的变量来取代。
在上面的代码中，声明了一个弱类型的REF cursor。以下再看一个强类型（受限）的REF cursor，这样的类型的REF cursor在实际的应用系统中用的也是比較多的。
create table gsm_resource
(
gsmno varchar2(11),
status varchar2(1),
price number(8,2),
store_id varchar2(32)
);
insert into gsm_resource values('13905310001','0',200.00,'SD.JN.01');
insert into gsm_resource values('13905312002','0',800.00,'SD.JN.02');
insert into gsm_resource values('13905315005','1',500.00,'SD.JN.01');
insert into gsm_resource values('13905316006','0',900.00,'SD.JN.03');
commit;
SQL> declare
2 type gsm_rec is record(
3 gsmno varchar2(11),
4 status varchar2(1),
5 price number(8,2));
6
7 type app_ref_cur_type is ref cursor return gsm_rec;
8 my_cur app_ref_cur_type;
9 my_rec gsm_rec;
10
11 begin
12 open my_cur for select gsmno,status,price
13 from gsm_resource
14 where store_id='SD.JN.01';
15 fetch my_cur into my_rec;
16 while my_cur%found loop
17 dbms_output.put_line(my_rec.gsmno||'#'||my_rec.status||'#'||my_rec.price);
18 fetch my_cur into my_rec;
19 end loop;
20 close my_cur;
21 end;
22 /
13905310001#0#200
13905315005#1#500
PL/SQL procedure successfully completed
SQL>
普通cursor与REF cursor另一些大家应该都熟悉的差别，我再浪费点唾沫。
1）PL/SQL静态光标不能返回到client。仅仅有PL/SQL才干利用它。ref光标可以被返回到client。这就是从Oracle的存储过程返回结果集的方式。
2）PL/SQL静态光标能够是全局的，而ref光标则不是。 也就是说。不能在包说明或包体中的过程或函数之外定义ref光标。
仅仅能在定义ref光标的过程中处理它，或返回到client应用程序。
3）ref光标能够从子例程传递到子例程，而光标则不能。 为了共享静态光标。必须在包说明或包体中把它定义为全局光标。 由于使用全局变量通常不是一种非常好的编码习惯。因此能够用ref光标来共享PL/SQL中的光标，无需混合使用全局变量。
最后，使用静态光标--通过静态SQL（但不用ref光标）--比使用ref光标效率高。而ref光标的使用仅限于下面几种情况：
把结果集返回给client；
在多个子例程之间共享光标（实际上与上面提到的一点很类似）；
没有其它有效的方法来达到你的目标时，则使用ref光标，正如必须用动态SQL时那样；
简言之，首先考虑使用静态SQL，仅仅有绝对必须使用ref光标时才使用ref光标，也有人建议尽量使用隐式游标，避免编写附加的游标控制代码（声明，打开，获取，关闭）。也不须要声明变量来保存从游标中获取的数据。这个就因人因详细的case大家去酌定吧。
四、游标属性
%FOUND： bool - TRUE if >1 row returned
%NOTFOUND：bool - TRUE if 0 rows returned
%ISOPEN： bool - TRUE if cursor still open
%ROWCOUNT：int - number of rows affected by last SQL statement
注：NO_DATA_FOUND和%NOTFOUND的使用方法是有差别的。小结例如以下：
1）SELECT . . . INTO 语句触发 NO_DATA_FOUND。
2）当一个显式光标的 where 子句未找到时触发 %NOTFOUND。
3）当UPDATE或DELETE 语句的where 子句未找到时触发 SQL%NOTFOUND。
4）在光标的提取(Fetch)循环中要用 %NOTFOUND 或%FOUND 来确定循环的退出条件，不要用NO_DATA_FOUND。