(一).缘起
1.1 我的一个出错程序
程序名称：呼叫处理模块的压力测试工具，分为客户端和服务端。
开发工具：Delhpi 5
相关技术：客户端通过与服务端建立Socket连接来模拟一组电话机的拨入、按键、等待、挂机等过程。服务端对Socket事件以及收到的数据包进行预处理，并转化为抽象的呼叫模型数据，然后发送给更上层的呼叫处理模块。由于呼叫处理模块是硬件无关的（与语音板卡、交换机类型均无关），因此通过此压力测试工具可以比较真实地模拟海量呼叫，以达到测试呼叫处理模块程序的逻辑正确性及其性能的目的。
由于系统设计时的某些考虑，该测试工具被分作客户端和服务端两个程序来实现，且采用socket进行通讯。现在想来，其实不如整合成一个程序实现更为简单——但也正因为采用两个程序来实现，才引发了后面的一些问题，并由此引入了简单的垃圾回收框架。
1.2 问题
在测试工具的使用过程中，我们发现当呼叫量巨大，且测试工具动作频繁的情况下，系统出现以下错误：
■访问地址错(EAccessViolation)，代码地址位于$0046FC80附近，访问地址多为$00000028。
■出现EinvalidCast错误，该错误表明对一个地址进行类类型转换时出错（采用as关键字）。
■程序内多处断言失败，出现许多引用已销毁对象的情况。
仔细检查程序后，我仍然认为这一切简直是不可思议！而且，本来用于对别的程序进行测试的程序自身却出现这类问题，几乎让我无地自容！
为了挽回自己的声誉，我不得不成沉住气来仔细跟踪错误，排解问题！
(二).解决办法
2.1 查错
其实问题的解决还比较顺利。
通过查看程序的调用栈，发现程序出错前总是停留在发送Socket数据包的过程里。接着，进一步通过单步跟踪，发现在发送数据包的过程中，Socket检测到对端连接已经断开，就会触发OnDisconnect事件。而我正是在ServerSocket的OnDisconnect事件中根据传递进来的Socket句柄，找到对应的对象将之销毁的。
我在ServerSocket的OnDisconnect事件中的代码如下：
procedure Txxxx.ServerClientDisconnect(Sender: TObject; Socket: TCustomWinSocket);
Begin
…
//正是这一句，在不合适的时机释放了对象
FLines.DestroyLineBySocket(Socket);
…
end;
问题是这么出现的。
比如，在某个过程中具有如下代码（前面为行号）：
1 FLine.DoSomething；
2 FLine.SendSocketData；
3 FLine.DoOtherThings；
其中，FLine是代表一路呼叫的对象。该对象内部引用了一个TCustomWinSocket指针。SendSocketData就是利用此Socket进行数据发送。
Flines是TLine对象的容器类的一个实例。
由此不难解读前述的各类错误：
1．由于行2的Socket连接断开导致FLine对象释放，因此行3访问DoOtherThings几乎必然造成访问地址错；
2．由于行2的对象销毁，因此程序中类似“Object as TLine”的代码导致第二类错误；
3．由于对象提前销毁，善后处理工作未到位导致第三类错误；
2.2 解决方案
明白其原因后，问题解决起来就容易多了。上述问题不外乎两个方案：
一，判断实例是否存在
在DoOtherThings之后，判断FLine对象是否仍然处于Flines之中，若是则继续处理，否则结束处理；
二，延迟销毁FLine对象
在ServerSocket的OnDisconnect中，将FLine对象抛入垃圾池，待时机成熟时再销毁。
考虑到方案一所要改动的代码量较大，同时，此种方案代码也不甚优美，因此决定采用方案二，即引入垃圾回收机制来解决问题。方案二的要点是选择合适的时机真正销毁对象。而对于这一点，问题倒不大，只需选择消息循环中处理消息的第一个环节进行回收即可。因为在之后的处理环节中，必然能够确保对FLine是否仍然有效的检查。
(三).简易对象垃圾回收框架（untGarbagCollector）
3.1 概述
简易的垃圾回收非常简单：
■使用TThreadList支持线程并发访问，并保存待回收的对象指针；
■提供Put方法保存待回收对象；
■提供Recycle方法进行真正的回收（因为所有对象均自TObject派生而来）。
3.2 实现代码
unit untGarbagCollector;
interface
uses
Classes;
type
TGarbagCollector = Class(TObject)
private
FList: TThreadList;
public
constructor Create;
destructor Destroy; override;
procedure Put(const AObject: TObject);
procedure Recycle(const MaxCount: Integer);
end;
function GarbagCollector: TGarbagCollector;
implementation
var
_GarbagCollector: TGarbagCollector;
function GarbagCollector: TGarbagCollector;
begin
if not Assigned(_GarbagCollector) then
_GarbagCollector := TGarbagCollector.Create;
result := _GarbagCollector;
end;
{ TGarbagCollect }
constructor TGarbagCollector.Create;
begin
FList := TThreadList.Create;
end;
destructor TGarbagCollector.Destroy;
begin
try
Recycle(FList.LockList.Count);
finally
FList.UnlockList;
end;
FList.Free;
end;
procedure TGarbagCollector.Put(const AObject: TObject);
begin
try
FList.LockList.Add(AObject);
finally
FList.UnlockList;
end;
end;
procedure TGarbagCollector.Recycle(const MaxCount: Integer);
var
I: Integer;
AList: TList;
begin
AList := FList.LockList;
try
I := 0;
while (AList.Count > 0) and (I < MaxCount) do
begin
TObject(AList.Last).Free;
AList.Delete(AList.Count - 1);
Inc(I);
end;
finally
FList.UnlockList;
end;
end;
initialization
finalization
if Assigned(_GarbagCollector) then
_GarbagCollector.Free;
end.
3.3 使用举例
引用untGarbagCollector单元后，可以直接使用GarbagCollector进行对象的销毁和回收。
■销毁
AObject := TObject.Create;
GarbagCollector.Put(AObject);
■回收
可以在定时器、线程以及其他场合调用Recycle方法。
MaxCount是用于控制每次销毁个数的参数，主要是怕一次性销毁太多占用过多的cpu。
（突然发现还可以扩展为限制时间进行销毁，比如每次销毁耗时不超过的n毫秒）。
3.4 使用场合
在本案例中，为了防止对象过早销毁引起访问冲突，而引入了垃圾回收技术。
在其它场合，比如为了提高某些程序的主观性能，也可以引入该技术。比如完成某些特定任务的程序，在处理过程中会产生临时的对象，而销毁这些对象又比较耗时。因此，为了尽早地结束任务，可以把这些临时对象保存至垃圾池中。待作业（任务）完成，并且等一段时间后cpu比较空闲时，再把临时对象真正销毁。此做法的真谛就是以空间换取时间——与某些系统预创建对象，并重复利用对象以提高性能的做法相同。
http://www.lsworks.net/article/91.html