对于复杂的计算，单片机的速度显得偏慢。最好的办法是由人工事先算出全部的结果，依次存放在ROM中，程序执行时，直接从ROM中查出结果即可。
51单片机有两条查表指令：
MOVC A, @A + PC
MOVC A, @A + DPTR
前一条可以不用 DPTR，但是其中有个“偏移量”颇为难算，因为涉及到指令字节数的基本概念、查表等，令很多人头痛。
做而论道针对这个问题，研究出一个自动计算偏移量的方法，可以避免烦琐的人工计算过程。
下面是做而论道回答的一个网上的题目：
在 30H ~ 39H中，预先存入数据为 1，3，5，7，9，2，4，6，8，10。
利用 MOVC A, @A + PC 指令编写一查平方表程序，将片内30H ~ 39H内的数求出平方后送入40H ~ 49H单元。
做而论道编写的程序如下：
;-------------------------------------------
org 0000h
mov 30h, #1 ;先存放一些数据
mov 31h, #3
mov 32h, #5
mov 33h, #7
mov 34h, #9
mov 35h, #2
mov 36h, #4
mov 37h, #6
mov 38h, #8
mov 39h, #10
call SQRT ;调用子程序，求出上述10个数字的平方
;存放在40H开始的单元部分略
sjmp $
;-------------------------------------------
;用查表法求平方的子程序
SQRT:
MOV R0, #30H ;源数值起始地址
MOV R1, #40H ;目标起始地址
MOV R2, #10 ;共有10个数字
LOOP:
MOV A, @R0
ADD A, #S_TAB - ($ + 3) ;自动计算偏移量
MOVC A, @A + PC ;查表，求出平方
MOV @R1, A
INC R0
INC R1
DJNZ R2, LOOP
RET
;-------------------
S_TAB:
DB 0, 1, 4, 9, 16, 25, 36, 49, 64, 81, 100, 121, 144, 169, 196
;-------------------------------------------
;完
提问者对于答案的评价：恩恩 很对的 不过 #S_TAB - ($ + 3)这个什么意思啊？
原题网址：http://zhidao.baidu.com/question/125242924.html
========================================
算法说明：
在 S_TAB 开始，用 DB 伪指令存放了一系列的《平方数字》。－－百度排版很差，引号，显示的太小，用书名号代替。
那么，从 S_TAB 开始数，第 0 个字节，就是 0 的平方，第 1 个字节，就是 1 的平方，……，第 14 个字节，就是 14 的平方。
如果，查表指令 MOVC A, @A + PC 中的 PC 等于 S_TAB 就好了，A 是几，就能从表中，查出几的平方。
呵呵，这有点像《立定跳远》，站在跳板上，有多大的劲，就跳多远。
而实际上，执行查表指令 MOVC A, @A + PC 时，PC，它并不等于 S_TAB。
怎么办 ？想想跳远就知道，加上助跑，就可以了。助跑的步数或米数，大家应该都会算。
在执行查表指令之前，把 S_TAB 和执行查表指令时的 PC 之差，算出来，加入到 A 中，即可。
这个数字，称为偏移量，加入到 A 中，这就相当于《助跑》。
计算这个偏移量，就是要统计 S_TAB 和执行查表指令时的 PC 之间的字节数。
如果不熟悉机器语言，由人工计算偏移量，是相当难的。
而且，如果修改了这其中的指令，还要重新计算，非常的麻烦。
幸好，做而论道发明了自动计算偏移量的方法。
程序中，下面的两行：
ADD A, #S_TAB - ($ + 3) ;2字节
MOVC A, @A + PC ;1字节
即完成了自动计算偏移量、查表的工作。
程序中的算式为：#S_TAB - ($ + 3)，也可以写成：#S_TAB - $ - 3。
下面是各个部分说明：
$：代表 ADD 指令所在的当前地址；
$ + 3：即执行查表指令时的 PC 数值，加 3，是这两条指令共占用了三个字节；
S_TAB - ($ + 3)：求出表格首地址与查表时地址的差值；
按照单片机教材上介绍的方法，使用 MOVC A, @A + PC 指令，是要人工计算《查表指令与表首之间地址的差值》的。
用过这种方法的人，都知道有多难。
所以，绝大多数人，都宁可浪费一个 DPTR，也不愿意计算这个差值。
而做而论道研究出来的这个公式，有理论，有实践方法，极大的方便了单片机编程人员，值得广泛推广。
做而论道研究出来的这个公式，是首创的，此前，从未见到有人发表过。
呵呵，做而论道嘛，没有点自己独创的方法，怎么敢自称做而论道 ！
========================================