<> 翻译 2.2 CMake 编程

时间：2023-03-10 05:41:41
<<Modern CMake>> 翻译 2.2 CMake 编程

<<Modern CMake>> 翻译 2.2 CMake 编程

流程控制

CMake有一个 if 语句, 经年累月之后，现在它已经相当复杂。 您可以在 if 语句中使用全大写字母书写一系列关键字，并且您通常可以直接通过名称（if语句在历史上出现早于变量扩展）或使用 ${} 语法来引用变量。 下面是 if 语句的示例：

if(variable)

    # If variable is `ON`, `YES`, `TRUE`, `Y`, or non zero number

else()

    # If variable is `0`, `OFF`, `NO`, `FALSE`, `N`, `IGNORE`, `NOTFOUND`, `""`, or ends in `-NOTFOUND`

endif()

# If variable does not expand to one of the above, CMake will expand it then try again

如果您明确地进行变量扩展（例如 ${variable}，由于扩展的潜在扩展），这可能会有点混乱。 在CMake 3.1+ 中添加了一个策略(CMP0054)，使得被引号引起来的变量扩展不被递归扩展。 因此，只要 CMake 的最低版本是 3.1+，您就可以：

if("${variable}")

    # True if variable is not false-like

else()

    # Note that undefined variables would be `""` thus false

endif()

这里还有一些可以在 if 命令中使用的关键字，例如：

  • 一元关键字: NOT, TARGET, EXISTS (文件), DEFINED, 等等
  • 二元关键字: STREQUAL, AND, OR, MATCHES (正则表达式), VERSION_LESS, VERSION_LESS_EQUAL(CMake 3.7+), 等等
  • 括号可以用于分组

生成器表达式 (Generator-expressions)

Generator-expressions 非常强大，但也有点奇怪和专业。 大多数 CMake 命令在配置时运行，包括上面看到的 if 语句。 但是如果你需要在构建时甚至安装时间执行逻辑呢？ 为了这个目的 CMake 添加了生成器表达式(Generator-expressions)。1 它们在目标属性中进行计算和执行。

最简单的生成器表达式是信息表达式，具有这样 $<KEYWORD> 的形式; 他们评估(计算和执行)一条与当前配置相关的信息。 另一种形式是 $<KEYWORD:value>，KEYWORD 关键字控制评估，value 是要评估的项目（这里也允许使用信息表达式关键字）。 如果 KEYWORD 是一个计算结果为 0 或 1 的生成器表达式或变量，value 则替换为 0 或 1。 您可以嵌套生成器表达式，并且可以使用变量来使嵌套变量可读。 某些表达式允许使用逗号分隔的多个值。2

例如，如果你想要设置仅在 DEBUG 配置下生效的编译标志，则可以这样写：

target_compile_options(MyTarget PRIVATE "$<$<CONFIG:Debug>:--my-flag>")

这是一种比使用专用 *_DEBUG 变量更新，更好的方式，并且可以推广到生成器表达式支持的所有情况。 请注意，您永远不应该使用配置时的值作为当前配置，因为 IDE 之类的多配置生成器并没有“当前”配置，仅在构建时通过生成器表达式和自定义的 *_<CONFIG> 变量起作用。

生成器表达式的其他常见用法：

  • 将项目限制为仅限某种语言（例如 CXX），以避免它与 CUDA 等混在一起，或者根据目标语言将其包装以使其不同。
  • 访问配置相关属性，例如目标文件位置。
  • 为构建和安装目录提供不同的位置。

最后一个很常见。几乎每个支持安装的软件包都会看到类似的内容：

 target_include_directories(

     MyTarget

     PUBLIC

     $<BUILD_INTERFACE:"${CMAKE_CURRENT_SOURCE_DIR}/include">

     $<INSTALL_INTERFACE:include>

     )

1. 它们就像在构建/安装时评估它们一样，但实际上它们是针对每个构建配置分别进行评估的。↩

2. CMake 文档将表达式拆分为信息，逻辑和输出。↩

宏和函数

你可以方便的定义你自己的 CMake 函数 function 和宏 macro 。 函数和宏之间的唯一区别是作用范围：宏没有作用范围。 因此，如果您在函数中设置了变量并希望它在外部可见，那么您将需要用 PARENT_SCOPE。 由于您必须在每个函数中明确用 PARENT_SCOPE 设置您希望外部世界可见的变量，嵌套函数有点儿烦。 但是，函数不会像宏一样 “泄漏” 变量。 在以下示例中，我将使用函数。

一个简单使用函数的例子如下：

function(SIMPLE REQUIRED_ARG)

    message(STATUS "Simple arguments: ${REQUIRED_ARG}, followed by ${ARGV}")

    set(${REQUIRED_ARG} "From SIMPLE" PARENT_SCOPE)

endfunction()

simple(This)

message("Output: ${This}")

如果你想用位置参数，它们需要明确列出，并且所有其他参数都被放在 ARGN 中（ARGV 中保存有所有参数，甚至那些你已经列出的参数）。 您只能通过设置变量来解决 CMake 中函数没有返回值的问题。 在上面的示例中，您可以显式指定要设置的变量名称。

参数

你已经在 CMake 函数的大部分使用中看到，CMake 有一个命名变量系统。 您可以将它与 cmake_parse_arguments 函数一起使用。 如果要支持 3.5 以下的 CMake 版本，您还需要包含 CMakeParseArguments 模块，该模块在成为内置命令之前就已存在。

以下是如何使用它的示例：

function(COMPLEX)

cmake_parse_arguments(

    COMPLEX_PREFIX

    "SINGLE;ANOTHER"

    "ONE_VALUE;ALSO_ONE_VALUE"

    "MULTI_VALUES"

    ${ARGN}

)

endfunction()

complex(SINGLE ONE_VALUE value MULTI_VALUES some other values)

在此调用 cmake_parse_arguments 函数后，在 complex 函数内部，给我们产生了这些变量：

COMPLEX_PREFIX_SINGLE = TRUE

COMPLEX_PREFIX_ANOTHER = FALSE

COMPLEX_PREFIX_ONE_VALUE = "value"

COMPLEX_PREFIX_ALSO_ONE_VALUE = <UNDEFINED>

COMPLEX_PREFIX_MULTI_VALUES = "some;other;values"

如果你查看官方页面，你会看到一个稍微不同的使用 set 的方法避免在列表中明确写分号的方法; 随意使用您最喜欢的结构。 您也可以将它与上面列出的位置参数混合使用; 任何剩余的参数（包括可选的位置参数）都会保存在 COMPLEX_PREFIX_UNPARSED_ARGUMENTS 中。

相关文章