LeetCode Shell Problems

195. Tenth Line -- 第十行

How would you print just the 10th line of a file?

Solution:

awk 'NR==10' file.txt

---

194. Transpose File -- 转置文件

Given a text file file.txt, transpose its content.

You may assume that each row has the same number of columns and each field is separated by the ' ' character.

For example, if file.txt has the following content:

name age

alice 21

ryan 30

Output the following:

name alice ryan

age 21 30

Solution:

awk '{
    max_nf = NF
    max_nr = NR
    for (x = 1; x <= NF; x++) {
        vector[x, NR] = $x
    }
}
END {
for (x = 1; x <= max_nf; x++) {
    for (y = 1; y <= max_nr; y++) {
        printf("%s", vector[x, y])
        if (y < max_nr)
            printf(" ")
    }
    if (x < max_nf)
        printf("\n")
}
}' file.txt

---

193. Valid Phone Numbers -- 有效电话号码

Given a text file file.txt that contains list of phone numbers (one per line), write a one liner bash script to print all valid phone numbers.

You may assume that a valid phone number must appear in one of the following two formats: (xxx) xxx-xxxx or xxx-xxx-xxxx. (x means a digit)

You may also assume each line in the text file must not contain leading or trailing white spaces.

For example, assume that file.txt has the following content:

987-123-4567

123 456 7890

[phone]

Your script should output the following valid phone numbers:

987-123-4567

[phone]

Solution:

awk '/^[0-9]{3}-[0-9]{3}-[0-9]{4}$/ || /^\([0-9]{3}\) [0-9]{3}-[0-9]{4}$/' file.txt

---

192. Word Frequency -- 词频

Write a bash script to calculate the frequency of each word in a text file words.txt.

For simplicity sake, you may assume:

• words.txt contains only lowercase characters and space ' ' characters.
• Each word must consist of lowercase characters only.
• Words are separated by one or more whitespace characters.

For example, assume that words.txt has the following content:

the day is sunny the the

the sunny is is

Your script should output the following, sorted by descending frequency:

the 4

is 3

sunny 2

day 1

Note:

Don't worry about handling ties, it is guaranteed that each word's frequency count is unique.

Solution:

awk '{for(i=1;i<=NF;i++) a[$i]+=1} END{for(i in a) print i,a[i] | "sort -r -n -k2"}' words.txt