link script(链接器ld吃的文件)中使用宏定义的解决方案

问题：工作中遇到一个需求：需要在ld script中使用类似C语言的define等宏定义来做一些判断和替换

实验：

1：理论上*.c中都能用，是否gcc/ld也支持在ld script中直接用宏呢，结果：

arm-linux-ld:xxx.lds:2: ignoring invalid character `#' in expression
arm-linux-ld:xxx.lds:2: syntax error

人说水火无情，看来ld和gcc也不给面子啊。这里用的是交叉编译的ld，x86的也是一样的结论，本是同根生嘛。看来此路不通。

2：*.c中为什么能用define等宏呢，这个是在预编译阶段完成的。我们把gcc的预编译拿来先帮我们处理一次是否就可以了呢？带着疑问我们继续出发

先贴一份原始的ld script 吧：old.lds，里面有些define和注释哦

/*
 * comments like C style
 * if comments line is less than 2 lines like this, maybe generate some strange result
 *
 */
#ifdef __ARM__
OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
OUTPUT_ARCH(arm)
#else
OUTPUT_FORMAT("elf32-littlends", "elf32-littlends", "elf32-littlends")
OUTPUT_ARCH(nds)
#endif
ENTRY(_start)

SECTIONS
{
        //C++ comments
        . = 0x00000000;

        . = ALIGN(__ALIGN__);
        .text :   /*C style comment*/
        {
#if defined(__ARM__)
                cpu/arm920t/start.o     (.text)
#endif
                board/xxx/lowlevel_init.o       (.text)
                board/xxx/nand_read.o   (.text)
                *(.text)
        }

        . = ALIGN(__ALIGN__);
        .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }

        . = ALIGN(__ALIGN__);
        .data : { *(.data) }

        . = ALIGN(__ALIGN__);
        __bss_start = .;
        .bss (NOLOAD) : { *(.bss) . = ALIGN(__ALIGN__); }
        _end = .;
}

我们请gcc出马帮忙只进行预编译吧：(主要是 -E 和 -P的参数，不了解的man gcc 或者 gcc --help)

deeve@debian:~/linux_all/project$ arm-linux-gcc -E -D__ARM__ -D__ALIGN__=4 -P old.lds -o new.lds
arm-none-linux-gnueabi-gcc: old.lds: linker input file unused because linking not done

继续被打，看了gcc还认文件扩展名呀。那我们忽悠忽悠它吧：

deeve@debian:~/linux_all/project$ cp old.lds old.c
deeve@debian:~/linux_all/project$ arm-linux-gcc -E -D__ARM__  -D__ALIGN__=4 -P old.c -o new.lds

哇，居然成功糊弄过去了，赶紧看看new.lds是否是预期的呢：

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
OUTPUT_ARCH(arm)
ENTRY(_start)
SECTIONS
{
 . = 0x00000000;
 . = ALIGN(4);
 .text :
 {
  cpu/arm920t/start.o (.text)
  board/xxx/lowlevel_init.o (.text)
  board/xxx/nand_read.o (.text)
  *(.text)
 }
 . = ALIGN(4);
 .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
 . = ALIGN(4);
 .data : { *(.data) }
 . = ALIGN(4);
 __bss_start = .;
 .bss (NOLOAD) : { *(.bss) . = ALIGN(4); }
 _end = .;
}

太cool了，gcc看来还比较好骗嘛，O(∩_∩)O哈哈~

如果客官您觉得改名成*.c感觉不是太好，那您就使用下面的一行命令来搞定它吧：(注意命令中单独的一个"-"的用法哦)

deeve@debian:~/linux_all/project$ cat old.lds | arm-linux-gcc -E -D__ARM__  -D__ALIGN__=4 -P - -o new.lds
deeve@debian:~/linux_all/project$ arm-linux-gcc -E -D__ARM__  -D__ALIGN__=4 -P - <old.lds -o new.lds
deeve@debian:~/linux_all/project$ arm-linux-gcc -E -D__ARM__  -D__ALIGN__=4 -P - <old.lds > new.lds

以上三个命令，随便捞一个吧（一行居然没显示下，将就看看吧）
接下来呢，ld再吃已经处理过的new.lds就可以啦。不用我说，聪明的客官你肯定早知道了。